[gentoo-commits] gentoo-x86 commit in sys-apps/policycoreutils: policycoreutils-2.4-r1.ebuild policycoreutils-9999.ebuild ChangeLog

[Jason Zaman (perfinion)]

perfinion    15/07/04 12:43:43

  Modified:             policycoreutils-9999.ebuild ChangeLog
  Added:                policycoreutils-2.4-r1.ebuild
  Log:
  bump of policycoreutils-extra, fixes bugs 544598, 517456, 517450
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0x7EF137EC935B0EAF)

Revision  Changes    Path
1.2                  sys-apps/policycoreutils/policycoreutils-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/policycoreutils/policycoreutils-9999.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/policycoreutils/policycoreutils-9999.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/policycoreutils/policycoreutils-9999.ebuild?r1=1.1&r2=1.2

Index: policycoreutils-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/policycoreutils/policycoreutils-9999.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- policycoreutils-9999.ebuild	9 Jun 2015 15:38:25 -0000	1.1
+++ policycoreutils-9999.ebuild	4 Jul 2015 12:43:43 -0000	1.2
@@ -1,17 +1,17 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/policycoreutils/policycoreutils-9999.ebuild,v 1.1 2015/06/09 15:38:25 swift Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/policycoreutils/policycoreutils-9999.ebuild,v 1.2 2015/07/04 12:43:43 perfinion Exp $
 
 EAPI="5"
 PYTHON_COMPAT=( python2_7 )
 PYTHON_REQ_USE="xml"
 
-inherit multilib python-r1 toolchain-funcs eutils
+inherit multilib python-r1 toolchain-funcs eutils bash-completion-r1
 
 MY_P="${P//_/-}"
-MY_RELEASEDATE="20150202"
 
-EXTRAS_VER="1.33"
+MY_RELEASEDATE="20150202"
+EXTRAS_VER="1.34"
 SEMNG_VER="${PV}"
 SELNX_VER="${PV}"
 SEPOL_VER="${PV}"
@@ -25,35 +25,35 @@
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/SELinuxProject/selinux.git"
 	SRC_URI="mirror://gentoo/policycoreutils-extra-${EXTRAS_VER}.tar.bz2"
-	S="${WORKDIR}/${MY_P}/${PN}"
 	S1="${WORKDIR}/${MY_P}/${PN}"
 	S2="${WORKDIR}/policycoreutils-extra"
+	S="${S1}"
 else
-	SRC_URI="https://raw.githubusercontent.com/wiki/SELinuxProject/selinux/files/releases/20150202/${MY_P}.tar.gz
-		mirror://gentoo/policycoreutils-extra-${EXTRAS_VER}.tar.bz2"
+	SRC_URI="https://raw.githubusercontent.com/wiki/SELinuxProject/selinux/files/releases/${MY_RELEASEDATE}/${MY_P}.tar.gz
+		http://dev.gentoo.org/~perfinion/distfiles/policycoreutils-extra-${EXTRAS_VER}.tar.bz2"
 	KEYWORDS="~amd64 ~x86"
-	S="${WORKDIR}/${MY_P}"
 	S1="${WORKDIR}/${MY_P}"
 	S2="${WORKDIR}/policycoreutils-extra"
+	S="${S1}"
 fi
 
 LICENSE="GPL-2"
 SLOT="0"
 
-DEPEND=">=sys-libs/libselinux-${SELNX_VER}[python]
+DEPEND=">=sys-libs/libselinux-${SELNX_VER}:=[python]
 	>=sys-libs/glibc-2.4
-	>=sys-libs/libcap-1.10-r10
-	>=sys-libs/libsemanage-${SEMNG_VER}[python]
-	sys-libs/libcap-ng
-	>=sys-libs/libsepol-${SEPOL_VER}
+	>=sys-libs/libcap-1.10-r10:=
+	>=sys-libs/libsemanage-${SEMNG_VER}:=[python]
+	sys-libs/libcap-ng:=
+	>=sys-libs/libsepol-${SEPOL_VER}:=
 	sys-devel/gettext
 	dev-python/ipy[${PYTHON_USEDEP}]
 	dbus? (
 		sys-apps/dbus
-		dev-libs/dbus-glib
+		dev-libs/dbus-glib:=
 	)
 	audit? ( >=sys-process/audit-1.5.1 )
-	pam? ( sys-libs/pam )
+	pam? ( sys-libs/pam:= )
 	${PYTHON_DEPS}"
 
 ### libcgroup -> seunshare
@@ -62,7 +62,8 @@
 # pax-utils for scanelf used by rlpkg
 RDEPEND="${DEPEND}
 	dev-python/sepolgen
