[gentoo-commits] repo/gentoo:master commit in: media-tv/kodi/

[Craig Andrews]

commit:     ab1153c42eadaa23ec67fd70be5264e0d51b539a
Author:     Craig Andrews <candrews <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 17 15:33:26 2019 +0000
Commit:     Craig Andrews <candrews <AT> gentoo <DOT> org>
CommitDate: Sun Feb 17 15:34:51 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ab1153c4

media-tv/kodi: 18.1 version bump

Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Craig Andrews <candrews <AT> gentoo.org>

 media-tv/kodi/Manifest         |   1 +
 media-tv/kodi/kodi-18.1.ebuild | 320 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 321 insertions(+)

diff --git a/media-tv/kodi/Manifest b/media-tv/kodi/Manifest
index 89c5526111b..6d877b04c26 100644
--- a/media-tv/kodi/Manifest
+++ b/media-tv/kodi/Manifest
@@ -11,6 +11,7 @@ DIST kodi-18.0rc2.tar.gz 50969888 BLAKE2B 982d660c6f87706fa5d50c5ece84ea3d27adcd
 DIST kodi-18.0rc3.tar.gz 50978485 BLAKE2B 791053553f475dbcacc2bc7c3a1e420849de3f48d3eb3d788f958b2b2c3fb47454cfd909f36cefee37050923c39173690b5d48d517a042254d796aeafb39fcb8 SHA512 622e3fff01e8d856bb524339796410d3fc3226539ae91c69a367464e8f5aeb28ca3ffd605dc4a4f9944e4cc59a1949d7da6fec70175d978a44f3b5bbb59190c3
 DIST kodi-18.0rc4.tar.gz 50985659 BLAKE2B 5b2475d98e084e007aebf0a5e142d03ddd08b11c9067ddf0c978892ce15a4b8f22009156bfe4e26df1ebab55bf724182c4573207440e1e9f50dd5f6b739f8a3e SHA512 cec2af70e6babed79ed649846342cbcfe979ad90a4ef4dde250e114477991c48dcfffac56a6234dc16913c9896a9a31337ebbb19488f0abf68e6c1f410d12607
 DIST kodi-18.0rc5.tar.gz 50988431 BLAKE2B 4abf13057e04f1cc3f600bbedaa9f5d641a0af59d283817410aa38c41141d8835b8ce59ac3a851e1f59752396236dd195e7ace5f233ad22127597c8a964986f4 SHA512 d5eca9c4c7380c93d1339187017c36ad8424a7484cbe0f77281c561e37896e44a36da534a894ecd30fc4eea43fc0b1703bb0e545d04d5f8c7c93eaae23066884
+DIST kodi-18.1.tar.gz 51001112 BLAKE2B 65de0adff0e387821f0043156a20da2d99feb6c1d2390efa5d16c7e3bdc1f724024c0d00781be59b16a78a73b5ebb2d16602f806d32c95362732114279d42d71 SHA512 2df32e14e1138474cf0a1b8102b4c734e1a54799b1aab049cfe9f623f467e0c9eb87237b4c81ded280e72bc4655a27a887904d164927b3fd227a9c9311531ebc
 DIST kodi-18.1rc1.tar.gz 51006614 BLAKE2B f547b72d84943ea48be54640c2569df11a779f5fd0e8f7ca822e6c85d78f20f1945d67dc277dc175a7f5534bf2694e6f6893e6e22a3002382ed7924b8b6b8cdc SHA512 1d9fff991ec0e72f9a23179269c0ea6ab5729bf0904eaeb7154a200ee8acf38043a7ef319eb603fef9db02367b7a98356f571df8397a23672673bc0f26070cec
 DIST libdvdcss-1.4.2-Leia-Beta-5.tar.gz 101068 BLAKE2B 283aa2cec0a2200d3569bc280cb9659e9224a6b3a77db8a35b269cd8caf1337ac9d8b92b806df66f63ef7458a46bd6261f0b8b14678b10e26644a79dcbeea5da SHA512 5185dbdbeb1bd13ea9d8723f1f4ab599d6f3102f5ba1096cd085aa1cda252c045f327c719227bba8e1b742352ade5e335106c8d0c1637a5a6b93ce661620dd7e
 DIST libdvdcss-2f12236bc1c92f73c21e973363f79eb300de603f.tar.gz 95395 BLAKE2B fb3973e098201d177309ad7ca50131725eee4bc6f30f425efa5fea406411f6143ba03abd82cd6c91a250419d3e0a29aafcbf981ba015f6e14cd0ceb001222c12 SHA512 12ba7aa653fcb26d5336bf2a8110c924d634cec79f684bbf19dc38ea33f69fb68c22c97f4c09e5ca7c35f95f6c324a6d70ccc2c501a99122a9321cafd33b2cd9

