[gentoo-commits] gentoo-x86 commit in net-analyzer/nmap: nmap-6.25.ebuild metadata.xml ChangeLog nmap-6.40-r1.ebuild nmap-6.01.ebuild

[Jeroen Roovers (jer)]

jer         13/08/02 13:52:45

  Modified:             nmap-6.25.ebuild metadata.xml ChangeLog
                        nmap-6.01.ebuild
  Added:                nmap-6.40-r1.ebuild
  Log:
  Move USE=gtk to USE=zenmap in accordance with other USE flags. Clean up dependencies. Migrate to python-*-r1. Remove pysqlite dep (bug #408835).
  
  (Portage version: 2.2.0_alpha191/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.28                 net-analyzer/nmap/nmap-6.25.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.25.ebuild?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.25.ebuild?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.25.ebuild?r1=1.27&r2=1.28

Index: nmap-6.25.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-6.25.ebuild,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- nmap-6.25.ebuild	15 Mar 2013 13:30:43 -0000	1.27
+++ nmap-6.25.ebuild	2 Aug 2013 13:52:45 -0000	1.28
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-6.25.ebuild,v 1.27 2013/03/15 13:30:43 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-6.25.ebuild,v 1.28 2013/08/02 13:52:45 jer Exp $
 
 EAPI="4"
 
@@ -30,7 +30,6 @@
 	dev-lang/python:2.7[sqlite]
 	dev-lang/python:2.6[sqlite]
 	dev-lang/python:2.5[sqlite]
-	dev-python/pysqlite:2
 )
 "
 RDEPEND="



1.9                  net-analyzer/nmap/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/metadata.xml?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/metadata.xml?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/metadata.xml?r1=1.8&r2=1.9

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/nmap/metadata.xml,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- metadata.xml	11 Jan 2013 16:49:50 -0000	1.8
+++ metadata.xml	2 Aug 2013 13:52:45 -0000	1.9
@@ -8,5 +8,6 @@
 <flag name="ndiff">Install the ndiff utility</flag>
 <flag name="nmap-update">Install nmap-update, which uses <pkg>dev-vcs/subversion</pkg> to update nmap scripts in your home directory</flag>
 <flag name="nping">Install the nping utility</flag>
+<flag name="zenmap">Install the GTK+ based zenmap utility</flag>
 </use>
 </pkgmetadata>



1.304                net-analyzer/nmap/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/ChangeLog?rev=1.304&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/ChangeLog?rev=1.304&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/ChangeLog?r1=1.303&r2=1.304

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/nmap/ChangeLog,v
retrieving revision 1.303
retrieving revision 1.304
diff -u -r1.303 -r1.304
--- ChangeLog	1 Aug 2013 16:50:08 -0000	1.303
+++ ChangeLog	2 Aug 2013 13:52:45 -0000	1.304
@@ -1,6 +1,13 @@
 # ChangeLog for net-analyzer/nmap
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/ChangeLog,v 1.303 2013/08/01 16:50:08 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/ChangeLog,v 1.304 2013/08/02 13:52:45 jer Exp $
+
+*nmap-6.40-r1 (02 Aug 2013)
+
+  02 Aug 2013; Jeroen Roovers <jer@g.o> nmap-6.01.ebuild,
+  nmap-6.25.ebuild, +nmap-6.40-r1.ebuild, metadata.xml:
+  Move USE=gtk to USE=zenmap in accordance with other USE flags. Clean up
+  dependencies. Migrate to python-*-r1. Remove pysqlite dep (bug #408835).
 
   01 Aug 2013; Jeroen Roovers <jer@g.o> nmap-6.40.ebuild,
   +files/nmap-6.40-uninstaller.patch:



1.25                 net-analyzer/nmap/nmap-6.01.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.01.ebuild?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.01.ebuild?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.01.ebuild?r1=1.24&r2=1.25

Index: nmap-6.01.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-6.01.ebuild,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- nmap-6.01.ebuild	26 Jan 2013 18:18:04 -0000	1.24
+++ nmap-6.01.ebuild	2 Aug 2013 13:52:45 -0000	1.25
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-6.01.ebuild,v 1.24 2013/01/26 18:18:04 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-6.01.ebuild,v 1.25 2013/08/02 13:52:45 jer Exp $
 
 EAPI="4"
 
@@ -25,7 +25,6 @@
 	dev-lang/python:2.7[sqlite]
 	dev-lang/python:2.6[sqlite]
 	dev-lang/python:2.5[sqlite]
-	dev-python/pysqlite:2
 )
 "
 DEPEND="



1.1                  net-analyzer/nmap/nmap-6.40-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.40-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.40-r1.ebuild?rev=1.1&content-type=text/plain

Index: nmap-6.40-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-6.40-r1.ebuild,v 1.1 2013/08/02 13:52:45 jer Exp $

EAPI=5

PYTHON_COMPAT=( python2_{5,6,7} )
PYTHON_REQ_USE="sqlite"
inherit eutils flag-o-matic python-single-r1 toolchain-funcs

MY_P=${P/_beta/BETA}

DESCRIPTION="A utility for network exploration or security auditing"
HOMEPAGE="http://nmap.org/"
SRC_URI="
	http://nmap.org/dist/${MY_P}.tar.bz2
	http://dev.gentoo.org/~jer/nmap-logo-64.png
"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"

IUSE="ipv6 +lua ncat ndiff nls nmap-update nping ssl zenmap"
NMAP_LINGUAS=( de es fr hr hu id it ja pl pt_BR pt_PT ro ru sk zh )
IUSE+=" ${NMAP_LINGUAS[@]/#/linguas_}"

NMAP_PYTHON_DEPEND="
	|| ( ${PYTHON_DEPS} )
"
RDEPEND="
	dev-libs/libpcre
	net-libs/libpcap[ipv6?]
	zenmap? (
		dev-python/pygtk:2
		${NMAP_PYTHON_DEPEND}
	)
	lua? ( >=dev-lang/lua-5.2[deprecated] )
	ndiff? ( ${NMAP_PYTHON_DEPEND} )
	nls? ( virtual/libintl )
	nmap-update? ( dev-libs/apr dev-vcs/subversion )
	ssl? ( dev-libs/openssl )
"
DEPEND="
	${RDEPEND}
	nls? ( sys-devel/gettext )
"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	# prevent unpacking the logo
	unpack ${MY_P}.tar.bz2
}

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-4.75-nolua.patch \
		"${FILESDIR}"/${PN}-5.10_beta1-string.patch \
		"${FILESDIR}"/${PN}-5.21-python.patch \
		"${FILESDIR}"/${PN}-6.01-make.patch \
		"${FILESDIR}"/${PN}-6.25-liblua-ar.patch \
		"${FILESDIR}"/${P}-uninstaller.patch

	sed -i \
		-e 's/-m 755 -s ncat/-m 755 ncat/' \
		ncat/Makefile.in || die

	if use nls; then
		local lingua=''
		for lingua in ${NMAP_LINGUAS}; do
			if ! use linguas_${lingua}; then
				rm -rf zenmap/share/zenmap/locale/${lingua}
				rm -f zenmap/share/zenmap/locale/${lingua}.po
			fi
		done
	else
		# configure/make ignores --disable-nls
		for lingua in ${NMAP_LINGUAS}; do
			rm -rf zenmap/share/zenmap/locale/${lingua}
			rm -f zenmap/share/zenmap/locale/${lingua}.po
		done
	fi

	sed -i \
		-e '/^ALL_LINGUAS =/{s|$| id|g;s|jp|ja|g}' \
		Makefile.in || die

	# Fix desktop files wrt bug #432714
	sed -i \
		-e '/^Encoding/d' \
		-e 's|^Categories=.*|Categories=Network;System;Security;|g' \
		zenmap/install_scripts/unix/zenmap-root.desktop \
		zenmap/install_scripts/unix/zenmap.desktop || die
}

src_configure() {
	# The bundled libdnet is incompatible with the version available in the
	# tree, so we cannot use the system library here.
	econf \
		$(use_enable ipv6) \
		$(use_enable nls) \
		$(use_with zenmap) \
		$(usex lua --with-liblua=/usr --without-liblua) \
		$(use_with ncat) \
		$(use_with ndiff) \
		$(use_with nmap-update) \
		$(use_with nping) \
		$(use_with ssl openssl) \
		--with-libdnet=included \
		--with-pcre=/usr
}

src_compile() {
	emake \
		AR=$(tc-getAR) \
		RANLIB=$(tc-getRANLIB )
}

src_install() {
	LC_ALL=C emake -j1 \
		DESTDIR="${D}" \
		STRIP=: \
		nmapdatadir="${EPREFIX}"/usr/share/nmap \
		install
	if use nmap-update;then
		LC_ALL=C emake -j1 \
			-C nmap-update \
			DESTDIR="${D}" \
			STRIP=: \
			nmapdatadir="${EPREFIX}"/usr/share/nmap \
			install
	fi

	dodoc CHANGELOG HACKING docs/README docs/*.txt

	use zenmap && doicon "${DISTDIR}/nmap-logo-64.png"
}