[gentoo-commits] repo/gentoo:master commit in: dev-libs/wayland/

[Matt Turner]

commit:     b79bff070e814b0c365c4309af01e33592e4a4f1
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Jul  3 22:28:12 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Jul  3 22:30:19 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b79bff07

dev-libs/wayland: Version bump to 1.21.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/wayland/Manifest              |  1 +
 dev-libs/wayland/wayland-1.21.0.ebuild | 57 ++++++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/dev-libs/wayland/Manifest b/dev-libs/wayland/Manifest
index 680b0b621abe..46d7d2fbf65d 100644
--- a/dev-libs/wayland/Manifest
+++ b/dev-libs/wayland/Manifest
@@ -1 +1,2 @@
 DIST wayland-1.20.0.tar.xz 225188 BLAKE2B d607610ad8b30b6b3bbfc3945679f698030f271766cfb72425f98f170a96469fb085fb9a746a866b8562d7f452c844e61ad57f634dcf365474c7d050b76022e9 SHA512 e8a1f410994b947f850799bdd0d95a2429d8467f853e62a0ab3915a4e9fe130f8aa977e03715114ab740c6ec546edea63d275ce7f927d4f3029ea126e6a7d215
+DIST wayland-1.21.0.tar.xz 225936 BLAKE2B 2b43eb1517d476bb2b4daed1083373655b57d047968fdb93dbbbbe4235af12e25557627e30b5c3d2575bac4beaf1e0a0b8ef10a3c673538d9097501f33c05836 SHA512 5575216d30fdf5c63caa6bcad071e15f2a4f3acb12df776806073f65db37a50b5b5b3cc7957c5497636f4ac01893e2eaab26e453ded44b287acde01762f5fdc3

diff --git a/dev-libs/wayland/wayland-1.21.0.ebuild b/dev-libs/wayland/wayland-1.21.0.ebuild
new file mode 100644
index 000000000000..bbe4c3904bca
--- /dev/null
+++ b/dev-libs/wayland/wayland-1.21.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/wayland/wayland.git"
+	inherit git-r3
+else
+	SRC_URI="https://gitlab.freedesktop.org/wayland/${PN}/-/releases/${PV}/downloads/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+inherit meson-multilib
+
+DESCRIPTION="Wayland protocol libraries"
+HOMEPAGE="https://wayland.freedesktop.org/ https://gitlab.freedesktop.org/wayland/wayland"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	~dev-util/wayland-scanner-${PV}
+	virtual/pkgconfig
+	doc? (
+		>=app-doc/doxygen-1.6[dot]
+		app-text/xmlto
+		>=media-gfx/graphviz-2.26.0
+	)
+"
+DEPEND="
+	>=dev-libs/libffi-3.0.13-r1:=[${MULTILIB_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_bool doc documentation)
+		$(meson_native_true dtd_validation)
+		-Dlibraries=true
+		-Dscanner=false
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# We set it on purpose to only a short subdir name, as socket paths are
+	# created in there, which are 108 byte limited. With this it hopefully
+	# barely fits to the limit with /var/tmp/portage/${CATEGORY}/${PF}/temp/x
+	export XDG_RUNTIME_DIR="${T}"/x
+	mkdir "${XDG_RUNTIME_DIR}" || die
+	chmod 0700 "${XDG_RUNTIME_DIR}" || die
+
+	multilib-minimal_src_test
+}