[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-games: ChangeLog gnome-games-2.20.2.ebuild

[Gilles Dartiguelongue (eva)]

eva         07/12/06 22:37:02

  Modified:             ChangeLog
  Added:                gnome-games-2.20.2.ebuild
  Log:
  bump to 2.20.2
  (Portage version: 2.1.4_rc7)

Revision  Changes    Path
1.221                gnome-extra/gnome-games/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-games/ChangeLog?rev=1.221&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-games/ChangeLog?rev=1.221&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-games/ChangeLog?r1=1.220&r2=1.221

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/ChangeLog,v
retrieving revision 1.220
retrieving revision 1.221
diff -u -r1.220 -r1.221
--- ChangeLog	29 Nov 2007 06:03:44 -0000	1.220
+++ ChangeLog	6 Dec 2007 22:37:02 -0000	1.221
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/gnome-games
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/ChangeLog,v 1.220 2007/11/29 06:03:44 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/ChangeLog,v 1.221 2007/12/06 22:37:02 eva Exp $
+
+*gnome-games-2.20.2 (06 Dec 2007)
+
+  06 Dec 2007; Gilles Dartiguelongue <eva@g.o>
+  +gnome-games-2.20.2.ebuild:
+  bump to 2.20.2
 
   29 Nov 2007; Jeroen Roovers <jer@g.o> gnome-games-2.20.1.ebuild:
   Stable for HPPA (bug #199740).



1.1                  gnome-extra/gnome-games/gnome-games-2.20.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.20.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.20.2.ebuild?rev=1.1&content-type=text/plain

Index: gnome-games-2.20.2.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.20.2.ebuild,v 1.1 2007/12/06 22:37:02 eva Exp $

# make sure games is inherited first so that the gnome2
# functions will be called if they are not overridden
inherit games eutils gnome2 autotools

DESCRIPTION="Collection of games for the GNOME desktop"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="artworkextra guile opengl"

RDEPEND=">=gnome-base/libgnomeui-2.16.0
	>=gnome-base/libgnome-2.16.0
	>=dev-python/pygtk-2.10
	>=dev-python/gnome-python-desktop-2.17.3
	>=x11-libs/gtk+-2.8
	>=gnome-base/gconf-2
	>=x11-libs/cairo-1
	>=dev-libs/libxml2-2.4.0
	>=gnome-base/librsvg-2.14
	>=media-libs/gstreamer-0.10.11
	>=gnome-base/libglade-2
	>=dev-libs/glib-2.6.3
	guile? ( >=dev-scheme/guile-1.6.5 )
	artworkextra? ( gnome-extra/gnome-games-extra-data )
	opengl? ( dev-python/pygtkglext )
	!games-board/glchess"

DEPEND="${RDEPEND}
	>=sys-devel/autoconf-2.53
	>=dev-util/pkgconfig-0.15
	>=dev-util/intltool-0.35
	>=sys-devel/gettext-0.10.40
	>=gnome-base/gnome-common-2.12.0
	>=app-text/scrollkeeper-0.3.8"

# Others are installed below; multiples in this package.
DOCS="HACKING MAINTAINERS"

pkg_setup() {
	# create the games user / group
	games_pkg_setup

	G2CONF="--with-scores-group=${GAMES_GROUP}"

	if use guile; then
		if has_version =dev-scheme/guile-1.8*; then
			local flags="deprecated regex"
			built_with_use dev-scheme/guile ${flags} || die "guile must be built with \"${flags}\" use flags"
		fi
	else
		G2CONF="${G2CONF} --enable-omitgames=aisleriot"
	fi
}

src_unpack() {
	gnome2_src_unpack

	# Resolve symbols at execution time in setgid binaries
	epatch "${FILESDIR}/${PN}-2.14.0-no_lazy_bindings.patch"

	AT_M4DIR="m4" eautoreconf
}

src_install() {
	gnome2_src_install

	# Documentation install for each of the games
	for game in \
	$(find . -maxdepth 1 -type d ! -name po ! -name libgames-support); do
		docinto ${game}
		for doc in AUTHORS ChangeLog NEWS README TODO; do
			[ -s ${game}/${doc} ] && dodoc ${game}/${doc}
		done
	done
}

pkg_preinst() {
	# Avoid overwriting previous .scores files
	local basefile
	for scorefile in "${D}"/var/lib/games/*.scores; do
		basefile=$(basename $scorefile)
		if [ -s "${ROOT}/var/lib/games/${basefile}" ]; then
			cp "${ROOT}/var/lib/games/${basefile}" \
			"${D}/var/lib/games/${basefile}"
		fi
	done
}



-- 
gentoo-commits@g.o mailing list