[gentoo-commits] repo/gentoo:master commit in: dev-python/hatchling/

[Michał Górny]

commit:     40d4ca31fa201b3e5379364ebc3c4826448c034d
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jul  4 04:57:52 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jul  4 05:08:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=40d4ca31

dev-python/hatchling: Bump to 1.4.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/hatchling/Manifest               |  1 +
 dev-python/hatchling/hatchling-1.4.0.ebuild | 74 +++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index 1eb68c12f6f7..65dd4c94ae17 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -1 +1,2 @@
 DIST hatch-hatchling-v1.3.1.gh.tar.gz 220023 BLAKE2B db336126d8c5235eab57ca53e2f8832b9590513f40215ff4b51d1b60c43b0d971b472dc4434cfcf77406143a4ed3172a2fcd95d4c7d11a6f39ccd937f9eff9e6 SHA512 21fa8bd4ffe0bec5ae9f8b9716ce3b7ece45c6a62bc74f0cd49f759baaa5b21343bcc9f2a8e505f0b724b7d73a4c1f84c863a29e064e95f4aa1a288098adc8d3
+DIST hatch-hatchling-v1.4.0.gh.tar.gz 229007 BLAKE2B 5a288a9de356fb06646ebb3eab95aee319d3e7d15a67d4a36cf52d0865a4ecd7ddd1e18db203c55136e950221f79572b152f9edf9398f52ecc927819e5a2f2fd SHA512 a104e092b2078eaeadfd6ea70b65bd8aabc91044e4e9fef4e1a54a61c138629e2a3963f26773e303f3cca0839ea63530849260b2d8c51b50fe67a3cdc5707029

diff --git a/dev-python/hatchling/hatchling-1.4.0.ebuild b/dev-python/hatchling/hatchling-1.4.0.ebuild
new file mode 100644
index 000000000000..868dd0172a97
--- /dev/null
+++ b/dev-python/hatchling/hatchling-1.4.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{8..11} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/pypa/hatch/
+"
+SRC_URI="
+	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/editables-0.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.9[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x EPYTEST_DESELECT=(
+		# these run pip to install stuff
+		tests/backend/dep/test_core.py::test_dependency_found
+		tests/backend/dep/test_core.py::test_extra_met
+		tests/backend/dep/test_core.py::test_extra_no_dependencies
+		tests/backend/dep/test_core.py::test_extra_unmet
+		tests/backend/dep/test_core.py::test_unknown_extra
+		tests/backend/dep/test_core.py::test_version_unmet
+	)
+
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+	epytest tests/backend
+}