[gentoo-commits] gentoo-x86 commit in sys-fs/udisks: ChangeLog udisks-1.0.1-r2.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/08/21 09:17:07

  Modified:             ChangeLog
  Added:                udisks-1.0.1-r2.ebuild
  Log:
  Fix long hangs on probing nonexistant floppies.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.16                 sys-fs/udisks/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	20 Aug 2010 17:08:15 -0000	1.15
+++ ChangeLog	21 Aug 2010 09:17:06 -0000	1.16
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/udisks
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v 1.15 2010/08/20 17:08:15 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v 1.16 2010/08/21 09:17:06 ssuominen Exp $
+
+*udisks-1.0.1-r2 (21 Aug 2010)
+
+  21 Aug 2010; Samuli Suominen <ssuominen@g.o>
+  +udisks-1.0.1-r2.ebuild, +files/udisks-1.0.1-no-floppy.patch:
+  Fix long hangs on probing nonexistant floppies.
 
   20 Aug 2010; Jeroen Roovers <jer@g.o> udisks-1.0.1-r1.ebuild:
   Move from sys-apps/parted to sys-block/parted.



1.1                  sys-fs/udisks/udisks-1.0.1-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/udisks-1.0.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/udisks-1.0.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: udisks-1.0.1-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/udisks-1.0.1-r2.ebuild,v 1.1 2010/08/21 09:17:06 ssuominen Exp $

EAPI=3
inherit eutils bash-completion

DESCRIPTION="Daemon providing interfaces to work with storage devices"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/udisks"
SRC_URI="http://hal.freedesktop.org/releases/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="debug doc nls remote-access"

COMMON_DEPEND=">=sys-fs/udev-147[extras]
	>=dev-libs/glib-2.16.1:2
	>=sys-apps/dbus-1
	>=dev-libs/dbus-glib-0.82
	>=sys-auth/polkit-0.92
	>=sys-block/parted-1.8.8[device-mapper]
	>=sys-fs/lvm2-2.02.66
	>=dev-libs/libatasmart-0.14
	>=sys-apps/sg3_utils-1.27.20090411
	!sys-apps/devicekit-disks"
RDEPEND="${COMMON_DEPEND}
	remote-access? ( net-dns/avahi )"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
	dev-libs/libxslt
	app-text/docbook-xsl-stylesheets
	doc? ( dev-util/gtk-doc
		app-text/docbook-xml-dtd:4.1.2 )
	nls? ( >=dev-util/intltool-0.40.0 )"

# This would require running dbus and also sudo.
RESTRICT="test"

src_prepare() {
	epatch "${FILESDIR}"/${P}-lvm2_api_support.patch \
		"${FILESDIR}"/${P}-no-floppy.patch
}

src_configure() {
	econf \
		--localstatedir="${EPREFIX}/var" \
		--disable-dependency-tracking \
		--disable-static \
		$(use_enable debug verbose-mode) \
		--enable-man-pages \
		$(use_enable doc gtk-doc) \
		$(use_enable remote-access) \
		$(use_enable nls) \
		--with-html-dir="${EPREFIX}/usr/share/doc/${PF}/html"
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS HACKING NEWS README

	rm -f "${ED}"/etc/profile.d/udisks-bash-completion.sh
	dobashcompletion tools/udisks-bash-completion.sh ${PN}

	find "${ED}" -name '*.la' -delete
	keepdir /media
}