[gentoo-commits] repo/gentoo:master commit in: dev-python/fakeredis/

[Michał Górny]

commit:     20bb464e5f04af6288109cb557e56b8481530022
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun May  8 07:23:22 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun May  8 08:47:10 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=20bb464e

dev-python/fakeredis: Bump to 1.7.4

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/fakeredis/Manifest               |  1 +
 dev-python/fakeredis/fakeredis-1.7.4.ebuild | 93 +++++++++++++++++++++++++++++
 dev-python/fakeredis/metadata.xml           |  2 +-
 3 files changed, 95 insertions(+), 1 deletion(-)

diff --git a/dev-python/fakeredis/Manifest b/dev-python/fakeredis/Manifest
index 8d025a58b420..d7fc8cbf2524 100644
--- a/dev-python/fakeredis/Manifest
+++ b/dev-python/fakeredis/Manifest
@@ -1 +1,2 @@
 DIST fakeredis-1.7.1.gh.tar.gz 71151 BLAKE2B 87877c94a4c03ad6ff4b55f307526f712daa860257374a97a8f7bd29440d171467e18e4041ca56bb6af30df30481a3d5b13c7d0657ba3eb7673a653664ffbe8a SHA512 f41d9393ae50bae9de064678948f4364fc47db06f489782e5b428f449828ad5813b08b2fb053bef878b2a1b500edbb0ea1881449dbd12c2b6e385f6a2fba4c59
+DIST fakeredis-py-1.7.4.gh.tar.gz 73024 BLAKE2B d3d18611d846a0dabb52d74ca53cad997b37e794ef320bc800ab5339f70710bc30f9e33c0820db941064fbf9dca0dde3e72c78298895b8c2510a93353898b355 SHA512 71c9ffe7c208453bc8f5e719b3647a9b9fc5406c5fe3856ef1dc42c019bd7128355d260be468b62dcb764a918a3510f193fb1aaf374bb3866e352c9c2bae90c6

diff --git a/dev-python/fakeredis/fakeredis-1.7.4.ebuild b/dev-python/fakeredis/fakeredis-1.7.4.ebuild
new file mode 100644
index 000000000000..01803254b09c
--- /dev/null
+++ b/dev-python/fakeredis/fakeredis-1.7.4.ebuild
@@ -0,0 +1,93 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{9..10} )
+
+inherit distutils-r1 optfeature
+
+MY_P=fakeredis-py-${PV}
+DESCRIPTION="Fake implementation of redis API for testing purposes"
+HOMEPAGE="
+	https://github.com/dsoftwareinc/fakeredis-py/
+	https://pypi.org/project/fakeredis/
+"
+SRC_URI="
+	https://github.com/dsoftwareinc/fakeredis-py/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/redis-py[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/aioredis[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin redis
+	sed -i -e '/redis/s:<=.*::' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# also lupa
+		test/test_aioredis2.py::test_failed_script_error
+		# TODO
+		"test/test_fakeredis.py::test_set_get_nx[StrictRedis]"
+		"test/test_fakeredis.py::test_lpop_count[StrictRedis]"
+		"test/test_fakeredis.py::test_rpop_count[StrictRedis]"
+		"test/test_fakeredis.py::test_zadd_minus_zero[StrictRedis]"
+	)
+	local EPYTEST_IGNORE=(
+		# these tests fail a lot...
+		test/test_hypothesis.py
+	)
+	local args=(
+		# tests requiring lupa (lua support)
+		-k 'not test_eval and not test_lua and not test_script'
+	)
+	epytest "${args[@]}"
+}
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+	local redis_test_config="
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	"
+
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	"${EPREFIX}"/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
+
+pkg_postinst() {
+	optfeature "Mock aioredis" dev-python/aioredis
+}

diff --git a/dev-python/fakeredis/metadata.xml b/dev-python/fakeredis/metadata.xml
index d6b0b74ee354..3d21e4768321 100644
--- a/dev-python/fakeredis/metadata.xml
+++ b/dev-python/fakeredis/metadata.xml
@@ -7,6 +7,6 @@
 	<stabilize-allarches/>
 	<upstream>
 		<remote-id type="pypi">fakeredis</remote-id>
-		<remote-id type="github">jamesls/fakeredis</remote-id>
+		<remote-id type="github">dsoftwareinc/fakeredis</remote-id>
 	</upstream>
 </pkgmetadata>