[gentoo-commits] gentoo-x86 commit in media-libs/libjpeg-turbo: ChangeLog libjpeg-turbo-1.1.90.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    11/11/20 06:57:15

  Modified:             ChangeLog
  Added:                libjpeg-turbo-1.1.90.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha75/cvs/Linux x86_64)

Revision  Changes    Path
1.20                 media-libs/libjpeg-turbo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	20 Nov 2011 06:27:45 -0000	1.19
+++ ChangeLog	20 Nov 2011 06:57:15 -0000	1.20
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libjpeg-turbo
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog,v 1.19 2011/11/20 06:27:45 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libjpeg-turbo/ChangeLog,v 1.20 2011/11/20 06:57:15 ssuominen Exp $
+
+*libjpeg-turbo-1.1.90 (20 Nov 2011)
+
+  20 Nov 2011; Samuli Suominen <ssuominen@g.o>
+  +libjpeg-turbo-1.1.90.ebuild:
+  Version bump.
 
   20 Nov 2011; Samuli Suominen <ssuominen@g.o>
   -libjpeg-turbo-1.1.0.ebuild:



1.1                  media-libs/libjpeg-turbo/libjpeg-turbo-1.1.90.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libjpeg-turbo/libjpeg-turbo-1.1.90.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libjpeg-turbo/libjpeg-turbo-1.1.90.ebuild?rev=1.1&content-type=text/plain

Index: libjpeg-turbo-1.1.90.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libjpeg-turbo/libjpeg-turbo-1.1.90.ebuild,v 1.1 2011/11/20 06:57:15 ssuominen Exp $

EAPI=4
inherit flag-o-matic java-pkg-opt-2 libtool toolchain-funcs

DESCRIPTION="MMX, SSE, and SSE2 SIMD accelerated JPEG library"
HOMEPAGE="http://libjpeg-turbo.virtualgl.org/ http://sourceforge.net/projects/libjpeg-turbo/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
	mirror://debian/pool/main/libj/libjpeg8/libjpeg8_8c-2.debian.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
IUSE="java static-libs"

ASM_DEPEND="|| ( dev-lang/nasm dev-lang/yasm )"
COMMON_DEPEND="!media-libs/jpeg:0"
RDEPEND="${COMMON_DEPEND}
	java? ( >=virtual/jre-1.5 )"
DEPEND="${COMMON_DEPEND}
	amd64? ( ${ASM_DEPEND} )
	x86? ( ${ASM_DEPEND} )
	amd64-linux? ( ${ASM_DEPEND} )
	x86-linux? ( ${ASM_DEPEND} )
	java? ( >=virtual/jdk-1.5 )"

src_prepare() {
	elibtoolize

	java-pkg-opt-2_src_prepare
}

src_configure() {
	if use java; then
		export JAVACFLAGS="$(java-pkg_javac-args)"
		export JNI_CFLAGS="$(java-pkg_get-jni-cflags)"
	fi

	econf \
		$(use_enable static-libs static) \
		--with-jpeg8 \
		$(use_with java)
}

src_compile() {
	local _java_makeopts
	use java && _java_makeopts="-j1"
	emake ${_java_makeopts}

	cd ../debian/extra || die
	emake CC="$(tc-getCC)" CFLAGS="${LDFLAGS} ${CFLAGS}"
}

src_test() {
	emake test
}

src_install() {
	emake DESTDIR="${D}" install
	find "${D}" -name '*.la' -exec rm -f {} +

	dodoc ChangeLog.txt example.c README-turbo.txt

	if use java; then
		docinto java
		dodoc java/README
		rm -rf "${ED}"usr/classes
		java-pkg_dojar java/turbojpeg.jar
	fi

	cd ../debian/extra || die
	emake DESTDIR="${D}" prefix="${EPREFIX}/usr" \
		INSTALL="install -m755" INSTALLDIR="install -d -m755" \
		install
}