diff --git a/media-tv/kodi/kodi-18.1.ebuild b/media-tv/kodi/kodi-18.1.ebuild
new file mode 100644
index 00000000000..46debc7cf61
--- /dev/null
+++ b/media-tv/kodi/kodi-18.1.ebuild
@@ -0,0 +1,320 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+PYTHON_REQ_USE="libressl?,sqlite,ssl"
+LIBDVDCSS_VERSION="1.4.2-Leia-Beta-5"
+LIBDVDREAD_VERSION="6.0.0-Leia-Alpha-3"
+LIBDVDNAV_VERSION="6.0.0-Leia-Alpha-3"
+FFMPEG_VERSION="4.0.3"
+CODENAME="Leia"
+FFMPEG_KODI_VERSION="RC5"
+SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz -> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
+	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz -> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
+	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz -> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
+	!system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
+
+if [[ ${PV} == *9999 ]] ; then
+	PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+	EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
+	inherit git-r3
+else
+	PYTHON_COMPAT=( python2_7 )
+	MY_PV=${PV/_p/_r}
+	MY_PV=${MY_PV/_alpha/a}
+	MY_PV=${MY_PV/_beta/b}
+	MY_PV=${MY_PV/_rc/rc}
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
+fi
+
+inherit autotools cmake-utils eutils gnome2-utils linux-info pax-utils python-single-r1 xdg-utils
+
+DESCRIPTION="A free and open source media-player and entertainment hub"
+HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+# use flag is called libusb so that it doesn't fool people in thinking that
+# it is _required_ for USB support. Otherwise they'll disable udev and
+# that's going to be worse.
+IUSE="airplay alsa bluetooth bluray caps cec +css dbus dvd gbm gles lcms libressl libusb lirc mariadb mysql nfs +opengl pulseaudio samba systemd +system-ffmpeg test +udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( gles opengl )
+	^^ ( gbm wayland X )
+	?? ( mariadb mysql )
+	udev? ( !libusb )
+	udisks? ( dbus )
+	upower? ( dbus )
+"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	airplay? (
+		>=app-pda/libplist-2.0.0
+		net-libs/shairplay
+	)
+	alsa? ( >=media-libs/alsa-lib-1.1.4.1 )
+	bluetooth? ( net-wireless/bluez )
+	bluray? ( >=media-libs/libbluray-1.0.2 )
+	caps? ( sys-libs/libcap )
+	dbus? ( sys-apps/dbus )
+	dev-db/sqlite
+	dev-libs/expat
+	dev-libs/flatbuffers
+	>=dev-libs/fribidi-0.19.7
+	cec? ( >=dev-libs/libcec-4.0 )
+	dev-libs/libpcre[cxx]
+	>=dev-libs/libinput-1.10.5
+	>=dev-libs/libxml2-2.9.4
+	>=dev-libs/lzo-2.04
+	dev-libs/tinyxml[stl]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/pycryptodome[${PYTHON_USEDEP}]' 'python3*')
+	>=dev-libs/libcdio-0.94
+	dev-libs/libfmt
+	dev-libs/libfstrcmp
+	gbm? (	media-libs/mesa[gbm] )
+	gles? ( media-libs/mesa[gles2] )
+	lcms? ( media-libs/lcms:2 )
+	libusb? ( virtual/libusb:1 )
+	virtual/ttf-fonts
+	media-fonts/roboto
+	>=media-libs/fontconfig-2.12.4
+	>=media-libs/freetype-2.8
+	>=media-libs/libass-0.13.4
+	media-libs/mesa[egl]
+	>=media-libs/taglib-1.11.1
+	system-ffmpeg? (
+		>=media-video/ffmpeg-${FFMPEG_VERSION}:=[encode,postproc]
+		libressl? ( media-video/ffmpeg[libressl,-openssl] )
+		!libressl? ( media-video/ffmpeg[-libressl,openssl] )
+	)
+	mysql? ( dev-db/mysql-connector-c:= )
+	mariadb? ( dev-db/mariadb-connector-c:= )
+	>=net-misc/curl-7.56.1
+	nfs? ( >=net-fs/libnfs-2.0.0:= )
+	opengl? ( media-libs/glu )
+	!libressl? ( >=dev-libs/openssl-1.0.2l:0= )
+	libressl? ( dev-libs/libressl:0= )
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
+	>=sys-libs/zlib-1.2.11
+	udev? ( virtual/udev )
+	vaapi? (
+		x11-libs/libva:=
+		opengl? ( x11-libs/libva[opengl] )
+		system-ffmpeg? ( media-video/ffmpeg[vaapi] )
+		vdpau? ( x11-libs/libva[vdpau] )
+		wayland? ( x11-libs/libva[wayland] )
+		X? ( x11-libs/libva[X] )
+	)
+	virtual/libiconv
+	vdpau? (
+		|| ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
+		system-ffmpeg? ( media-video/ffmpeg[vdpau] )
+	)
+	wayland? (
+		>=dev-cpp/waylandpp-0.2.3:=
+		media-libs/mesa[wayland]
+		>=dev-libs/wayland-protocols-1.7
+		>=x11-libs/libxkbcommon-0.4.1
+	)
+	webserver? ( >=net-libs/libmicrohttpd-0.9.55[messages] )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXrandr
+		x11-libs/libXrender
+		system-ffmpeg? ( media-video/ffmpeg[X] )
+	)
+	x11-libs/libdrm
+	xslt? ( dev-libs/libxslt )
+	zeroconf? ( net-dns/avahi[dbus] )
+"
+RDEPEND="${COMMON_DEPEND}
+	lirc? ( app-misc/lirc )
+	!media-tv/xbmc
+	udisks? ( sys-fs/udisks:2 )
+	upower? ( sys-power/upower )
+"
+DEPEND="${COMMON_DEPEND}
+	app-arch/bzip2
+	app-arch/xz-utils
+	dev-lang/swig
+	dev-libs/crossguid
+	dev-libs/rapidjson
+	dev-util/cmake
+	dev-util/gperf
+	media-libs/giflib
+	>=media-libs/libjpeg-turbo-1.5.1:=
+	>=media-libs/libpng-1.6.26:0=
+	test? ( dev-cpp/gtest )
+	virtual/pkgconfig
+	virtual/jre
+	x86? ( dev-lang/nasm )
+"
+
+CONFIG_CHECK="~IP_MULTICAST"
+ERROR_IP_MULTICAST="
+In some cases Kodi needs to access multicast addresses.
+Please consider enabling IP_MULTICAST under Networking options.
+"
+
+pkg_setup() {
+	check_extra_config
+	python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999 ]] ; then
+		if python_is_python3; then
+			EGIT_BRANCH="feature_python3"
+			ewarn "Using the experimental Python 3 branch!"
+			ewarn "See https://kodi.wiki/view/Migration_to_Python_3 for more information."
+			ewarn "To use the non-experimental Python 2 version:"
+			ewarn "echo '~${CATEGORY}/${P} PYTHON_TARGETS: -* python2_7 PYTHON_SINGLE_TARGET: -* python2_7' >> /etc/portage/package.use"
+			ewarn "then re-merge using: emerge -a =${CATEGORY}/${PF}"
+		fi
+		git-r3_src_unpack
+	else
+		default
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# avoid long delays when powerkit isn't running #348580
+	sed -i \
+		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
+		xbmc/platform/linux/*.cpp || die
+
+	# Prepare tools and libs witch are configured with autotools during compile time
+	AUTOTOOLS_DIRS=(
+		"${S}"/lib/cpluff
+		"${S}"/tools/depends/native/TexturePacker/src
+		"${S}"/tools/depends/native/JsonSchemaBuilder/src
+	)
+
+	local d
+	for d in "${AUTOTOOLS_DIRS[@]}" ; do
+		pushd ${d} >/dev/null || die
+		AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
+		popd >/dev/null || die
+	done
+	elibtoolize
+
+	# Prevent autoreconf rerun
+	sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
+		"${S}"/cmake/modules/FindCpluff.cmake \
+		"${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
+		"${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
+		|| die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+		-DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
+		-DENABLE_ALSA=$(usex alsa)
+		-DENABLE_AIRTUNES=$(usex airplay)
+		-DENABLE_AVAHI=$(usex zeroconf)
+		-DENABLE_BLUETOOTH=$(usex bluetooth)
+		-DENABLE_BLURAY=$(usex bluray)
+		-DENABLE_CCACHE=OFF
+		-DENABLE_CEC=$(usex cec)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DVDCSS=$(usex css)
+		-DENABLE_INTERNAL_CROSSGUID=OFF
+		-DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
+		-DENABLE_INTERNAL_FSTRCMP=OFF
+		-DENABLE_CAP=$(usex caps)
+		-DENABLE_LCMS2=$(usex lcms)
+		-DENABLE_LIRCCLIENT=$(usex lirc)
+		-DENABLE_MARIADBCLIENT=$(usex mariadb)
+		-DENABLE_MYSQLCLIENT=$(usex mysql)
+		-DENABLE_MICROHTTPD=$(usex webserver)
+		-DENABLE_MYSQLCLIENT=$(usex mysql)
+		-DENABLE_NFS=$(usex nfs)
+		-DENABLE_OPENGLES=$(usex gles)
+		-DENABLE_OPENGL=$(usex opengl)
+		-DENABLE_OPTICAL=$(usex dvd)
+		-DENABLE_PLIST=$(usex airplay)
+		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
+		-DENABLE_SMBCLIENT=$(usex samba)
+		-DENABLE_UDEV=$(usex udev)
+		-DENABLE_UPNP=$(usex upnp)
+		-DENABLE_VAAPI=$(usex vaapi)
+		-DENABLE_VDPAU=$(usex vdpau)
+		-DENABLE_XSLT=$(usex xslt)
+		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
+		-Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz"
+		-Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz"
+	)
+
+	use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
+
+	if use system-ffmpeg; then
+		mycmakeargs+=( -DWITH_FFMPEG="yes" )
+	else
+		mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
+	fi
+
+	if use gbm; then
+		mycmakeargs+=(
+			-DCORE_PLATFORM_NAME="gbm"
+			-DGBM_RENDER_SYSTEM="$(usex opengl gl gles)"
+		)
+	fi
+
+	if use wayland; then
+		mycmakeargs+=(
+			-DCORE_PLATFORM_NAME="wayland"
+			-DWAYLAND_RENDER_SYSTEM="$(usex opengl gl gles)"
+		)
+	fi
+
+	if use X; then
+		mycmakeargs+=( -DCORE_PLATFORM_NAME="x11" )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile all
+	use test && emake -C "${BUILD_DIR}" kodi-test
+}
+
+src_test() {
+	emake -C "${BUILD_DIR}" test
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	pax-mark Em "${ED%/}"/usr/$(get_libdir)/${PN}/${PN}.bin
+
+	newicon media/icon48x48.png kodi.png
+
+	rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
+	dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
+		usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
+
+	python_domodule tools/EventClients/lib/python/xbmcclient.py
+	python_newscript "tools/EventClients/Clients/KodiSend/kodi-send.py" kodi-send
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}