[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-vfs: ChangeLog gnome-vfs-2.20.0.ebuild

[Daniel Gryniewicz (dang)]

dang        07/09/25 20:32:22

  Modified:             ChangeLog
  Added:                gnome-vfs-2.20.0.ebuild
  Log:
  New series for Gnome 2.20
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.265                gnome-base/gnome-vfs/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-vfs/ChangeLog?rev=1.265&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-vfs/ChangeLog?rev=1.265&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-vfs/ChangeLog?r1=1.264&r2=1.265

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/ChangeLog,v
retrieving revision 1.264
retrieving revision 1.265
diff -u -r1.264 -r1.265
--- ChangeLog	22 Sep 2007 06:49:01 -0000	1.264
+++ ChangeLog	25 Sep 2007 20:32:21 -0000	1.265
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-base/gnome-vfs
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/ChangeLog,v 1.264 2007/09/22 06:49:01 tgall Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/ChangeLog,v 1.265 2007/09/25 20:32:21 dang Exp $
+
+*gnome-vfs-2.20.0 (25 Sep 2007)
+
+  25 Sep 2007; Daniel Gryniewicz <dang@g.o> +gnome-vfs-2.20.0.ebuild:
+  New series for Gnome 2.20
 
   22 Sep 2007; Tom Gall <tgall@g.o> gnome-vfs-2.18.1.ebuild:
   stable on ppc64



1.1                  gnome-base/gnome-vfs/gnome-vfs-2.20.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-vfs/gnome-vfs-2.20.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-vfs/gnome-vfs-2.20.0.ebuild?rev=1.1&content-type=text/plain

Index: gnome-vfs-2.20.0.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/gnome-vfs-2.20.0.ebuild,v 1.1 2007/09/25 20:32:21 dang Exp $

WANT_AUTOMAKE=1.8
inherit eutils gnome2 autotools

DESCRIPTION="Gnome Virtual Filesystem"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2 LGPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="avahi doc gnutls hal ipv6 samba ssl"

RDEPEND=">=gnome-base/gconf-2
	>=dev-libs/glib-2.9.3
	>=dev-libs/libxml2-2.6
	>=net-misc/neon-0.25.3
	app-arch/bzip2
	virtual/fam
	gnome-base/gnome-mime-data
	>=x11-misc/shared-mime-info-0.14
	>=dev-libs/dbus-glib-0.71
	samba? ( >=net-fs/samba-3 )
	gnutls?	(
				net-libs/gnutls
				!gnome-extra/gnome-vfs-sftp
			)
	ssl?	(
		!gnutls?	(
				>=dev-libs/openssl-0.9.5
				!gnome-extra/gnome-vfs-sftp
				)
		)
	hal?	(
				>=sys-apps/hal-0.5.7
			)
	avahi? ( >=net-dns/avahi-0.6 )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	gnome-base/gnome-common
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.9
	doc? ( >=dev-util/gtk-doc-1 )"
PDEPEND="hal? ( >=gnome-base/gnome-mount-0.4 )"

DOCS="AUTHORS ChangeLog HACKING NEWS README TODO"

pkg_setup() {
	if use hal ; then
		G2CONF="--with-hal-mount=/usr/bin/gnome-mount \
				--with-hal-umount=/usr/bin/gnome-umount \
				--with-hal-eject=/usr/bin/gnome-eject"
	fi

	G2CONF="${G2CONF}                 \
		--disable-schemas-install     \
		--disable-cdda                \
		--disable-howl                \
		--enable-http-neon            \
		$(use_enable ssl openssl)     \
		$(use_enable gnutls)          \
		$(use_enable samba)           \
		$(use_enable ipv6)            \
		$(use_enable hal)             \
		$(use_enable avahi)"

	# this works because of the order of conifgure parsing
	# so should always be behind the use_enable options
	# foser <foser@g.o 19 Apr 2004
	use gnutls && use ssl && G2CONF="${G2CONF} --disable-openssl"
}

src_unpack() {
	gnome2_src_unpack

	# Allow the Trash on afs filesystems (#106118)
	epatch "${FILESDIR}"/${PN}-2.12.0-afs.patch

	# Fix compiling with headers missing
	epatch "${FILESDIR}"/${PN}-2.15.2-headers-define.patch

	# Fix for crashes running programs via sudo
	epatch "${FILESDIR}"/${PN}-2.16.0-no-dbus-crash.patch

	use doc || epatch "${FILESDIR}/${PN}-2.18.1-drop-gtk-doc-check.patch"

	eautoreconf
	intltoolize --force
}



-- 
gentoo-commits@g.o mailing list