[gentoo-commits] gentoo-x86 commit in net-p2p/tribler: tribler-6.2.0.ebuild ChangeLog

[Anthony G. Basile (blueness)]

blueness    13/08/02 13:31:40

  Modified:             ChangeLog
  Added:                tribler-6.2.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.12.2/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

Revision  Changes    Path
1.48                 net-p2p/tribler/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/tribler/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/tribler/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/tribler/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/tribler/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	10 May 2013 01:32:31 -0000	1.47
+++ ChangeLog	2 Aug 2013 13:31:39 -0000	1.48
@@ -1,6 +1,12 @@
 # ChangeLog for net-p2p/tribler
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/tribler/ChangeLog,v 1.47 2013/05/10 01:32:31 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/tribler/ChangeLog,v 1.48 2013/08/02 13:31:39 blueness Exp $
+
+*tribler-6.2.0 (02 Aug 2013)
+
+  02 Aug 2013; Anthony G. Basile <blueness@g.o>
+  +files/tribler-6.2.0-fix-desktop.patch, +tribler-6.2.0.ebuild:
+  Version bump
 
 *tribler-6.1.0 (10 May 2013)
 



1.1                  net-p2p/tribler/tribler-6.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/tribler/tribler-6.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/tribler/tribler-6.2.0.ebuild?rev=1.1&content-type=text/plain

Index: tribler-6.2.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/tribler/tribler-6.2.0.ebuild,v 1.1 2013/08/02 13:31:39 blueness Exp $

EAPI="5"
PYTHON_DEPEND="2"
PYTHON_USE_WITH="sqlite"

inherit eutils python unpacker

DESCRIPTION="Bittorrent client that does not require a website to discover content"
HOMEPAGE="http://www.tribler.org/"
SRC_URI="
	http://dl.tribler.org/tribler_6.2.0ubuntu1_all.deb
	x86?   ( http://dl.tribler.org/tribler-swift_6.2.0ubuntu1_i386.deb )
	amd64? ( http://dl.tribler.org/tribler-swift_6.2.0ubuntu1_amd64.deb )"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="vlc"

RDEPEND="
	dev-python/apsw
	dev-python/feedparser
	dev-python/m2crypto
	dev-python/netifaces
	dev-libs/openssl
	dev-python/wxpython
	net-libs/rb_libtorrent
	vlc? (
			media-video/vlc
			media-video/ffmpeg
		)"

DEPEND="${RDEPEND}
	app-arch/unzip"

S="${WORKDIR}"

QA_PREBUILT="/usr/lib/tribler/swift"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-log2homedir.patch"
	epatch "${FILESDIR}/${P}-fix-desktop.patch"

	python_convert_shebangs -r 2 .
}

src_compile() { :; }

src_install() {
	#Remove a dead sym link
	rm usr/share/tribler/Tribler/Main/webUI/static/mootools.js

	#Rename the doc dir properly
	mv usr/share/doc/${PN} usr/share/doc/${P}

	#Move the readme to the doc dir
	mv usr/share/${PN}/Tribler/readme.txt usr/share/doc/${P}

	#Remove the licenses scattered throughout
	rm usr/share/doc/${P}/copyright
	rm usr/share/${PN}/Tribler/*.txt
	rm usr/share/${PN}/Tribler/Core/DecentralizedTracking/pymdht/LGPL-2.1.txt

	#Copy the rest over
	cp -pPR usr/ "${ED}"/
}

pkg_postinst() {
	python_mod_optimize "${ROOT}"usr/share/${PN}
}

pkg_postrm() {
	python_mod_cleanup "${ROOT}"usr/share/${PN}
}