[gentoo-commits] gentoo-x86 commit in gnome-extra/polkit-gnome: ChangeLog polkit-gnome-0.100.ebuild

[Nirbheek Chauhan (nirbheek)]

nirbheek    11/02/23 13:33:47

  Modified:             ChangeLog
  Added:                polkit-gnome-0.100.ebuild
  Log:
  Bump to 0.100, manually add autostart desktop file
  
  (Portage version: 2.1.9.40/cvs/Linux x86_64)

Revision  Changes    Path
1.25                 gnome-extra/polkit-gnome/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/polkit-gnome/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/polkit-gnome/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/polkit-gnome/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/polkit-gnome/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	31 Jan 2011 16:41:42 -0000	1.24
+++ ChangeLog	23 Feb 2011 13:33:47 -0000	1.25
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/polkit-gnome
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/polkit-gnome/ChangeLog,v 1.24 2011/01/31 16:41:42 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/polkit-gnome/ChangeLog,v 1.25 2011/02/23 13:33:47 nirbheek Exp $
+
+*polkit-gnome-0.100 (23 Feb 2011)
+
+  23 Feb 2011; Nirbheek Chauhan <nirbheek@g.o>
+  +polkit-gnome-0.100.ebuild,
+  +files/polkit-gnome-authentication-agent-1.desktop:
+  Bump to 0.100, manually add autostart desktop file
 
   31 Jan 2011; Gilles Dartiguelongue <eva@g.o>
   polkit-gnome-0.96-r1.ebuild, polkit-gnome-0.99.ebuild:



1.1                  gnome-extra/polkit-gnome/polkit-gnome-0.100.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/polkit-gnome/polkit-gnome-0.100.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/polkit-gnome/polkit-gnome-0.100.ebuild?rev=1.1&content-type=text/plain

Index: polkit-gnome-0.100.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/polkit-gnome/polkit-gnome-0.100.ebuild,v 1.1 2011/02/23 13:33:47 nirbheek Exp $

EAPI="3"

inherit autotools eutils

DESCRIPTION="A dbus session bus service that is used to bring up authentication dialogs"
HOMEPAGE="http://hal.freedesktop.org/docs/PolicyKit/"
SRC_URI="http://hal.freedesktop.org/releases/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="doc examples +introspection"

# XXX: Change to gtk3 when it gets added to ~arch
# Strict dep on the same polkit shouldn't be needed, but we can't be sure
RDEPEND=">=x11-libs/gtk+-2.17.1:2
	>=sys-auth/polkit-${PV}
	introspection? ( >=dev-libs/gobject-introspection-0.6.2 )
	!lxde-base/lxpolkit"
DEPEND="${RDEPEND}
	dev-util/gtk-doc-am
	>=dev-util/intltool-0.35.0
	dev-util/pkgconfig
	gnome-base/gnome-common
	sys-devel/gettext
	doc? ( >=dev-util/gtk-doc-1.3 )"

src_prepare() {
	# Fix make check, bug 298345
	epatch "${FILESDIR}"/${PN}-0.95-fix-make-check.patch

	if use doc; then
		# Fix parallel build failure, bug 293247
		epatch "${FILESDIR}"/${PN}-0.95-parallel-build-failure.patch

		gtkdocize || die
		eautoreconf
	fi
}

src_configure() {
	# Do we need USE static-libs ? By user request.
	econf \
		--disable-dependency-tracking \
		--disable-static \
		$(use_enable doc gtk-doc) \
		$(use_enable examples) \
		$(use_enable introspection)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS HACKING NEWS

	# polkit-gnome-authentication-agent-1.desktop was removed, manually added now
	# translations are lost though, what to do about that?
	insinto /etc/xdg/autostart
	doins "${FILESDIR}/polkit-gnome-authentication-agent-1.desktop"

	find "${D}" -name '*.la' -exec rm -f '{}' +
}