[gentoo-commits] repo/gentoo:master commit in: sys-apps/gnome-disk-utility/

[Matt Turner]

commit:     e27b28c330efee8d8428061d9b0d4e7f45ee753e
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 16 22:00:04 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Apr 16 22:03:48 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e27b28c3

sys-apps/gnome-disk-utility: Version bump to 40.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 sys-apps/gnome-disk-utility/Manifest               |  1 +
 .../gnome-disk-utility-40.0.ebuild                 | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/sys-apps/gnome-disk-utility/Manifest b/sys-apps/gnome-disk-utility/Manifest
index e30857bbf90..8e00cb835f7 100644
--- a/sys-apps/gnome-disk-utility/Manifest
+++ b/sys-apps/gnome-disk-utility/Manifest
@@ -1 +1,2 @@
 DIST gnome-disk-utility-3.38.2.tar.xz 1375128 BLAKE2B e437eead1273bb2931462ac6c7a7dfea75c603c5325af003d403f4b5130b28e95496724c1939e5dd2e3c8b517eb0d3cdf51952299451546b41f9f5eaddcf9e63 SHA512 3afc0a40e82f0ab3608302af3d83acb15a758581122188125f9572e95a802359d1af0a1e99fb0cd8fb612413aac09e3d33404d08a2d5e189b79d4f284c92cb82
+DIST gnome-disk-utility-40.0.tar.xz 1386880 BLAKE2B 680057797dc820197adbb3a8dea53c9545343ef03037d22ac3f3f87f34a0727d02c2b602a5886006e30acf97a1c1358258ff6f947be2192d835f955020b366cb SHA512 c53e1bef93dc024bc69be60848825f8175841319a2a7b92a75f48432423c5465151536f597c69707ebff37e5bc8e2c96d8a10f0f0e7ebe7cdc961a74841efd80

diff --git a/sys-apps/gnome-disk-utility/gnome-disk-utility-40.0.ebuild b/sys-apps/gnome-disk-utility/gnome-disk-utility-40.0.ebuild
new file mode 100644
index 00000000000..3192512980a
--- /dev/null
+++ b/sys-apps/gnome-disk-utility/gnome-disk-utility-40.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Disk Utility for GNOME using udisks"
+HOMEPAGE="https://wiki.gnome.org/Apps/Disks"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="fat elogind gnome systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+DEPEND="
+	>=media-libs/libdvdread-4.2.0:0=
+	>=dev-libs/glib-2.31:2
+	>=x11-libs/gtk+-3.16.0:3
+	>=media-libs/libcanberra-0.1[gtk3]
+	>=gui-libs/libhandy-1.1.90:1=
+	>=app-arch/xz-utils-5.0.5
+	>=x11-libs/libnotify-0.7:=
+	>=app-crypt/libsecret-0.7
+	>=dev-libs/libpwquality-1.0.0
+	>=sys-fs/udisks-2.7.6:2
+	elogind? ( >=sys-auth/elogind-209 )
+	systemd? ( >=sys-apps/systemd-209:0= )
+"
+RDEPEND="${DEPEND}
+	x11-themes/adwaita-icon-theme
+	fat? ( sys-fs/dosfstools )
+	gnome? ( >=gnome-base/gnome-settings-daemon-3.8 )
+"
+# libxml2 for xml-stripblanks in gresource
+BDEPEND="
+	dev-libs/libxml2:2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dlogind=$(usex systemd libsystemd $(usex elogind libelogind none))
+		$(meson_use gnome gsd_plugin)
+		-Dman=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}