[gentoo-commits] repo/gentoo:master commit in: xfce-extra/xfce4-pulseaudio-plugin/

[Michał Górny]

commit:     524093d1f54b59942cf40bbda0de615363b09592
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 11 19:24:27 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Aug 11 19:24:27 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=524093d1

xfce-extra/xfce4-pulseaudio-plugin: Bump to 0.4.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-extra/xfce4-pulseaudio-plugin/Manifest        |  1 +
 .../xfce4-pulseaudio-plugin-0.4.2.ebuild           | 62 ++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/xfce-extra/xfce4-pulseaudio-plugin/Manifest b/xfce-extra/xfce4-pulseaudio-plugin/Manifest
index 8b201d0be5a..35560525bc9 100644
--- a/xfce-extra/xfce4-pulseaudio-plugin/Manifest
+++ b/xfce-extra/xfce4-pulseaudio-plugin/Manifest
@@ -1 +1,2 @@
 DIST xfce4-pulseaudio-plugin-0.4.1.tar.bz2 391791 BLAKE2B 038eedbecbc6ba4845f1be86938aa57165f55e1d287f914deea998383fad5a019d1ca7500c7366d76692c1b59cf87214e2057833786318cb69c326eea2a69ea4 SHA512 e7b778c78ede9ad62afaa379941ce03636a79dd000e40e748079d3e0f3c71f2e68e32cf85e527be4e1192074652714db4b7c5707b727066198c2ea43184a71cc
+DIST xfce4-pulseaudio-plugin-0.4.2.tar.bz2 428504 BLAKE2B dd8c855e75aaee060df1e7abb2f8b835f1a630ce8b45b28c407c48f52071a51729e0bf8c645d5f68f968f12a45dea272d03ee69f4554009421a1a075a8fb8d2c SHA512 94184fe7379a7f1763d606fe3c45186767a43180329b43c8cba04b76ae5e1b2249531fc1fb6304da9bb03e7475ad65f861341253ead530d9a945165b4eb9e46e

diff --git a/xfce-extra/xfce4-pulseaudio-plugin/xfce4-pulseaudio-plugin-0.4.2.ebuild b/xfce-extra/xfce4-pulseaudio-plugin/xfce4-pulseaudio-plugin-0.4.2.ebuild
new file mode 100644
index 00000000000..a492310fc30
--- /dev/null
+++ b/xfce-extra/xfce4-pulseaudio-plugin/xfce4-pulseaudio-plugin-0.4.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="A panel plug-in for PulseAudio volume control"
+HOMEPAGE="https://git.xfce.org/panel-plugins/xfce4-pulseaudio-plugin/"
+SRC_URI="https://archive.xfce.org/src/panel-plugins/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="debug keybinder libnotify wnck"
+
+RDEPEND=">=dev-libs/glib-2.42.0:=
+	media-sound/pulseaudio:=
+	>=x11-libs/gtk+-3.20.0:3=
+	>=xfce-base/libxfce4ui-4.11.0:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.9.0:=
+	>=xfce-base/xfce4-panel-4.11.0:=
+	>=xfce-base/xfconf-4.6.0:=
+	keybinder? ( dev-libs/keybinder:3= )
+	libnotify? ( x11-libs/libnotify:= )
+	wnck? ( x11-libs/libwnck:3= )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		$(use_enable keybinder)
+		$(use_enable libnotify)
+		$(use_enable wnck)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if ! has_version media-sound/pavucontrol; then
+		elog "For the 'audio mixer...' shortcut to work, you need to install"
+		elog "an external mixer application. Please either install:"
+		elog
+		elog "	media-sound/pavucontrol"
+		elog
+		elog "or specify another application to use in the 'Properties' dialog."
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}