[gentoo-commits] repo/gentoo:master commit in: dev-scheme/gambit/

[Amy Liffey]

commit:     9c32100f86e54afbb5f1867b123ad141093c01f1
Author:     Stefan Strogin <stefan.strogin <AT> gmail <DOT> com>
AuthorDate: Thu Sep 20 16:04:45 2018 +0000
Commit:     Amy Liffey <amynka <AT> gentoo <DOT> org>
CommitDate: Sat Dec 29 14:16:14 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9c32100f

dev-scheme/gambit: revbump to add USE libressl

Closes: https://bugs.gentoo.org/666629
Package-Manager: Portage-2.3.49, Repoman-2.3.10
Closes: https://github.com/gentoo/gentoo/pull/9929
Signed-off-by: Stefan Strogin <stefan.strogin <AT> gmail.com>
Signed-off-by: Amy Liffey <amynka <AT> gentoo.org>

 dev-scheme/gambit/gambit-4.8.8-r2.ebuild | 64 ++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/dev-scheme/gambit/gambit-4.8.8-r2.ebuild b/dev-scheme/gambit/gambit-4.8.8-r2.ebuild
new file mode 100644
index 00000000000..d8fd8612bfc
--- /dev/null
+++ b/dev-scheme/gambit/gambit-4.8.8-r2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils elisp-common
+
+MY_PV="${PV//./_}"
+MY_P="${PN}-v${MY_PV}"
+
+DESCRIPTION="Gambit-C is a native Scheme to C compiler and interpreter"
+HOMEPAGE="http://www.iro.umontreal.ca/~gambit/"
+SRC_URI="http://www-labs.iro.umontreal.ca/~gambit/download/gambit/v${PV%.*}/source/${MY_P}.tgz"
+
+LICENSE="|| ( Apache-2.0 LGPL-2.1 )"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x86-macos"
+
+RDEPEND="ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+DEPEND="
+	${RDEPEND}
+	emacs? ( virtual/emacs )
+"
+
+SITEFILE="50gambit-gentoo.el"
+
+S="${WORKDIR}/${MY_P}" #-devel
+
+IUSE="emacs libressl ssl static"
+
+src_configure() {
+	econf $(use_enable !static shared) \
+		$(use_enable ssl openssl) \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		--enable-gnu-gcc-specific-options \
+		--enable-gnu-gcc-no-strict-aliasing \
+		--enable-single-host \
+		--disable-absolute-shared-libs \
+		--enable-type-checking
+}
+
+src_compile() {
+	emake bootstrap
+
+	if use emacs; then
+		elisp-compile misc/*.el || die
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	keepdir /usr/share/"${MY_PN}"
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}