[gentoo-commits] repo/gentoo:master commit in: net-libs/ortp/

[Pacho Ramos]

commit:     81436a875a39e0afaf17f500b50b1b7d20e92602
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Oct  9 15:36:03 2016 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Oct  9 16:18:38 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=81436a87

net-libs/ortp: Support libressl (#565236)

Package-Manager: portage-2.3.1

 net-libs/ortp/ortp-0.23.0-r1.ebuild | 81 +++++++++++++++++++++++++++++++++++++
 1 file changed, 81 insertions(+)

diff --git a/net-libs/ortp/ortp-0.23.0-r1.ebuild b/net-libs/ortp/ortp-0.23.0-r1.ebuild
new file mode 100644
index 00000000..bdc1b15
--- /dev/null
+++ b/net-libs/ortp/ortp-0.23.0-r1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="Open Real-time Transport Protocol (RTP, RFC3550) stack"
+HOMEPAGE="http://www.linphone.org/"
+SRC_URI="mirror://nongnu/linphone/${PN}/sources/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/9"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~ppc-macos ~x64-macos ~x86-macos"
+
+IUSE="debug doc examples ipv6 libressl minimal ntp-timestamp ssl srtp zrtp"
+REQUIRED_USE="zrtp? ( srtp )"
+
+RDEPEND="
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= ) )
+	srtp? ( net-libs/libsrtp:0= )
+	zrtp? ( >=net-libs/libzrtpcpp-4.0.0:0= )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	# ${P} is added after ${docdir}
+	if use doc; then
+		sed -i -e 's/$(docdir)\/$(PACKAGE)-$(VERSION)/$(docdir)/' Makefile.in \
+			|| die "patching Makefile.in failed"
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		# memcheck is for HP-UX only
+		--disable-memcheck
+		# mode64bit adds +DA2.0W +DS2.0 CFLAGS wich are needed for HP-UX
+		--disable-mode64bit
+		# strict adds -Werror, do not want it
+		--disable-strict
+		# they seriously failed to understand AC_ARG_ENABLE...
+		--disable-tests_enabled
+		--enable-fast-install
+		--enable-libtool-lock
+		# this is fine as long as we do not link to polarssl
+		--enable-broken-srtp
+
+		$(use_enable debug)
+		$(use_enable ipv6)
+		$(use_enable minimal perf)
+		$(use_enable ntp-timestamp)
+		$(use_enable ssl ssl-hmac)
+		$(use_enable zrtp)
+
+		--with-srtp=$(usex srtp "${EPREFIX}"/usr none)
+		$(use doc || echo ac_cv_path_DOXYGEN=false)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdocdir="${EPREFIX}"/usr/share/doc/${PF} \
+		install
+
+	einstalldocs
+
+	prune_libtool_files
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins src/tests/*.c
+	fi
+}