[gentoo-commits] repo/gentoo:master commit in: media-libs/babl/

[Sam James]

commit:     9dc282fb7b31e7f7beb5e63c8846e5b0721375d5
Author:     Sergey Torokhov <torokhov-s-a <AT> yandex <DOT> ru>
AuthorDate: Mon Dec 28 23:02:08 2020 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Dec 29 01:54:42 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9dc282fb

media-libs/babl: 0.1.84 version bump

Signed-off-by: Sergey Torokhov <torokhov-s-a <AT> yandex.ru>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-libs/babl/Manifest           |  1 +
 media-libs/babl/babl-0.1.84.ebuild | 61 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/media-libs/babl/Manifest b/media-libs/babl/Manifest
index e52c4aea7c8..0535b744eab 100644
--- a/media-libs/babl/Manifest
+++ b/media-libs/babl/Manifest
@@ -1 +1,2 @@
 DIST babl-0.1.78.tar.xz 298920 BLAKE2B 654baf0ed09fbbad54578bf8bba60f45152e446d8b3d3ee49ca57084f220d22ed9478bc95851c5c1b17deeacdacfc14a39ab4d6e3f0448012eb212eef8b357b2 SHA512 d40f68cbd3d7703066a8985958b6cc49eaefe842c0fb3b7bbf6a5d6e6198642b55c4f95bdbf0d25a29d24a975c9b94acfd084792c60b18ec5f66260dfe54893b
+DIST babl-0.1.84.tar.xz 299216 BLAKE2B 80db725230f5bee71a9e2056e40cfe9c4dda7669fe3004d73c2d1525c9a89362491edc5addef47f28a94938ab3cdefef0496b38404fc4ab11931e7b9e0daaebe SHA512 a8cba80bd3a434ee9bbd1a0d1fcd6e5e38f9c657b189a70631ff3fe4e4c270e64762d1be13d48e8514d4166ac4175745001499fcda68eb1ea93e03c18b2a5d06

diff --git a/media-libs/babl/babl-0.1.84.ebuild b/media-libs/babl/babl-0.1.84.ebuild
new file mode 100644
index 00000000000..cd9637db782
--- /dev/null
+++ b/media-libs/babl/babl-0.1.84.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+VALA_USE_DEPEND=vapigen
+
+inherit meson gnome2-utils vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/babl.git"
+	SRC_URI=""
+else
+	SRC_URI="https://ftp.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 -sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A dynamic, any to any, pixel format conversion library"
+HOMEPAGE="https://gegl.org/babl/"
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="introspection lcms vala cpu_flags_x86_avx2 cpu_flags_x86_f16c cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse4_1"
+REQUIRED_USE="vala? ( introspection )"
+
+BDEPEND="
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+RDEPEND="
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	lcms? ( >=media-libs/lcms-2.8:2 )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	gnome2_environment_reset
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	# Automagic rsvg support is just for website generation we do not call,
+	#     so we don't need to fix it
+	# w3m is used for dist target thus no issue for us that it is automagically
+	#     detected
+	local emesonargs=(
+		-Dwith-docs=false
+		$(meson_use introspection enable-gir)
+		$(meson_use lcms with-lcms)
+		$(meson_use vala enable-vapi)
+		$(meson_use cpu_flags_x86_avx2 enable-avx2)
+		$(meson_use cpu_flags_x86_f16c enable-f16c)
+		$(meson_use cpu_flags_x86_mmx enable-mmx)
+		$(meson_use cpu_flags_x86_sse enable-sse)
+		$(meson_use cpu_flags_x86_sse2 enable-sse2)
+		$(meson_use cpu_flags_x86_sse4_1 enable-sse4_1)
+	)
+	meson_src_configure
+}