[gentoo-commits] gentoo-x86 commit in dev-scheme/gauche-gtk: gauche-gtk-0.6_pre1.ebuild ChangeLog

[Akinori Hattori (hattya)]

hattya      11/11/27 08:05:49

  Modified:             ChangeLog
  Added:                gauche-gtk-0.6_pre1.ebuild
  Log:
  new upstream snapshot. fixes bug #239821.
  
  (Portage version: 2.1.10.11/cvs/Linux i686)

Revision  Changes    Path
1.14                 dev-scheme/gauche-gtk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/gauche-gtk/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/gauche-gtk/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/gauche-gtk/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-scheme/gauche-gtk/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	29 Mar 2011 12:19:38 -0000	1.13
+++ ChangeLog	27 Nov 2011 08:05:49 -0000	1.14
@@ -1,6 +1,13 @@
 # ChangeLog for dev-scheme/gauche-gtk
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-scheme/gauche-gtk/ChangeLog,v 1.13 2011/03/29 12:19:38 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-scheme/gauche-gtk/ChangeLog,v 1.14 2011/11/27 08:05:49 hattya Exp $
+
+*gauche-gtk-0.6_pre1 (27 Nov 2011)
+
+  27 Nov 2011; Akinori Hattori <hattya@g.o>
+  +files/gauche-gtk-gtk-lib.hints.diff, +files/gauche-gtk-h2s-cpp.diff,
+  +files/gauche-gtk-h2s-gdk-pixbuf.diff, +gauche-gtk-0.6_pre1.ebuild:
+  new upstream snapshot. fixes bug #239821.
 
   29 Mar 2011; Christoph Mende <angelos@g.o> gauche-gtk-0.4.1.ebuild:
   Fixed slot deps



1.1                  dev-scheme/gauche-gtk/gauche-gtk-0.6_pre1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/gauche-gtk/gauche-gtk-0.6_pre1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-scheme/gauche-gtk/gauche-gtk-0.6_pre1.ebuild?rev=1.1&content-type=text/plain

Index: gauche-gtk-0.6_pre1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-scheme/gauche-gtk/gauche-gtk-0.6_pre1.ebuild,v 1.1 2011/11/27 08:05:49 hattya Exp $

EAPI="4"

inherit autotools eutils

MY_P="${P/g/G}"
MY_PN="${PN/g/G}2"
PV_COMMIT="598828842a339a44c32ab8c16f5f9a77f3c1c799"

DESCRIPTION="GTK2 binding for Gauche"
HOMEPAGE="http://practical-scheme.net/gauche/"
SRC_URI="https://github.com/shirok/${MY_PN}/tarball/${PV_COMMIT} -> ${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE="examples glgd nls opengl"
RESTRICT="test"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"
RDEPEND="x11-libs/gtk+:2
	dev-scheme/gauche
	opengl? (
		x11-libs/gtkglext
		dev-scheme/gauche-gl
	)"
S="${WORKDIR}/shirok-${MY_PN}-${PV_COMMIT:0:7}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-h2s-gdk-pixbuf.diff
	epatch "${FILESDIR}"/${PN}-gtk-lib.hints.diff
	epatch "${FILESDIR}"/${PN}-h2s-cpp.diff
	eautoconf
}

src_configure() {
	local myconf
	if use opengl; then
		if use glgd; then
			myconf="--enable-glgd"
			if use nls; then
				myconf="${myconf}-pango"
			fi
		else
			myconf="--enable-gtkgl"
		fi
	fi

	econf ${myconf}
}

src_compile() {
	emake stubs
	emake
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc ChangeLog README

	if use examples; then
		docompress -x /usr/share/doc/${PF}/examples
		docinto examples
		dodoc examples/*.scm
		# install gtk-tutorial
		docinto examples/gtk-tutorial
		dodoc examples/gtk-tutorial/*
		if use opengl; then
			# install gtkglext
			dodoc -r examples/gtkglext
			if use glgd; then
				# install glgd
				dodoc -r examples/glgd
			fi
		fi
	fi
}