[gentoo-commits] gentoo-x86 commit in x11-wm/wmii: ChangeLog wmii-3.9.2-r1.ebuild wmii-3.9.2.ebuild

[Jeroen Roovers (jer)]

jer         10/06/26 16:58:30

  Modified:             ChangeLog
  Added:                wmii-3.9.2-r1.ebuild
  Removed:              wmii-3.9.2.ebuild
  Log:
  Respect CC.
  (Portage version: 2.2_rc67/cvs/Linux i686)

Revision  Changes    Path
1.35                 x11-wm/wmii/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/wmii/ChangeLog?rev=1.35&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/wmii/ChangeLog?rev=1.35&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/wmii/ChangeLog?r1=1.34&r2=1.35

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/wmii/ChangeLog,v
retrieving revision 1.34
retrieving revision 1.35
diff -u -r1.34 -r1.35
--- ChangeLog	26 Jun 2010 14:01:17 -0000	1.34
+++ ChangeLog	26 Jun 2010 16:58:30 -0000	1.35
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/wmii
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/wmii/ChangeLog,v 1.34 2010/06/26 14:01:17 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/wmii/ChangeLog,v 1.35 2010/06/26 16:58:30 jer Exp $
+
+*wmii-3.9.2-r1 (26 Jun 2010)
+
+  26 Jun 2010; Jeroen Roovers <jer@g.o> -wmii-3.9.2.ebuild,
+  +wmii-3.9.2-r1.ebuild:
+  Respect CC.
 
 *wmii-3.9.2 (26 Jun 2010)
 



1.1                  x11-wm/wmii/wmii-3.9.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/wmii/wmii-3.9.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/wmii/wmii-3.9.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: wmii-3.9.2-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/wmii/wmii-3.9.2-r1.ebuild,v 1.1 2010/06/26 16:58:30 jer Exp $

EAPI=2
inherit flag-o-matic multilib toolchain-funcs

MY_P=wmii+ixp-${PV}

DESCRIPTION="A dynamic window manager for X11"
HOMEPAGE="http://wmii.suckless.org/"
SRC_URI="http://dl.suckless.org/wmii/${MY_P}.tbz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc64 ~x86"
IUSE=""

COMMON_DEPEND="x11-libs/libXft
	x11-libs/libXext
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/libX11
	x11-libs/libXinerama
	>=media-libs/freetype-2"
RDEPEND="${COMMON_DEPEND}
	x11-apps/xmessage
	x11-apps/xsetroot
	media-fonts/font-misc-misc"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${MY_P}

MAKEOPTS="${MAKEOPTS} -j1"

pkg_setup() {
	mywmiiconf=(
		"PREFIX=/usr"
		"DOC=/usr/share/doc/${PF}"
		"ETC=/etc"
		"LIBDIR=/usr/$(get_libdir)"
		"DESTDIR=${D}"
		)
}

src_prepare() {
	sed -i config.mk -e "/^\(CC\|LD\)/s|cc|$(tc-getCC)|g" || die "sed failed"
}

src_compile() {
	append-flags -I/usr/include/freetype2
	emake "${mywmiiconf[@]}" || die
}

src_install() {
	emake "${mywmiiconf[@]}" install || die
	dodoc NEWS NOTES README TODO

	echo wmii > "${T}"/wmii
	exeinto /etc/X11/Sessions
	doexe "${T}"/wmii || die

	insinto /usr/share/xsessions
	doins "${FILESDIR}"/${PN}.desktop || die
}