[gentoo-commits] gentoo-x86 commit in media-video/cinelerra: cinelerra-20140710.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    14/07/10 17:59:35

  Modified:             ChangeLog
  Added:                cinelerra-20140710.ebuild
  Log:
  Create a new Cinelerra CV snapshot from git wrt #516850 by Michał Górny
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.69                 media-video/cinelerra/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/cinelerra/ChangeLog?rev=1.69&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/cinelerra/ChangeLog?rev=1.69&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/cinelerra/ChangeLog?r1=1.68&r2=1.69

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/cinelerra/ChangeLog,v
retrieving revision 1.68
retrieving revision 1.69
diff -u -r1.68 -r1.69
--- ChangeLog	10 Feb 2014 16:56:28 -0000	1.68
+++ ChangeLog	10 Jul 2014 17:59:35 -0000	1.69
@@ -1,6 +1,14 @@
 # ChangeLog for media-video/cinelerra
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/cinelerra/ChangeLog,v 1.68 2014/02/10 16:56:28 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/cinelerra/ChangeLog,v 1.69 2014/07/10 17:59:35 ssuominen Exp $
+
+*cinelerra-20140710 (10 Jul 2014)
+
+  10 Jul 2014; Samuli Suominen <ssuominen@g.o>
+  +cinelerra-20140710.ebuild, +files/cinelerra-20140710-ffmpeg-0.11.patch,
+  +files/cinelerra-20140710-underlinking.patch,
+  +files/cinelerra-20140710-validate_desktop_entry.patch:
+  Create a new Cinelerra CV snapshot from git wrt #516850 by Michał Górny
 
   10 Feb 2014; Samuli Suominen <ssuominen@g.o> cinelerra-20120707.ebuild:
   Missing virtual/glu dependency for USE="opengl" wrt #500904 by Michal Feix



1.1                  media-video/cinelerra/cinelerra-20140710.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/cinelerra/cinelerra-20140710.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/cinelerra/cinelerra-20140710.ebuild?rev=1.1&content-type=text/plain

Index: cinelerra-20140710.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/cinelerra/cinelerra-20140710.ebuild,v 1.1 2014/07/10 17:59:35 ssuominen Exp $

EAPI=5
inherit autotools eutils multilib flag-o-matic

DESCRIPTION="The most advanced non-linear video editor and compositor"
HOMEPAGE="http://www.cinelerra.org/"
SRC_URI="http://dev.gentoo.org/~ssuominen/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="3dnow alsa altivec css debug ieee1394 mmx opengl oss"

RDEPEND="media-libs/a52dec:=
	media-libs/faac:=
	media-libs/faad2:=
	>=media-libs/freetype-2
	media-libs/libdv:=
	>=media-libs/libogg-1.2:=
	media-libs/libpng:0=
	media-libs/libsndfile:=
	>=media-libs/libtheora-1.1:=
	>=media-libs/libvorbis-1.3:=
	>=media-libs/openexr-1.5:=
	media-libs/tiff:0=
	media-libs/x264:=
	media-sound/lame:=
	>=media-video/mjpegtools-2
	>=sci-libs/fftw-3
	x11-libs/libX11:=
	x11-libs/libXext:=
	x11-libs/libXft:=
	x11-libs/libXv:=
	x11-libs/libXvMC:=
	x11-libs/libXxf86vm:=
	virtual/ffmpeg
	|| ( media-video/ffmpeg:0 media-libs/libpostproc )
	virtual/jpeg:0
	alsa? ( media-libs/alsa-lib:= )
	ieee1394? (
		media-libs/libiec61883:=
		>=sys-libs/libraw1394-1.2.0:=
		>=sys-libs/libavc1394-0.5.0:=
		)
	opengl? (
		virtual/glu
		virtual/opengl
		)"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	virtual/pkgconfig
	mmx? ( dev-lang/nasm )"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-validate_desktop_entry.patch \
		"${FILESDIR}"/${PN}-ffmpeg.patch \
		"${FILESDIR}"/${P}-underlinking.patch \
		"${FILESDIR}"/${P}-ffmpeg-0.11.patch \
		"${FILESDIR}"/${PN}-libav9.patch

	if has_version '>=media-video/ffmpeg-2' ; then
		epatch "${FILESDIR}"/${PN}-ffmpeg2.patch
	fi

	eautoreconf
}

src_configure() {
	append-cppflags -D__STDC_CONSTANT_MACROS #321945
	append-ldflags -Wl,-z,noexecstack #212959

	local myconf
	use debug && myconf='--enable-x-error-output'

	econf \
		$(use_enable oss) \
		$(use_enable alsa) \
		--disable-esd \
		$(use_enable ieee1394 firewire) \
		$(use_enable css) \
		$(use_enable mmx) \
		$(use_enable 3dnow) \
		$(use_enable altivec) \
		$(use_enable opengl) \
		--with-plugindir=/usr/$(get_libdir)/${PN} \
		--with-buildinfo=cust/"Gentoo - ${PV}" \
		--with-external-ffmpeg \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install
	dohtml -a png,html,texi,sdw -r doc/*

	rm -rf "${D}"/usr/include
	mv -vf "${D}"/usr/bin/mpeg3cat{,.hv} || die
	mv -vf "${D}"/usr/bin/mpeg3dump{,.hv} || die
	mv -vf "${D}"/usr/bin/mpeg3toc{,.hv} || die
	dosym /usr/bin/mpeg2enc /usr/$(get_libdir)/${PN}/mpeg2enc.plugin

	prune_libtool_files --all
}