Gentoo Archives: gentoo-commits

From: Andreas Sturmlechner <asturm@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] proj/kde:master commit in: kde-plasma/plasma-desktop/
Date: Mon, 17 Jan 2022 17:50:03
Message-Id: 1642441600.f3017be939a497d0751511b4bcc60839ef968fd3.asturm@gentoo
1 commit: f3017be939a497d0751511b4bcc60839ef968fd3
2 Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
3 AuthorDate: Mon Jan 17 17:40:44 2022 +0000
4 Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
5 CommitDate: Mon Jan 17 17:46:40 2022 +0000
6 URL: https://gitweb.gentoo.org/proj/kde.git/commit/?id=f3017be9
7
8 kde-plasma/plasma-desktop: 5.23.90 version bump
9
10 Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
11
12 .../plasma-desktop/plasma-desktop-5.23.90.ebuild | 179 +++++++++++++++++++++
13 1 file changed, 179 insertions(+)
14
15 diff --git a/kde-plasma/plasma-desktop/plasma-desktop-5.23.90.ebuild b/kde-plasma/plasma-desktop/plasma-desktop-5.23.90.ebuild
16 new file mode 100644
17 index 0000000000..d35b171b5b
18 --- /dev/null
19 +++ b/kde-plasma/plasma-desktop/plasma-desktop-5.23.90.ebuild
20 @@ -0,0 +1,179 @@
21 +# Copyright 1999-2022 Gentoo Authors
22 +# Distributed under the terms of the GNU General Public License v2
23 +
24 +EAPI=8
25 +
26 +ECM_HANDBOOK="forceoptional"
27 +ECM_TEST="true"
28 +KFMIN=5.90.0
29 +PVCUT=$(ver_cut 1-3)
30 +QTMIN=5.15.2
31 +VIRTUALX_REQUIRED="test"
32 +inherit ecm kde.org optfeature
33 +
34 +DESCRIPTION="KDE Plasma desktop"
35 +XORGHDRS="${PN}-override-include-dirs-1"
36 +SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${XORGHDRS}.tar.xz"
37 +
38 +LICENSE="GPL-2" # TODO: CHECK
39 +SLOT="5"
40 +KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
41 +IUSE="emoji ibus +kaccounts scim +semantic-desktop telemetry"
42 +
43 +COMMON_DEPEND="
44 + >=dev-qt/qtconcurrent-${QTMIN}:5
45 + >=dev-qt/qtdbus-${QTMIN}:5
46 + >=dev-qt/qtdeclarative-${QTMIN}:5
47 + >=dev-qt/qtgui-${QTMIN}:5
48 + >=dev-qt/qtnetwork-${QTMIN}:5
49 + >=dev-qt/qtprintsupport-${QTMIN}:5
50 + >=dev-qt/qtsql-${QTMIN}:5
51 + >=dev-qt/qtsvg-${QTMIN}:5
52 + >=dev-qt/qtwidgets-${QTMIN}:5
53 + >=dev-qt/qtx11extras-${QTMIN}:5
54 + >=dev-qt/qtxml-${QTMIN}:5
55 + >=kde-frameworks/attica-${KFMIN}:5
56 + >=kde-frameworks/kactivities-${KFMIN}:5
57 + >=kde-frameworks/kactivities-stats-${KFMIN}:5
58 + >=kde-frameworks/karchive-${KFMIN}:5
59 + >=kde-frameworks/kauth-${KFMIN}:5
60 + >=kde-frameworks/kbookmarks-${KFMIN}:5
61 + >=kde-frameworks/kcmutils-${KFMIN}:5
62 + >=kde-frameworks/kcodecs-${KFMIN}:5
63 + >=kde-frameworks/kcompletion-${KFMIN}:5
64 + >=kde-frameworks/kconfig-${KFMIN}:5
65 + >=kde-frameworks/kconfigwidgets-${KFMIN}:5
66 + >=kde-frameworks/kcoreaddons-${KFMIN}:5
67 + >=kde-frameworks/kcrash-${KFMIN}:5
68 + >=kde-frameworks/kdbusaddons-${KFMIN}:5
69 + >=kde-frameworks/kdeclarative-${KFMIN}:5
70 + >=kde-frameworks/kded-${KFMIN}:5
71 + >=kde-frameworks/kdelibs4support-${KFMIN}:5
72 + >=kde-frameworks/kglobalaccel-${KFMIN}:5
73 + >=kde-frameworks/kguiaddons-${KFMIN}:5
74 + >=kde-frameworks/ki18n-${KFMIN}:5
75 + >=kde-frameworks/kiconthemes-${KFMIN}:5
76 + >=kde-frameworks/kio-${KFMIN}:5
77 + >=kde-frameworks/kitemmodels-${KFMIN}:5
78 + >=kde-frameworks/kitemviews-${KFMIN}:5
79 + >=kde-frameworks/kjobwidgets-${KFMIN}:5
80 + >=kde-frameworks/knewstuff-${KFMIN}:5
81 + >=kde-frameworks/knotifications-${KFMIN}:5
82 + >=kde-frameworks/knotifyconfig-${KFMIN}:5
83 + >=kde-frameworks/kparts-${KFMIN}:5
84 + >=kde-frameworks/krunner-${KFMIN}:5
85 + >=kde-frameworks/kservice-${KFMIN}:5
86 + >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
87 + >=kde-frameworks/kwindowsystem-${KFMIN}:5
88 + >=kde-frameworks/kxmlgui-${KFMIN}:5
89 + >=kde-frameworks/plasma-${KFMIN}:5
90 + >=kde-frameworks/solid-${KFMIN}:5
91 + >=kde-frameworks/sonnet-${KFMIN}:5
92 + >=kde-plasma/kwin-${PVCUT}:5
93 + >=kde-plasma/libksysguard-${PVCUT}:5
94 + >=kde-plasma/libkworkspace-${PVCUT}:5
95 + >=kde-plasma/plasma-workspace-${PVCUT}:5
96 + >=media-libs/phonon-4.11.0
97 + virtual/libcrypt:=
98 + x11-libs/libX11
99 + x11-libs/libXfixes
100 + x11-libs/libXi
101 + x11-libs/libxcb[xkb]
102 + x11-libs/libxkbfile
103 + emoji? (
104 + app-i18n/ibus[emoji]
105 + dev-libs/glib:2
106 + media-fonts/noto-emoji
107 + )
108 + ibus? (
109 + app-i18n/ibus
110 + dev-libs/glib:2
111 + >=dev-qt/qtx11extras-${QTMIN}:5
112 + x11-libs/libxcb
113 + x11-libs/xcb-util-keysyms
114 + )
115 + kaccounts? (
116 + kde-apps/kaccounts-integration:5
117 + net-libs/accounts-qt
118 + )
119 + scim? ( app-i18n/scim )
120 + semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
121 + telemetry? ( dev-libs/kuserfeedback:5 )
122 +"
123 +DEPEND="${COMMON_DEPEND}
124 + dev-libs/boost
125 + x11-base/xorg-proto
126 +"
127 +RDEPEND="${COMMON_DEPEND}
128 + !kde-plasma/user-manager
129 + >=dev-qt/qtgraphicaleffects-${QTMIN}:5
130 + >=dev-qt/qtquickcontrols2-${QTMIN}:5
131 + >=kde-frameworks/kirigami-${KFMIN}:5
132 + >=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
133 + >=kde-plasma/kde-cli-tools-${PVCUT}:5
134 + >=kde-plasma/oxygen-${PVCUT}:5
135 + sys-apps/util-linux
136 + x11-apps/setxkbmap
137 + x11-misc/xdg-user-dirs
138 + kaccounts? ( net-libs/signon-oauth2 )
139 +"
140 +BDEPEND="virtual/pkgconfig"
141 +
142 +PATCHES=(
143 + "${WORKDIR}/${XORGHDRS}/override-include-dirs.patch" # downstream patch
144 +)
145 +
146 +src_prepare() {
147 + ecm_src_prepare
148 +
149 + if ! use ibus; then
150 + sed -e "s/Qt5X11Extras_FOUND AND XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
151 + -i applets/kimpanel/backend/ibus/CMakeLists.txt || die
152 + fi
153 +
154 + use emoji || cmake_run_in applets/kimpanel/backend/ibus \
155 + cmake_comment_add_subdirectory emojier
156 +
157 + # TODO: try to get a build switch upstreamed
158 + if ! use scim; then
159 + sed -e "s/^pkg_check_modules.*SCIM/#&/" -i CMakeLists.txt || die
160 + fi
161 +}
162 +
163 +src_configure() {
164 + local mycmakeargs=(
165 + -DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON # not packaged
166 + -DEVDEV_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
167 + -DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
168 + -DXORGSERVER_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
169 + -DSYNAPTICS_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
170 + $(cmake_use_find_package kaccounts AccountsQt5)
171 + $(cmake_use_find_package kaccounts KAccounts)
172 + $(cmake_use_find_package semantic-desktop KF5Baloo)
173 + $(cmake_use_find_package telemetry KUserFeedback)
174 + )
175 + if ! use emoji && ! use ibus; then
176 + mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_GLIB2=ON )
177 + fi
178 +
179 + ecm_src_configure
180 +}
181 +
182 +src_test() {
183 + # parallel tests fail, foldermodeltest,positionertest hang, bug #646890
184 + # test_kio_fonts needs D-Bus, bug #634166
185 + # lookandfeel-kcmTest is unreliable for a long time, bug #607918
186 + local myctestargs=(
187 + -j1
188 + -E "(foldermodeltest|positionertest|test_kio_fonts|lookandfeel-kcmTest)"
189 + )
190 +
191 + ecm_src_test
192 +}
193 +
194 +pkg_postinst() {
195 + if [[ -z "${REPLACING_VERSIONS}" ]]; then
196 + optfeature "screen reader support" app-accessibility/orca
197 + fi
198 + ecm_pkg_postinst
199 +}