[gentoo-commits] gentoo-x86 commit in games-strategy/boswars: ChangeLog boswars-2.7-r1.ebuild

[Julian Ospald (hasufell)]

hasufell    13/07/29 21:28:56

  Modified:             ChangeLog
  Added:                boswars-2.7-r1.ebuild
  Log:
  fix broken png images wrt #475764
  
  (Portage version: 2.2.0_alpha190/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.22                 games-strategy/boswars/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/boswars/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/boswars/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/boswars/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/boswars/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	24 Jun 2013 16:11:50 -0000	1.21
+++ ChangeLog	29 Jul 2013 21:28:56 -0000	1.22
@@ -1,6 +1,11 @@
 # ChangeLog for games-strategy/boswars
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/boswars/ChangeLog,v 1.21 2013/06/24 16:11:50 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/boswars/ChangeLog,v 1.22 2013/07/29 21:28:56 hasufell Exp $
+
+*boswars-2.7-r1 (29 Jul 2013)
+
+  29 Jul 2013; Julian Ospald <hasufell@g.o> +boswars-2.7-r1.ebuild:
+  fix broken png images wrt #475764
 
 *boswars-2.7 (24 Jun 2013)
 



1.1                  games-strategy/boswars/boswars-2.7-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/boswars/boswars-2.7-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/boswars/boswars-2.7-r1.ebuild?rev=1.1&content-type=text/plain

Index: boswars-2.7-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/boswars/boswars-2.7-r1.ebuild,v 1.1 2013/07/29 21:28:56 hasufell Exp $

EAPI=5
inherit eutils scons-utils games

DESCRIPTION="Futuristic real-time strategy game"
HOMEPAGE="http://www.boswars.org/"
SRC_URI="http://www.boswars.org/dist/releases/${P}-src.tar.gz
	http://dev.gentoo.org/~hasufell/distfiles/${P}-fixed-images-for-libpng-1.6.tar.xz
	mirror://gentoo/bos.png"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

RDEPEND="dev-lang/lua
	media-libs/libsdl[audio,video]
	media-libs/libpng:0
	media-libs/libvorbis
	media-libs/libtheora
	media-libs/libogg
	virtual/opengl
	x11-libs/libX11"
DEPEND="${RDEPEND}"

S=${WORKDIR}/${P}-src

src_unpack() {
	default
	# bug 475764
	cp -dRp ${P}-fixed-images-for-libpng-1.6/* ${P}-src/ \
		|| die "copying fixed images failed!"
}

src_prepare() {
	rm -f doc/{README-SDL.txt,guichan-copyright.txt}
	epatch \
		"${FILESDIR}"/${P}-gentoo.patch \
		"${FILESDIR}"/${P}-scons-blows.patch
	sed -i \
		-e "s:@GENTOO_DATADIR@:${GAMES_DATADIR}/${PN}:" \
		engine/include/stratagus.h \
		|| die
	sed -i \
		-e "/-O2/s:-O2.*math:${CXXFLAGS} -Wall:" \
		SConstruct \
		|| die
}

src_compile() {
	escons || die
}

src_install() {
	newgamesbin build/${PN}-release ${PN}
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r campaigns graphics intro languages maps patches scripts sounds units
	newicon "${DISTDIR}"/bos.png ${PN}.png
	make_desktop_entry ${PN} "Bos Wars"
	# COPYRIGHT.txt is referenced by the html
	dodoc CHANGELOG COPYRIGHT.txt README.txt
	dohtml -r doc/*
	prepgamesdirs
}