[gentoo-commits] repo/gentoo:master commit in: sys-apps/gnome-disk-utility/

[Mart Raudsepp]

commit:     620a9ae155203418671a833edc707a18547f9dbc
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Fri Dec  7 12:05:35 2018 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri Dec  7 12:05:35 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=620a9ae1

sys-apps/gnome-disk-utility: bump to 3.30.2, add longdesc

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>
Package-Manager: Portage-2.3.52, Repoman-2.3.11

 sys-apps/gnome-disk-utility/Manifest               |  1 +
 .../gnome-disk-utility-3.30.2.ebuild               | 63 ++++++++++++++++++++++
 sys-apps/gnome-disk-utility/metadata.xml           |  5 ++
 3 files changed, 69 insertions(+)

diff --git a/sys-apps/gnome-disk-utility/Manifest b/sys-apps/gnome-disk-utility/Manifest
index 99e9545d33a..3c46b7098de 100644
--- a/sys-apps/gnome-disk-utility/Manifest
+++ b/sys-apps/gnome-disk-utility/Manifest
@@ -1 +1,2 @@
 DIST gnome-disk-utility-3.24.1.tar.xz 1947976 BLAKE2B a3b9d02417bed415bf6b9b8d86abcfa857abe316133ce7abfa11db835831e916d879b09d1e1129d12621b0234ffa27c1e246837cb614c51c54ce387a9c73bea4 SHA512 ae6bf83e005733ae985987411a9fe25b0059f64484fc0d613ad54af478130782974607bec53713ee36c2a28de653ceba82b0fb091aee57101773c0eeeaaed2d5
+DIST gnome-disk-utility-3.30.2.tar.xz 1665896 BLAKE2B 9000dc8e95f27cccdb3a13b84c527c740f801a58b0f3f1a384ae1415eeed330f5f81f284f190d110dca0f5dcfb9316262491b715c2b2cd4f67813587046b5b42 SHA512 59228fa923b7b1e89e8ce8d96920b6f452bc6ae62c203261bffbc584a2ef231e1d2006db8ddbd15f1f7b4ee14aeae54b85520b89bfd3e1450d42c423d987f2dc

diff --git a/sys-apps/gnome-disk-utility/gnome-disk-utility-3.30.2.ebuild b/sys-apps/gnome-disk-utility/gnome-disk-utility-3.30.2.ebuild
new file mode 100644
index 00000000000..16ce62737a9
--- /dev/null
+++ b/sys-apps/gnome-disk-utility/gnome-disk-utility-3.30.2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Disk Utility for GNOME using udisks"
+HOMEPAGE="https://wiki.gnome.org/Apps/Disks"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="fat gnome systemd"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.31:2
+	>=sys-fs/udisks-2.7.6:2
+	>=x11-libs/gtk+-3.16.0:3
+	>=app-crypt/libsecret-0.7
+	>=dev-libs/libpwquality-1.0.0
+	>=media-libs/libcanberra-0.1[gtk3]
+	>=media-libs/libdvdread-4.2.0
+	>=x11-libs/libnotify-0.7:=
+	>=app-arch/xz-utils-5.0.5
+	systemd? ( >=sys-apps/systemd-209:0= )
+"
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+	fat? ( sys-fs/dosfstools )
+	gnome? ( >=gnome-base/gnome-settings-daemon-3.8 )
+"
+# appstream-glib for developer_name tag in appdata (gettext-0.19.8.1 own appdata.its file doesn't have it yet)
+# libxml2 for xml-stripblanks in gresource
+DEPEND="${COMMON_DEPEND}
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gnome gsd_plugin)
+		$(meson_use systemd libsystemd)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}

diff --git a/sys-apps/gnome-disk-utility/metadata.xml b/sys-apps/gnome-disk-utility/metadata.xml
index 72800be15e7..7a24d5bba6c 100644
--- a/sys-apps/gnome-disk-utility/metadata.xml
+++ b/sys-apps/gnome-disk-utility/metadata.xml
@@ -9,4 +9,9 @@
 	<flag name="fat">Include FAT16/FAT32 support
 		(<pkg>sys-fs/dosfstools</pkg>)</flag>
 </use>
+<longdescription lang="en">
+	Disks provides an easy way to inspect, format, partition, and configure disks
+	and block devices. Using Disks, you can view SMART data, manage devices,
+	benchmark physical disks, and image USB sticks.
+</longdescription>
 </pkgmetadata>