[gentoo-commits] repo/gentoo:master commit in: dev-python/ipython/

[Sebastian Pipping]

commit:     3b448598f3ea1b77f020e6a37b14962938958698
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Sat Jan  2 12:54:38 2021 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Sat Jan  2 12:54:38 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3b448598

dev-python/ipython: Prevent use with dev-python/jedi-0.18.0

Closes: https://bugs.gentoo.org/762703
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-3.0.12, Repoman-3.0.2

 dev-python/ipython/ipython-7.16.1-r1.ebuild | 135 +++++++++++++++++++++++++++
 dev-python/ipython/ipython-7.19.0-r1.ebuild | 136 ++++++++++++++++++++++++++++
 2 files changed, 271 insertions(+)

diff --git a/dev-python/ipython/ipython-7.16.1-r1.ebuild b/dev-python/ipython/ipython-7.16.1-r1.ebuild
new file mode 100644
index 00000000000..15ab6164e4e
--- /dev/null
+++ b/dev-python/ipython/ipython-7.16.1-r1.ebuild
@@ -0,0 +1,135 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	<dev-python/jedi-0.18[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="${CDEPEND}
+	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )"
+
+DEPEND="${CDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.14[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+	)"
+
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	distutils_install_for_testing
+	pushd "${TEST_DIR}" >/dev/null || die
+	"${TEST_DIR}"/scripts/iptest || die
+	popd >/dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}

diff --git a/dev-python/ipython/ipython-7.19.0-r1.ebuild b/dev-python/ipython/ipython-7.19.0-r1.ebuild
new file mode 100644
index 00000000000..9cf2d7af922
--- /dev/null
+++ b/dev-python/ipython/ipython-7.19.0-r1.ebuild
@@ -0,0 +1,136 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	<dev-python/jedi-0.18[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="${CDEPEND}
+	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )"
+
+BDEPEND="
+	test? (
+		${CDEPEND}
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.14[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+	)"
+
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	distutils_install_for_testing
+	pushd "${TEST_DIR}" >/dev/null || die
+	"${TEST_DIR}"/scripts/iptest || die
+	popd >/dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}