1 |
commit: 85a026cc56d91933fe75c7f507f7a6190d8015aa |
2 |
Author: Craig Andrews <candrews <AT> gentoo <DOT> org> |
3 |
AuthorDate: Tue Sep 1 19:22:23 2020 +0000 |
4 |
Commit: Craig Andrews <candrews <AT> gentoo <DOT> org> |
5 |
CommitDate: Tue Sep 1 19:22:38 2020 +0000 |
6 |
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=85a026cc |
7 |
|
8 |
media-tv/kodi: Re-add 18.8 |
9 |
|
10 |
Package-Manager: Portage-3.0.5, Repoman-3.0.1 |
11 |
Signed-off-by: Craig Andrews <candrews <AT> gentoo.org> |
12 |
|
13 |
media-tv/kodi/Manifest | 1 + |
14 |
media-tv/kodi/kodi-18.8.ebuild | 319 +++++++++++++++++++++++++++++++++++++++++ |
15 |
2 files changed, 320 insertions(+) |
16 |
|
17 |
diff --git a/media-tv/kodi/Manifest b/media-tv/kodi/Manifest |
18 |
index bcf8587bbc1..7cb3c827c14 100644 |
19 |
--- a/media-tv/kodi/Manifest |
20 |
+++ b/media-tv/kodi/Manifest |
21 |
@@ -2,6 +2,7 @@ DIST ffmpeg-kodi-4.0.4-Leia-18.4.tar.gz 12430413 BLAKE2B 6de6fde2c16264f851466b4 |
22 |
DIST ffmpeg-kodi-4.3-Matrix-Alpha1.tar.gz 13478011 BLAKE2B 6219293fba86981c34c22b1a91c6dce0c298d523ecafe2e0ddce8b1ec4213d4f8f65610e4555a124a582d7fa8e858d0ad6921015fa4e639d64a02e955f7faf46 SHA512 23220650b550fe2008c38c955e10baf55e1ceaac780cf170db5349b156ac399ff3eda39509773f0c973c50083e75823b1da8e92b3751c04bb06a7f5687bef850 |
23 |
DIST kodi-18-libmicrohttpd-0.9.71.patch 84981 BLAKE2B e07c7df63bdfbaf9dfc5d0989adf96eb663a8c99ea11c42dfc585d8b91343a3445e9bc2f1797e845b0895e79568526e8e594a76e8cb3d7b591153a0ad45ce807 SHA512 286a1466174d847eac460b2a7a1b66b082148f2a3e91c4f5f881b909a59b8fdb2037eda074bd3c6e5dbe6a65dc2bef9f1d6746d7db2cb78d285c4b7750c366c2 |
24 |
DIST kodi-18.7.tar.gz 51051040 BLAKE2B 7ff04cd0ddcf74e46eef4318cf870662b9e076b362322958a6b8019d49134e37981f7ca21b5806e38b942adc4c29ea2b25a19f46e5da3d469613cf19a29f4e8c SHA512 7e5678f5e23e8af929056a49b0ce0b992a1f53a1fe970a149610c5a24adb591085bb06cc405e8bdc6040eef853d23e99df660d7006fc1ea4e79afd3a697875c5 |
25 |
+DIST kodi-18.8.tar.gz 51052219 BLAKE2B 6e49b08b5e2bfe778dafb687658e82b90226a9f1c1a7827a4290d601fe4c98e5cbaabaa39563c19a2956b83ce3a76640f081a56a41dfea4d65fb8b503c6f37b0 SHA512 242eaa9144ba0d9b15f02ab41282295de76d375cf66d595e7f6687d47c996133fcf5647448dcd06759df9f30bd86cdba239720b9bdd8b57827b6f261c08c4aaa |
26 |
DIST kodi-19.0_alpha1_p20200830.tar.gz 51683611 BLAKE2B 8957e76bc0558d5ba8efb4c9884021b644376a8fe56d1d23086485d596d5f91ccf110bdbe2fdb9fd650da03eed5558fb55dd017ef1550b2b676b2baeae13c554 SHA512 4a9c407b2a0384297083bbfa279dda07fd70489e2da45542182a8faf9f1fbe92fb17f6aa9b8b14f8e95d7e00b5edd732587667649d91ff89b2ff43f3da95b32f |
27 |
DIST libdvdcss-1.4.2-Leia-Beta-5.tar.gz 101068 BLAKE2B 283aa2cec0a2200d3569bc280cb9659e9224a6b3a77db8a35b269cd8caf1337ac9d8b92b806df66f63ef7458a46bd6261f0b8b14678b10e26644a79dcbeea5da SHA512 5185dbdbeb1bd13ea9d8723f1f4ab599d6f3102f5ba1096cd085aa1cda252c045f327c719227bba8e1b742352ade5e335106c8d0c1637a5a6b93ce661620dd7e |
28 |
DIST libdvdnav-6.0.0-Leia-Alpha-3.tar.gz 137942 BLAKE2B 7573434a0ae8e8ccabf48173f81fcde29074eb138e119a2ae9156cde3c3d8bfd716f5d0e605b97f2dcac21f570781137c8533c5ae306b51e3905822fda318355 SHA512 11c93eaacd156f8fd7dec7c43d366438b201f31ad55b2870463a9e286912b6ada08882319a021fb7992190f87b909a49f2b83e0321cc17aedc29f7fe5898fa72 |
29 |
|
30 |
diff --git a/media-tv/kodi/kodi-18.8.ebuild b/media-tv/kodi/kodi-18.8.ebuild |
31 |
new file mode 100644 |
32 |
index 00000000000..4311cb82d79 |
33 |
--- /dev/null |
34 |
+++ b/media-tv/kodi/kodi-18.8.ebuild |
35 |
@@ -0,0 +1,319 @@ |
36 |
+# Copyright 1999-2020 Gentoo Authors |
37 |
+# Distributed under the terms of the GNU General Public License v2 |
38 |
+ |
39 |
+EAPI=7 |
40 |
+ |
41 |
+PYTHON_REQ_USE="libressl?,sqlite,ssl" |
42 |
+LIBDVDCSS_VERSION="1.4.2-Leia-Beta-5" |
43 |
+LIBDVDREAD_VERSION="6.0.0-Leia-Alpha-3" |
44 |
+LIBDVDNAV_VERSION="6.0.0-Leia-Alpha-3" |
45 |
+FFMPEG_VERSION="4.0.4" |
46 |
+CODENAME="Leia" |
47 |
+FFMPEG_KODI_VERSION="18.4" |
48 |
+SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz -> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz |
49 |
+ https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz -> libdvdread-${LIBDVDREAD_VERSION}.tar.gz |
50 |
+ https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz -> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz |
51 |
+ !system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz ) |
52 |
+ https://dev.gentoo.org/~candrews/kodi-18-libmicrohttpd-0.9.71.patch" |
53 |
+ |
54 |
+if [[ ${PV} == *9999 ]] ; then |
55 |
+ PYTHON_COMPAT=( python2_7 python3_{6,7} ) |
56 |
+ EGIT_REPO_URI="https://github.com/xbmc/xbmc.git" |
57 |
+ inherit git-r3 |
58 |
+else |
59 |
+ PYTHON_COMPAT=( python2_7 ) |
60 |
+ MY_PV=${PV/_p/_r} |
61 |
+ MY_PV=${MY_PV/_alpha/a} |
62 |
+ MY_PV=${MY_PV/_beta/b} |
63 |
+ MY_PV=${MY_PV/_rc/rc} |
64 |
+ MY_P="${PN}-${MY_PV}" |
65 |
+ SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz" |
66 |
+ KEYWORDS="~amd64 ~arm ~arm64 ~x86" |
67 |
+ S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME} |
68 |
+fi |
69 |
+ |
70 |
+inherit autotools cmake desktop linux-info pax-utils python-single-r1 xdg |
71 |
+ |
72 |
+DESCRIPTION="A free and open source media-player and entertainment hub" |
73 |
+HOMEPAGE="https://kodi.tv/ https://kodi.wiki/" |
74 |
+ |
75 |
+LICENSE="GPL-2+" |
76 |
+SLOT="0" |
77 |
+# use flag is called libusb so that it doesn't fool people in thinking that |
78 |
+# it is _required_ for USB support. Otherwise they'll disable udev and |
79 |
+# that's going to be worse. |
80 |
+IUSE="airplay alsa bluetooth bluray caps cec +css dbus dvd gbm gles lcms libressl libusb lirc mariadb mysql nfs +opengl pulseaudio raspberry-pi samba systemd +system-ffmpeg test +udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf" |
81 |
+REQUIRED_USE=" |
82 |
+ ${PYTHON_REQUIRED_USE} |
83 |
+ || ( gles opengl ) |
84 |
+ ^^ ( gbm raspberry-pi wayland X ) |
85 |
+ ?? ( mariadb mysql ) |
86 |
+ udev? ( !libusb ) |
87 |
+ udisks? ( dbus ) |
88 |
+ upower? ( dbus ) |
89 |
+" |
90 |
+RESTRICT="!test? ( test )" |
91 |
+ |
92 |
+COMMON_DEPEND="${PYTHON_DEPS} |
93 |
+ airplay? ( |
94 |
+ >=app-pda/libplist-2.0.0 |
95 |
+ net-libs/shairplay |
96 |
+ ) |
97 |
+ alsa? ( >=media-libs/alsa-lib-1.1.4.1 ) |
98 |
+ bluetooth? ( net-wireless/bluez ) |
99 |
+ bluray? ( >=media-libs/libbluray-1.0.2 ) |
100 |
+ caps? ( sys-libs/libcap ) |
101 |
+ dbus? ( sys-apps/dbus ) |
102 |
+ dev-db/sqlite |
103 |
+ dev-libs/expat |
104 |
+ dev-libs/flatbuffers |
105 |
+ >=dev-libs/fribidi-0.19.7 |
106 |
+ cec? ( >=dev-libs/libcec-4.0[raspberry-pi?] ) |
107 |
+ dev-libs/libpcre[cxx] |
108 |
+ >=dev-libs/libinput-1.10.5 |
109 |
+ >=dev-libs/libxml2-2.9.4 |
110 |
+ >=dev-libs/lzo-2.04 |
111 |
+ dev-libs/tinyxml[stl] |
112 |
+ $(python_gen_cond_dep 'dev-python/pillow[${PYTHON_MULTI_USEDEP}]') |
113 |
+ $(python_gen_cond_dep 'dev-python/pycryptodome[${PYTHON_MULTI_USEDEP}]' 'python3*') |
114 |
+ >=dev-libs/libcdio-0.94 |
115 |
+ >=dev-libs/libfmt-3.0.1 |
116 |
+ dev-libs/libfstrcmp |
117 |
+ gbm? ( media-libs/mesa[gbm] ) |
118 |
+ gles? ( |
119 |
+ !raspberry-pi? ( media-libs/mesa[gles2] ) |
120 |
+ ) |
121 |
+ lcms? ( media-libs/lcms:2 ) |
122 |
+ libusb? ( virtual/libusb:1 ) |
123 |
+ virtual/ttf-fonts |
124 |
+ media-fonts/roboto |
125 |
+ >=media-libs/fontconfig-2.12.4 |
126 |
+ >=media-libs/freetype-2.8 |
127 |
+ >=media-libs/libass-0.13.4 |
128 |
+ !raspberry-pi? ( media-libs/mesa[egl,X(+)] ) |
129 |
+ >=media-libs/taglib-1.11.1 |
130 |
+ system-ffmpeg? ( |
131 |
+ >=media-video/ffmpeg-${FFMPEG_VERSION}:=[encode,postproc] |
132 |
+ libressl? ( media-video/ffmpeg[libressl,-openssl] ) |
133 |
+ !libressl? ( media-video/ffmpeg[-libressl,openssl] ) |
134 |
+ ) |
135 |
+ mysql? ( dev-db/mysql-connector-c:= ) |
136 |
+ mariadb? ( dev-db/mariadb-connector-c:= ) |
137 |
+ >=net-misc/curl-7.56.1[http2] |
138 |
+ nfs? ( >=net-fs/libnfs-2.0.0:= ) |
139 |
+ opengl? ( media-libs/glu ) |
140 |
+ !libressl? ( >=dev-libs/openssl-1.0.2l:0= ) |
141 |
+ libressl? ( dev-libs/libressl:0= ) |
142 |
+ raspberry-pi? ( |
143 |
+ || ( media-libs/raspberrypi-userland media-libs/raspberrypi-userland-bin media-libs/mesa[egl,gles2,video_cards_vc4] ) |
144 |
+ ) |
145 |
+ pulseaudio? ( media-sound/pulseaudio ) |
146 |
+ samba? ( >=net-fs/samba-3.4.6[smbclient(+)] ) |
147 |
+ >=sys-libs/zlib-1.2.11 |
148 |
+ udev? ( virtual/udev ) |
149 |
+ vaapi? ( |
150 |
+ x11-libs/libva:= |
151 |
+ opengl? ( x11-libs/libva[opengl] ) |
152 |
+ system-ffmpeg? ( media-video/ffmpeg[vaapi] ) |
153 |
+ vdpau? ( x11-libs/libva[vdpau] ) |
154 |
+ wayland? ( x11-libs/libva[wayland] ) |
155 |
+ X? ( x11-libs/libva[X] ) |
156 |
+ ) |
157 |
+ virtual/libiconv |
158 |
+ vdpau? ( |
159 |
+ || ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 ) |
160 |
+ system-ffmpeg? ( media-video/ffmpeg[vdpau] ) |
161 |
+ ) |
162 |
+ wayland? ( |
163 |
+ >=dev-cpp/waylandpp-0.2.3:= |
164 |
+ media-libs/mesa[wayland] |
165 |
+ >=dev-libs/wayland-protocols-1.7 |
166 |
+ ) |
167 |
+ webserver? ( >=net-libs/libmicrohttpd-0.9.55[messages(+)] ) |
168 |
+ X? ( |
169 |
+ x11-libs/libX11 |
170 |
+ x11-libs/libXrandr |
171 |
+ x11-libs/libXrender |
172 |
+ system-ffmpeg? ( media-video/ffmpeg[X] ) |
173 |
+ ) |
174 |
+ x11-libs/libdrm |
175 |
+ >=x11-libs/libxkbcommon-0.4.1 |
176 |
+ xslt? ( dev-libs/libxslt ) |
177 |
+ zeroconf? ( net-dns/avahi[dbus] ) |
178 |
+" |
179 |
+RDEPEND="${COMMON_DEPEND} |
180 |
+ lirc? ( app-misc/lirc ) |
181 |
+ !media-tv/xbmc |
182 |
+ udisks? ( sys-fs/udisks:2 ) |
183 |
+ upower? ( sys-power/upower ) |
184 |
+" |
185 |
+DEPEND="${COMMON_DEPEND} |
186 |
+ app-arch/bzip2 |
187 |
+ app-arch/xz-utils |
188 |
+ dev-lang/swig |
189 |
+ dev-libs/crossguid |
190 |
+ dev-libs/rapidjson |
191 |
+ dev-util/cmake |
192 |
+ dev-util/gperf |
193 |
+ media-libs/giflib |
194 |
+ >=media-libs/libjpeg-turbo-1.5.1:= |
195 |
+ >=media-libs/libpng-1.6.26:0= |
196 |
+ test? ( dev-cpp/gtest ) |
197 |
+ virtual/pkgconfig |
198 |
+ virtual/jre |
199 |
+ x86? ( dev-lang/nasm ) |
200 |
+" |
201 |
+ |
202 |
+CONFIG_CHECK="~IP_MULTICAST" |
203 |
+ERROR_IP_MULTICAST=" |
204 |
+In some cases Kodi needs to access multicast addresses. |
205 |
+Please consider enabling IP_MULTICAST under Networking options. |
206 |
+" |
207 |
+ |
208 |
+pkg_setup() { |
209 |
+ check_extra_config |
210 |
+ python-single-r1_pkg_setup |
211 |
+} |
212 |
+ |
213 |
+src_unpack() { |
214 |
+ if [[ ${PV} == *9999 ]] ; then |
215 |
+ if python_is_python3; then |
216 |
+ EGIT_BRANCH="feature_python3" |
217 |
+ ewarn "Using the experimental Python 3 branch!" |
218 |
+ ewarn "See https://kodi.wiki/view/Migration_to_Python_3 for more information." |
219 |
+ ewarn "To use the non-experimental Python 2 version:" |
220 |
+ ewarn "echo '~${CATEGORY}/${P} PYTHON_TARGETS: -* python2_7 PYTHON_SINGLE_TARGET: -* python2_7' >> /etc/portage/package.use" |
221 |
+ ewarn "then re-merge using: emerge -a =${CATEGORY}/${PF}" |
222 |
+ fi |
223 |
+ git-r3_src_unpack |
224 |
+ else |
225 |
+ default |
226 |
+ fi |
227 |
+} |
228 |
+ |
229 |
+src_prepare() { |
230 |
+ cmake_src_prepare |
231 |
+ |
232 |
+ # avoid long delays when powerkit isn't running #348580 |
233 |
+ sed -i \ |
234 |
+ -e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \ |
235 |
+ xbmc/platform/linux/*.cpp || die |
236 |
+ |
237 |
+ # Prepare tools and libs witch are configured with autotools during compile time |
238 |
+ AUTOTOOLS_DIRS=( |
239 |
+ "${S}"/lib/cpluff |
240 |
+ "${S}"/tools/depends/native/TexturePacker/src |
241 |
+ "${S}"/tools/depends/native/JsonSchemaBuilder/src |
242 |
+ ) |
243 |
+ |
244 |
+ local d |
245 |
+ for d in "${AUTOTOOLS_DIRS[@]}" ; do |
246 |
+ pushd ${d} >/dev/null || die |
247 |
+ AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf |
248 |
+ popd >/dev/null || die |
249 |
+ done |
250 |
+ elibtoolize |
251 |
+ |
252 |
+ # Prevent autoreconf rerun |
253 |
+ sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \ |
254 |
+ "${S}"/cmake/modules/FindCpluff.cmake \ |
255 |
+ "${S}"/tools/depends/native/TexturePacker/src/autogen.sh \ |
256 |
+ "${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \ |
257 |
+ || die |
258 |
+} |
259 |
+ |
260 |
+src_configure() { |
261 |
+ local mycmakeargs=( |
262 |
+ -Ddocdir="${EPREFIX}/usr/share/doc/${PF}" |
263 |
+ -DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124 |
264 |
+ -DENABLE_ALSA=$(usex alsa) |
265 |
+ -DENABLE_AIRTUNES=$(usex airplay) |
266 |
+ -DENABLE_AVAHI=$(usex zeroconf) |
267 |
+ -DENABLE_BLUETOOTH=$(usex bluetooth) |
268 |
+ -DENABLE_BLURAY=$(usex bluray) |
269 |
+ -DENABLE_CCACHE=OFF |
270 |
+ -DENABLE_CEC=$(usex cec) |
271 |
+ -DENABLE_DBUS=$(usex dbus) |
272 |
+ -DENABLE_DVDCSS=$(usex css) |
273 |
+ -DENABLE_INTERNAL_CROSSGUID=OFF |
274 |
+ -DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)" |
275 |
+ -DENABLE_INTERNAL_FSTRCMP=OFF |
276 |
+ -DENABLE_CAP=$(usex caps) |
277 |
+ -DENABLE_LCMS2=$(usex lcms) |
278 |
+ -DENABLE_LIRCCLIENT=$(usex lirc) |
279 |
+ -DENABLE_MARIADBCLIENT=$(usex mariadb) |
280 |
+ -DENABLE_MICROHTTPD=$(usex webserver) |
281 |
+ -DENABLE_MYSQLCLIENT=$(usex mysql) |
282 |
+ -DENABLE_NFS=$(usex nfs) |
283 |
+ -DENABLE_OPENGLES=$(usex gles) |
284 |
+ -DENABLE_OPENGL=$(usex opengl) |
285 |
+ -DENABLE_OPTICAL=$(usex dvd) |
286 |
+ -DENABLE_PLIST=$(usex airplay) |
287 |
+ -DENABLE_PULSEAUDIO=$(usex pulseaudio) |
288 |
+ -DENABLE_SMBCLIENT=$(usex samba) |
289 |
+ -DENABLE_UDEV=$(usex udev) |
290 |
+ -DENABLE_UPNP=$(usex upnp) |
291 |
+ -DENABLE_VAAPI=$(usex vaapi) |
292 |
+ -DENABLE_VDPAU=$(usex vdpau) |
293 |
+ -DENABLE_XSLT=$(usex xslt) |
294 |
+ -Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz" |
295 |
+ -Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz" |
296 |
+ -Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz" |
297 |
+ ) |
298 |
+ |
299 |
+ use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) ) |
300 |
+ |
301 |
+ if use system-ffmpeg; then |
302 |
+ mycmakeargs+=( -DWITH_FFMPEG="yes" ) |
303 |
+ else |
304 |
+ mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" ) |
305 |
+ fi |
306 |
+ |
307 |
+ if use gbm; then |
308 |
+ mycmakeargs+=( |
309 |
+ -DCORE_PLATFORM_NAME="gbm" |
310 |
+ -DGBM_RENDER_SYSTEM="$(usex opengl gl gles)" |
311 |
+ ) |
312 |
+ fi |
313 |
+ |
314 |
+ if use wayland; then |
315 |
+ mycmakeargs+=( |
316 |
+ -DCORE_PLATFORM_NAME="wayland" |
317 |
+ -DWAYLAND_RENDER_SYSTEM="$(usex opengl gl gles)" |
318 |
+ ) |
319 |
+ fi |
320 |
+ |
321 |
+ if use raspberry-pi; then |
322 |
+ mycmakeargs+=( -DCORE_PLATFORM_NAME="rbpi" ) |
323 |
+ fi |
324 |
+ |
325 |
+ if use X; then |
326 |
+ mycmakeargs+=( -DCORE_PLATFORM_NAME="x11" ) |
327 |
+ fi |
328 |
+ |
329 |
+ cmake_src_configure |
330 |
+} |
331 |
+ |
332 |
+src_compile() { |
333 |
+ cmake_src_compile all |
334 |
+} |
335 |
+ |
336 |
+src_test() { |
337 |
+ # see https://github.com/xbmc/xbmc/issues/17860#issuecomment-630120213 |
338 |
+ KODI_HOME="${BUILD_DIR}" cmake_build check |
339 |
+} |
340 |
+ |
341 |
+src_install() { |
342 |
+ cmake_src_install |
343 |
+ |
344 |
+ pax-mark Em "${ED}"/usr/$(get_libdir)/${PN}/${PN}.bin |
345 |
+ |
346 |
+ newicon media/icon48x48.png kodi.png |
347 |
+ |
348 |
+ rm "${ED}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die |
349 |
+ dosym ../../../../fonts/roboto/Roboto-Thin.ttf \ |
350 |
+ usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf |
351 |
+ |
352 |
+ python_domodule tools/EventClients/lib/python/xbmcclient.py |
353 |
+ python_newscript "tools/EventClients/Clients/KodiSend/kodi-send.py" kodi-send |
354 |
+} |