[gentoo-commits] repo/gentoo:master commit in: app-cdr/dolphin-plugins-mountiso/

[Andreas Sturmlechner]

commit:     b8e89cde87be9240b37a160c83fac60965dabacb
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 22 18:31:40 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Aug 22 20:11:17 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b8e89cde

app-cdr/dolphin-plugins-mountiso: 22.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-cdr/dolphin-plugins-mountiso/Manifest          |  1 +
 .../dolphin-plugins-mountiso-22.08.0.ebuild        | 64 ++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/app-cdr/dolphin-plugins-mountiso/Manifest b/app-cdr/dolphin-plugins-mountiso/Manifest
index f51a82e4a71c..2cd240b278d7 100644
--- a/app-cdr/dolphin-plugins-mountiso/Manifest
+++ b/app-cdr/dolphin-plugins-mountiso/Manifest
@@ -1 +1,2 @@
 DIST dolphin-plugins-22.04.3.tar.xz 257356 BLAKE2B e3d084e628920a08c9e1173c754002f6b0ecfad07bd4d89a64f5b29a7e93362a814ead6aeff80412b01e7198adce78c36f36428560a1ea9e555027113f7d8e6f SHA512 1b96511fbf8ec93b03a5f204c2e4cff232ca0d09e4d1599c89d4d514deb3fb889dfd3050a5cabe4e35b6e65a5283ad09635a13931c8484eebc98a22ba9057b42
+DIST dolphin-plugins-22.08.0.tar.xz 257872 BLAKE2B 9108b5ac5051b822d8fedac83dab967bd2a344f7d8d3ca8da9a544e40a186ae65a2f6470efce1fe091111392b7a998a8912842c0c31caf64a3e23b7e629ba184 SHA512 047997fa948d4a335495723946855964f6a652f9acf3ffd6f08f78dbfcb8c96a127861164f04f15de963e00295af226041ced7cdb25bd982a6a9f87c7c600855

diff --git a/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-22.08.0.ebuild b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-22.08.0.ebuild
new file mode 100644
index 000000000000..b2e29fdb7873
--- /dev/null
+++ b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-22.08.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="false"
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=5.96.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}