[gentoo-commits] gentoo-x86 commit in dev-python/jinja: jinja-2.7.3.ebuild ChangeLog

[Patrick McLean (chutzpah)]

chutzpah    14/06/26 17:49:49

  Modified:             ChangeLog
  Added:                jinja-2.7.3.ebuild
  Log:
  Version bump, fix for CVE-2014-0012.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xE3F69979BB4B8928DA78E3D17CBF44EF)

Revision  Changes    Path
1.109                dev-python/jinja/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/ChangeLog?rev=1.109&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/ChangeLog?rev=1.109&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/ChangeLog?r1=1.108&r2=1.109

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/jinja/ChangeLog,v
retrieving revision 1.108
retrieving revision 1.109
diff -u -r1.108 -r1.109
--- ChangeLog	18 May 2014 00:48:27 -0000	1.108
+++ ChangeLog	26 Jun 2014 17:49:48 -0000	1.109
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/jinja
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/jinja/ChangeLog,v 1.108 2014/05/18 00:48:27 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/jinja/ChangeLog,v 1.109 2014/06/26 17:49:48 chutzpah Exp $
+
+*jinja-2.7.3 (26 Jun 2014)
+
+  26 Jun 2014; Patrick McLean <chutzpah@g.o> +jinja-2.7.3.ebuild:
+  Version bump, fix for CVE-2014-0012.
 
 *jinja-2.7.2 (18 May 2014)
 



1.1                  dev-python/jinja/jinja-2.7.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/jinja-2.7.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/jinja-2.7.3.ebuild?rev=1.1&content-type=text/plain

Index: jinja-2.7.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/jinja/jinja-2.7.3.ebuild,v 1.1 2014/06/26 17:49:48 chutzpah Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )

inherit eutils distutils-r1

MY_PN=Jinja2
MY_P=${MY_PN}-${PV}

DESCRIPTION="A small but fast and easy to use stand-alone template engine written in pure Python"
HOMEPAGE="http://jinja.pocoo.org/ http://pypi.python.org/pypi/Jinja2"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris"
IUSE="doc examples"

RDEPEND="dev-python/markupsafe[${PYTHON_USEDEP}]
	dev-python/setuptools[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	doc? ( >=dev-python/sphinx-0.6 )"

# XXX: handle Babel better?

S=${WORKDIR}/${MY_P}
PATCHES=( "${FILESDIR}/jinja-2.7-docs.patch" )

wrap_opts() {
	local mydistutilsargs=()

	if [[ ${EPYTHON} == python* ]]; then
		mydistutilargs+=( --with-debugsupport )
	fi

	"${@}"
}

python_compile() {
	wrap_opts distutils-r1_python_compile
}

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	esetup.py test
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/html/. )
	use examples && local EXAMPLES=( examples/. )

	distutils-r1_python_install_all

	insinto /usr/share/vim/vimfiles/syntax
	doins ext/Vim/*
}

pkg_postinst() {
	if ! has_version dev-python/Babel; then
		elog "For i18n support, please emerge dev-python/Babel."
	fi
}