[gentoo-commits] gentoo-x86 commit in dev-libs/libgit2: libgit2-0.22.3.ebuild ChangeLog libgit2-9999.ebuild

[Tim Harder (radhermit)]

radhermit    15/07/03 03:36:09

  Modified:             ChangeLog libgit2-9999.ebuild
  Added:                libgit2-0.22.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.33                 dev-libs/libgit2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libgit2/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	29 May 2015 05:39:18 -0000	1.32
+++ ChangeLog	3 Jul 2015 03:36:09 -0000	1.33
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libgit2
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgit2/ChangeLog,v 1.32 2015/05/29 05:39:18 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgit2/ChangeLog,v 1.33 2015/07/03 03:36:09 radhermit Exp $
+
+*libgit2-0.22.3 (03 Jul 2015)
+
+  03 Jul 2015; Tim Harder <radhermit@g.o> +libgit2-0.22.3.ebuild,
+  libgit2-9999.ebuild:
+  Version bump.
 
 *libgit2-9999 (29 May 2015)
 



1.2                  dev-libs/libgit2/libgit2-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/libgit2-9999.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/libgit2-9999.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/libgit2-9999.ebuild?r1=1.1&r2=1.2

Index: libgit2-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libgit2/libgit2-9999.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- libgit2-9999.ebuild	29 May 2015 05:39:18 -0000	1.1
+++ libgit2-9999.ebuild	3 Jul 2015 03:36:09 -0000	1.2
@@ -1,19 +1,24 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgit2/libgit2-9999.ebuild,v 1.1 2015/05/29 05:39:18 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgit2/libgit2-9999.ebuild,v 1.2 2015/07/03 03:36:09 radhermit Exp $
 
 EAPI=5
 
-EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
-inherit cmake-utils git-r3 multilib
+inherit cmake-utils multilib
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~ppc-macos"
+fi
 
 DESCRIPTION="A linkable library for Git"
 HOMEPAGE="http://libgit2.github.com/"
-SRC_URI=""
 
 LICENSE="GPL-2-with-linking-exception"
-SLOT="0/22"
-KEYWORDS=""
+SLOT="0/23"
 IUSE="examples gssapi ssh test threads trace"
 
 RDEPEND="



1.1                  dev-libs/libgit2/libgit2-0.22.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/libgit2-0.22.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/libgit2-0.22.3.ebuild?rev=1.1&content-type=text/plain

Index: libgit2-0.22.3.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgit2/libgit2-0.22.3.ebuild,v 1.1 2015/07/03 03:36:09 radhermit Exp $

EAPI=5

inherit cmake-utils multilib

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
	inherit git-r3
else
	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~x86 ~ppc-macos"
fi

DESCRIPTION="A linkable library for Git"
HOMEPAGE="http://libgit2.github.com/"

LICENSE="GPL-2-with-linking-exception"
SLOT="0/22"
IUSE="examples gssapi ssh test threads trace"

RDEPEND="
	dev-libs/openssl:0
	sys-libs/zlib
	net-libs/http-parser
	gssapi? ( virtual/krb5 )
	ssh? ( net-libs/libssh2 )
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
"

DOCS=( AUTHORS CONTRIBUTING.md CONVENTIONS.md README.md )

src_prepare() {
	# skip online tests
	sed -i '/libgit2_clar/s/-ionline/-xonline/' CMakeLists.txt || die

	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DLIB_INSTALL_DIR="${EPREFIX}/usr/$(get_libdir)"
		$(cmake-utils_use_build test CLAR)
		$(cmake-utils_use_enable trace TRACE)
		$(cmake-utils_use_use gssapi GSSAPI)
		$(cmake-utils_use_use ssh SSH)
		$(cmake-utils_use threads THREADSAFE)
	)
	cmake-utils_src_configure
}

src_test() {
	if [[ ${EUID} -eq 0 ]] ; then
		# repo::iterator::fs_preserves_error fails if run as root
		# since root can still access dirs with 0000 perms
		ewarn "Skipping tests: non-root privileges are required for all tests to pass"
	else
		local TEST_VERBOSE=1
		cmake-utils_src_test
	fi
}

src_install() {
	cmake-utils_src_install

	if use examples ; then
		find examples -name .gitignore -delete || die
		dodoc -r examples
		docompress -x /usr/share/doc/${PF}/examples
	fi
}