[gentoo-commits] gentoo-x86 commit in app-editors/gedit: ChangeLog gedit-2.20.3.ebuild

[Gilles Dartiguelongue (eva)]

eva         07/10/21 23:14:01

  Modified:             ChangeLog
  Added:                gedit-2.20.3.ebuild
  Log:
  bump to 2.20.3
  (Portage version: 2.1.3.15)

Revision  Changes    Path
1.211                app-editors/gedit/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/ChangeLog?rev=1.211&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/ChangeLog?rev=1.211&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/ChangeLog?r1=1.210&r2=1.211

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v
retrieving revision 1.210
retrieving revision 1.211
diff -u -r1.210 -r1.211
--- ChangeLog	16 Oct 2007 19:50:02 -0000	1.210
+++ ChangeLog	21 Oct 2007 23:14:00 -0000	1.211
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/gedit
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.210 2007/10/16 19:50:02 remi Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.211 2007/10/21 23:14:00 eva Exp $
+
+*gedit-2.20.3 (21 Oct 2007)
+
+  21 Oct 2007; Gilles Dartiguelongue <eva@g.o> +gedit-2.20.3.ebuild:
+  bump to 2.20.3
 
 *gedit-2.20.2 (16 Oct 2007)
 



1.1                  app-editors/gedit/gedit-2.20.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/gedit-2.20.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/gedit-2.20.3.ebuild?rev=1.1&content-type=text/plain

Index: gedit-2.20.3.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/gedit-2.20.3.ebuild,v 1.1 2007/10/21 23:14:00 eva Exp $

inherit gnome2 eutils autotools

DESCRIPTION="A text editor for the GNOME desktop"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="doc python spell xattr"

RDEPEND=">=gnome-base/gconf-2
	xattr? ( sys-apps/attr )
	>=dev-libs/glib-2.13.5
	>=x11-libs/gtk+-2.11.6
	=x11-libs/gtksourceview-2*
	>=gnome-base/libgnomeui-2.16
	>=gnome-base/libglade-2.5.1
	>=gnome-base/libgnomeprintui-2.12.1
	>=gnome-base/gnome-vfs-2.16
	spell? (
		>=app-text/enchant-1.2
		app-text/iso-codes
	)
	python? (
		>=dev-python/pygobject-2.11.5
		>=dev-python/pygtk-2.9.7
		>=dev-python/pygtksourceview-2
	)"

DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/pkgconfig-0.9
	>=app-text/scrollkeeper-0.3.11
	>=dev-util/intltool-0.35
	>=app-text/gnome-doc-utils-0.3.2"

DOCS="AUTHORS BUGS ChangeLog MAINTAINERS NEWS README"

if [[ "${ARCH}" == "PPC" ]] ; then
	# HACK HACK HACK: someone fix this garbage
	MAKEOPTS="${MAKEOPTS} -j1"
fi

pkg_setup() {
	G2CONF="$(use_enable python) $(use_enable spell) $(use_enable xattr attr)"
}

src_unpack() {
	gnome2_src_unpack

	# Remove symbols that are not meant to be part of the docs, and
	# break compilation if USE="doc -python" (bug #158638).
	if use !python && use doc; then
		epatch "${FILESDIR}"/${PN}-2.16.2-no_python_module_docs.patch
	fi

	# chown on fbsd doesn't have --reference.  Bug #183691
	epatch "${FILESDIR}"/${PN}-2.18.1-fbsd.patch

	AT_M4DIR="./m4" eautoreconf
}



-- 
gentoo-commits@g.o mailing list