-	app-misc/pax-utils"
+	app-misc/pax-utils
+	!<sys-apps/openrc-0.14"
 
 src_unpack() {
 	# Override default one because we need the SRC_URI ones even in case of 9999 ebuilds
@@ -97,6 +98,8 @@
 
 	epatch_user
 
+	sed -i 's/-Werror//g' "${S1}"/*/Makefile || die "Failed to remove Werror"
+
 	python_copy_sources
 	# Our extra code is outside the regular directory, so set it to the extra
 	# directory. We really should optimize this as it is ugly, but the extra
@@ -153,11 +156,11 @@
 	S="${S1}" # back for later
 
 	# remove redhat-style init script
-	rm -fR "${D}/etc/rc.d"
+	rm -fR "${D}/etc/rc.d" || die
 
 	# compatibility symlinks
 	dosym /sbin/setfiles /usr/sbin/setfiles
-	dosym /$(get_libdir)/rc/runscript_selinux.so /$(get_libdir)/rcscripts/runscript_selinux.so
+	bashcomp_alias setsebool getsebool
 
 	# location for policy definitions
 	dodir /var/lib/selinux
@@ -172,10 +175,10 @@
 	done
 
 	dodir /usr/share/doc/${PF}/mcstrans/examples
-	cp -dR "${S1}"/mcstrans/share/examples/* "${D}/usr/share/doc/${PF}/mcstrans/examples"
+	cp -dR "${S1}"/mcstrans/share/examples/* "${D}/usr/share/doc/${PF}/mcstrans/examples" || die
 }
 
 pkg_postinst() {
 	# The selinux_gentoo init script is no longer needed with recent OpenRC
-	elog "The selinux_gentoo init script will be removed in future versions since it is not needed with OpenRC 0.13."
+	elog "The selinux_gentoo init script has been removed in this version as it is not required after OpenRC 0.13."
 }



1.155                sys-apps/policycoreutils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/policycoreutils/ChangeLog?rev=1.155&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/policycoreutils/ChangeLog?rev=1.155&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/policycoreutils/ChangeLog?r1=1.154&r2=1.155

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/policycoreutils/ChangeLog,v
retrieving revision 1.154
retrieving revision 1.155
diff -u -r1.154 -r1.155
--- ChangeLog	9 Jun 2015 15:38:25 -0000	1.154
+++ ChangeLog	4 Jul 2015 12:43:43 -0000	1.155
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/policycoreutils
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/policycoreutils/ChangeLog,v 1.154 2015/06/09 15:38:25 swift Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/policycoreutils/ChangeLog,v 1.155 2015/07/04 12:43:43 perfinion Exp $
+
+*policycoreutils-2.4-r1 (04 Jul 2015)
+
+  04 Jul 2015; Jason Zaman <perfinion@g.o>
+  +policycoreutils-2.4-r1.ebuild, policycoreutils-9999.ebuild:
+  bump of policycoreutils-extra, fixes bugs 544598, 517456, 517450
 
 *policycoreutils-9999 (09 Jun 2015)
 



1.1                  sys-apps/policycoreutils/policycoreutils-2.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/policycoreutils/policycoreutils-2.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/policycoreutils/policycoreutils-2.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: policycoreutils-2.4-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/policycoreutils/policycoreutils-2.4-r1.ebuild,v 1.1 2015/07/04 12:43:43 perfinion Exp $

EAPI="5"
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="xml"

inherit multilib python-r1 toolchain-funcs eutils bash-completion-r1

MY_P="${P//_/-}"

MY_RELEASEDATE="20150202"
EXTRAS_VER="1.34"
SEMNG_VER="${PV}"
SELNX_VER="${PV}"
SEPOL_VER="${PV}"

IUSE="audit pam dbus"

DESCRIPTION="SELinux core utilities"
HOMEPAGE="https://github.com/SELinuxProject/selinux/wiki"
SRC_URI="https://raw.githubusercontent.com/wiki/SELinuxProject/selinux/files/releases/${MY_RELEASEDATE}/${MY_P}.tar.gz
	http://dev.gentoo.org/~perfinion/distfiles/policycoreutils-extra-${EXTRAS_VER}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND=">=sys-libs/libselinux-${SELNX_VER}:=[python]
	>=sys-libs/glibc-2.4
	>=sys-libs/libcap-1.10-r10:=
	>=sys-libs/libsemanage-${SEMNG_VER}:=[python]
	sys-libs/libcap-ng:=
	>=sys-libs/libsepol-${SEPOL_VER}:=
	sys-devel/gettext
	dev-python/ipy[${PYTHON_USEDEP}]
	dbus? (
		sys-apps/dbus
		dev-libs/dbus-glib:=
	)
	audit? ( >=sys-process/audit-1.5.1 )
	pam? ( sys-libs/pam:= )
	${PYTHON_DEPS}"

### libcgroup -> seunshare
### dbus -> restorecond

# pax-utils for scanelf used by rlpkg
RDEPEND="${DEPEND}
	dev-python/sepolgen
	app-misc/pax-utils
	!<sys-apps/openrc-0.14"

S1="${WORKDIR}/${MY_P}"
S2="${WORKDIR}/policycoreutils-extra"
S="${S1}"

src_prepare() {
	epatch "${FILESDIR}/0010-remove-sesandbox-support.patch"
	epatch "${FILESDIR}/0020-disable-autodetection-of-pam-and-audit.patch"
	epatch "${FILESDIR}/0030-make-inotify-check-use-flag-triggered.patch"
	epatch "${FILESDIR}/0040-reverse-access-check-in-run_init.patch"
	epatch "${FILESDIR}/0070-remove-symlink-attempt-fails-with-gentoo-sandbox-approach.patch"
	epatch "${FILESDIR}/0110-build-mcstrans-bug-472912.patch"
	epatch "${FILESDIR}/0120-build-failure-for-mcscolor-for-CONTEXT__CONTAINS.patch"

	# rlpkg is more useful than fixfiles
	sed -i -e '/^all/s/fixfiles//' "${S}/scripts/Makefile" \
		|| die "fixfiles sed 1 failed"
	sed -i -e '/fixfiles/d' "${S}/scripts/Makefile" \
		|| die "fixfiles sed 2 failed"

	epatch_user

	sed -i 's/-Werror//g' "${S1}"/*/Makefile || die "Failed to remove Werror"

	python_copy_sources
	# Our extra code is outside the regular directory, so set it to the extra
	# directory. We really should optimize this as it is ugly, but the extra
	# code is needed for Gentoo at the same time that policycoreutils is present
	# (so we cannot use an additional package for now).
	S="${S2}"
	python_copy_sources
}

