[gentoo-commits] gentoo-x86 commit in app-editors/focuswriter: focuswriter-1.4.4.ebuild ChangeLog

[Julian Ospald (hasufell)]

hasufell    14/02/04 13:43:40

  Modified:             ChangeLog
  Added:                focuswriter-1.4.4.ebuild
  Log:
  version bump wrt #500198
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.18                 app-editors/focuswriter/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/focuswriter/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	20 May 2013 08:37:14 -0000	1.17
+++ ChangeLog	4 Feb 2014 13:43:40 -0000	1.18
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/focuswriter
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/focuswriter/ChangeLog,v 1.17 2013/05/20 08:37:14 ago Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/focuswriter/ChangeLog,v 1.18 2014/02/04 13:43:40 hasufell Exp $
+
+*focuswriter-1.4.4 (04 Feb 2014)
+
+  04 Feb 2014; Julian Ospald <hasufell@g.o> +focuswriter-1.4.4.ebuild:
+  version bump wrt #500198
 
   20 May 2013; Agostino Sarubbo <ago@g.o> focuswriter-1.4.2.ebuild:
   Stable for x86, wrt bug #470314



1.1                  app-editors/focuswriter/focuswriter-1.4.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/focuswriter-1.4.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/focuswriter-1.4.4.ebuild?rev=1.1&content-type=text/plain

Index: focuswriter-1.4.4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/focuswriter/focuswriter-1.4.4.ebuild,v 1.1 2014/02/04 13:43:40 hasufell Exp $

EAPI=5
PLOCALES="ca cs da de el en es es_MX fi fr he hu id it ja nl pl pt pt_BR ro ru
sk sv tr uk zh_CN"
PLOCALE_BACKUP="en"
inherit fdo-mime gnome2-utils qt4-r2 l10n readme.gentoo

DESCRIPTION="A fullscreen and distraction-free word processor"
HOMEPAGE="http://gottcode.org/focuswriter/"
SRC_URI="http://gottcode.org/${PN}/${P}-src.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

RDEPEND="app-text/enchant
	dev-libs/libzip
	dev-qt/qtcore:4
	dev-qt/qtgui:4
	sys-libs/zlib"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

DOCS=( ChangeLog CREDITS README )
DOC_CONTENTS="Focuswriter has optional sound support if media-libs/sdl-mixer is
installed with wav useflag enabled."

src_prepare() {
	l10n_for_each_disabled_locale_do rm_loc
}

src_configure() {
	eqmake4 PREFIX="${EPREFIX}/usr"
}

src_install() {
	readme.gentoo_create_doc
	qt4-r2_src_install
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	readme.gentoo_pkg_postinst
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
}

rm_loc() {
	sed -e "s|translations/${PN}_${1}.ts||"	-i ${PN}.pro || die 'sed failed'
	rm translations/${PN}_${1}.{ts,qm} || die "removing ${1} locale failed"
}