[gentoo-commits] gentoo-x86 commit in www-apps/dokuwiki: dokuwiki-20140929c.ebuild ChangeLog

[Jorge Manuel B. S. Vicetto (jmbsvicetto)]

jmbsvicetto    15/03/01 17:39:24

  Modified:             ChangeLog
  Added:                dokuwiki-20140929c.ebuild
  Log:
  Bump to the 20140929c release - bug 541712.
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key BB0E6E98)

Revision  Changes    Path
1.75                 www-apps/dokuwiki/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/ChangeLog?rev=1.75&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/ChangeLog?rev=1.75&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/ChangeLog?r1=1.74&r2=1.75

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/ChangeLog,v
retrieving revision 1.74
retrieving revision 1.75
diff -u -r1.74 -r1.75
--- ChangeLog	22 Dec 2014 13:52:28 -0000	1.74
+++ ChangeLog	1 Mar 2015 17:39:24 -0000	1.75
@@ -1,6 +1,12 @@
 # ChangeLog for www-apps/dokuwiki
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/ChangeLog,v 1.74 2014/12/22 13:52:28 jmbsvicetto Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/ChangeLog,v 1.75 2015/03/01 17:39:24 jmbsvicetto Exp $
+
+*dokuwiki-20140929c (01 Mar 2015)
+
+  01 Mar 2015; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
+  +dokuwiki-20140929c.ebuild:
+  Bump to the 20140929c release - bug 541712.
 
   22 Dec 2014; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
   -dokuwiki-20140505b.ebuild, -dokuwiki-20140929a.ebuild:



1.1                  www-apps/dokuwiki/dokuwiki-20140929c.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/dokuwiki-20140929c.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/dokuwiki-20140929c.ebuild?rev=1.1&content-type=text/plain

Index: dokuwiki-20140929c.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/dokuwiki-20140929c.ebuild,v 1.1 2015/03/01 17:39:24 jmbsvicetto Exp $

EAPI=5

inherit webapp depend.php

# upstream uses dashes in the datestamp
MY_BASE_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
MY_PV="${MY_BASE_PV}${PV:8:1}"

DESCRIPTION="DokuWiki is a simple to use Wiki aimed at a small company's documentation needs."
HOMEPAGE="http://wiki.splitbrain.org/wiki:dokuwiki"
SRC_URI="http://download.dokuwiki.org/src/${PN}/${PN}-${MY_PV}.tgz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="gd"

DEPEND=""
RDEPEND="
	>=dev-lang/php-5.3[xml]
	gd? ( ||
		(
			dev-lang/php[gd]
			media-gfx/imagemagick
		)
	)
"

need_httpd_cgi
need_php_httpd

S="${WORKDIR}/${PN}-${MY_PV}"

src_prepare() {
	# create initial changes file
	touch data/changes.log
}

src_install() {
	webapp_src_preinst

	dodoc README
	rm -f README COPYING

	docinto scripts
	dodoc bin/*
	rm -rf bin

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	for x in $(find data/ -not -name '.htaccess'); do
		webapp_serverowned "${MY_HTDOCSDIR}"/${x}
	done

	webapp_configfile "${MY_HTDOCSDIR}"/.htaccess.dist
	webapp_configfile "${MY_HTDOCSDIR}"/conf

	for x in $(find conf/ -not -name 'msg'); do
		webapp_configfile "${MY_HTDOCSDIR}"/${x}
	done

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_src_install
}