[gentoo-commits] repo/gentoo:master commit in: dev-libs/libmspack/

[Maciej Mrozowski]

commit:     89a8a05de188bd4c1bb7ef9910293788dd6a6850
Author:     David Heidelberg <david <AT> ixit <DOT> cz>
AuthorDate: Wed May 20 12:03:10 2020 +0000
Commit:     Maciej Mrozowski <reavertm <AT> gentoo <DOT> org>
CommitDate: Sun Aug  2 17:30:36 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=89a8a05d

dev-libs/libmspack: bump to 0.10.1_alpha

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: David Heidelberg <david <AT> ixit.cz>
Bug: https://bugs.gentoo.org/711218
Closes: https://github.com/gentoo/gentoo/pull/15891
Signed-off-by: Maciej Mrozowski <reavertm <AT> gentoo.org>

 dev-libs/libmspack/Manifest                      |  1 +
 dev-libs/libmspack/libmspack-0.10.1_alpha.ebuild | 73 ++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/dev-libs/libmspack/Manifest b/dev-libs/libmspack/Manifest
index fa7a18545ea..d2797cb1e3b 100644
--- a/dev-libs/libmspack/Manifest
+++ b/dev-libs/libmspack/Manifest
@@ -1 +1,2 @@
+DIST libmspack-0.10.1alpha.tar.gz 963274 BLAKE2B 39bcb3b7ea419d6d00850b70c217c802a2095dd4398038e594ae7c01ca12e71508218c1cfca5ae8b102636ab9517b13d55c1e411b31e87d28aa46331cd0127e6 SHA512 a7b5f7caa49190c5021f3e768b92f2e51cc0ce685c9ab6ed6fb36de885c73231b58d47a8a3b5c5aa5c9ac56c25c500eb683d84dbf11f09f97f6cb4fff5adc245
 DIST libmspack-0.9.1alpha.tar.gz 494651 BLAKE2B 4543215efbcac9cd2703cd56f2297645463831cc2dfa6b38d87c5f48f39676347bb20739e0e389e021983d910b9be99bfd369fb30d36090f3f72f09532d6bd1d SHA512 4e39c2be8768c5c0b0d0798c9322ff022173f5e05af1636c18541bbc9f58c1ae1af59252d5631340fca601495c5b1e5abed0ad83481387421d2df5efb75cd49a

diff --git a/dev-libs/libmspack/libmspack-0.10.1_alpha.ebuild b/dev-libs/libmspack/libmspack-0.10.1_alpha.ebuild
new file mode 100644
index 00000000000..25612d9d7d8
--- /dev/null
+++ b/dev-libs/libmspack/libmspack-0.10.1_alpha.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/kyz/libmspack.git"
+	inherit git-r3
+	MY_P="${PN}-9999"
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-solaris"
+	MY_PV="${PV/_alpha/alpha}"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="https://www.cabextract.org.uk/libmspack/libmspack-${MY_PV}.tar.gz"
+fi
+
+DESCRIPTION="A library for Microsoft compression formats"
+HOMEPAGE="https://www.cabextract.org.uk/libmspack/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="debug doc static-libs"
+
+DEPEND=""
+RDEPEND=""
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	if [[ ${PV} == "9999" ]] ; then
+		# Re-create file layout from release tarball
+		pushd "${WORKDIR}" &>/dev/null || die
+		cp -aL "${S}"/${PN} "${WORKDIR}"/${PN}-source || die
+		rm -r "${S}" || die
+		mv "${WORKDIR}"/${PN}-source "${S}" || die
+		popd &>/dev/null || die
+	fi
+
+	default
+
+	eautoreconf
+
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable debug) \
+		$(use_enable static-libs static)
+}
+
+multilib_src_test() {
+	if multilib_is_native_abi; then
+		default
+		cd "${S}"/test && "${BUILD_DIR}"/test/cabd_test || die
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS=(AUTHORS ChangeLog NEWS README TODO)
+	use doc && HTML_DOCS=(doc/*)
+	default_src_install
+	if use doc; then
+		rm "${ED}"/usr/share/doc/"${PF}"/html/{Makefile*,Doxyfile*} || die
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+	if ! use static-libs ; then
+		find "${ED}" -name "*.a" -delete || die
+	fi
+}