src_compile() {
	building() {
		emake -C "${BUILD_DIR}" \
			AUDIT_LOG_PRIVS="y" \
			AUDITH="$(usex audit)" \
			PAMH="$(usex pam)" \
			INOTIFYH="$(usex dbus)" \
			SESANDBOX="n" \
			CC="$(tc-getCC)" \
			PYLIBVER="${EPYTHON}" \
			LIBDIR="\$(PREFIX)/$(get_libdir)"
	}
	S="${S1}" # Regular policycoreutils
	python_foreach_impl building
	S="${S2}" # Extra set
	python_foreach_impl building
}

src_install() {
	# Python scripts are present in many places. There are no extension modules.
	installation-policycoreutils() {
		einfo "Installing policycoreutils"
		emake -C "${BUILD_DIR}" DESTDIR="${D}" \
			AUDITH="$(usex audit)" \
			PAMH="$(usex pam)" \
			INOTIFYH="$(usex dbus)" \
			SESANDBOX="n" \
			AUDIT_LOG_PRIV="y" \
			PYLIBVER="${EPYTHON}" \
			LIBDIR="\$(PREFIX)/$(get_libdir)" \
			install
		python_optimize
	}

	installation-extras() {
		einfo "Installing policycoreutils-extra"
		emake -C "${BUILD_DIR}" DESTDIR="${D}" INOTIFYH="$(usex dbus)" SHLIBDIR="${D}$(get_libdir)/rc" install
		python_optimize
	}

	S="${S1}" # policycoreutils
	python_foreach_impl installation-policycoreutils
	S="${S2}" # extras
	python_foreach_impl installation-extras
	S="${S1}" # back for later

	# remove redhat-style init script
	rm -fR "${D}/etc/rc.d" || die

	# compatibility symlinks
	dosym /sbin/setfiles /usr/sbin/setfiles
	bashcomp_alias setsebool getsebool

	# location for policy definitions
	dodir /var/lib/selinux
	keepdir /var/lib/selinux

	# Set version-specific scripts
	for pyscript in audit2allow sepolgen-ifgen sepolicy chcat; do
	  python_replicate_script "${ED}/usr/bin/${pyscript}"
	done
	for pyscript in semanage rlpkg; do
	  python_replicate_script "${ED}/usr/sbin/${pyscript}"
	done

	dodir /usr/share/doc/${PF}/mcstrans/examples
	cp -dR "${S1}"/mcstrans/share/examples/* "${D}/usr/share/doc/${PF}/mcstrans/examples" || die
}

pkg_postinst() {
	# The selinux_gentoo init script is no longer needed with recent OpenRC
	elog "The selinux_gentoo init script has been removed in this version as it is not required after OpenRC 0.13."
}