[gentoo-commits] gentoo-x86 commit in media-sound/amarok: ChangeLog amarok-2.3.2-r1.ebuild

[Jorge Manuel B. S. Vicetto (jmbsvicetto)]

jmbsvicetto    10/09/27 11:01:33

  Modified:             ChangeLog
  Added:                amarok-2.3.2-r1.ebuild
  Log:
  [media-sound/amarok-2.3.2-r1] Now that we finally have working patches for mariadb and mysql 5.1.50,
  fixed the embedded deps and added embedded to IUSE defaults.
  Added an upstream patch to fix issues with the collection scanning caused by a QT bug/regression -
  https://bugs.kde.org/show_bug.cgi?id=251762#c10
  
  (Portage version: 2.2_rc87/cvs/Linux x86_64)

Revision  Changes    Path
1.391                media-sound/amarok/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.391&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.391&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/ChangeLog?r1=1.390&r2=1.391

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v
retrieving revision 1.390
retrieving revision 1.391
diff -u -r1.390 -r1.391
--- ChangeLog	19 Sep 2010 13:03:20 -0000	1.390
+++ ChangeLog	27 Sep 2010 11:01:33 -0000	1.391
@@ -1,6 +1,17 @@
 # ChangeLog for media-sound/amarok
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.390 2010/09/19 13:03:20 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.391 2010/09/27 11:01:33 jmbsvicetto Exp $
+
+*amarok-2.3.2-r1 (27 Sep 2010)
+
+  27 Sep 2010; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
+  +amarok-2.3.2-r1.ebuild, +files/amarok-2.3.2-fix-qt-regression.patch:
+  [media-sound/amarok-2.3.2-r1] Now that we finally have working patches for
+  mariadb and mysql 5.1.50,
+  fixed the embedded deps and added embedded to IUSE defaults.
+  Added an upstream patch to fix issues with the collection scanning caused
+  by a QT bug/regression -
+  https://bugs.kde.org/show_bug.cgi?id=251762#c10
 
   19 Sep 2010; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
   amarok-2.3.1.90.ebuild:



1.1                  media-sound/amarok/amarok-2.3.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/amarok-2.3.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/amarok-2.3.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: amarok-2.3.2-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.3.2-r1.ebuild,v 1.1 2010/09/27 11:01:33 jmbsvicetto Exp $

EAPI="2"

# Translations are only in the tarballs, not the git repo
if [[ ${PV} != *9999* ]]; then
	KDE_LINGUAS="af bg ca ca@valencia cs da de el en_GB es et fr it ja lt lv nb nds pa pl
	pt pt_BR ru sk sl sr sr@ijekavian sr@ijekavianlatin sr@latin sv th tr uk zh_CN zh_TW"
	SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.bz2"
else
	EGIT_REPO_URI="git://git.kde.org/${PN}/${PN}.git"
	GIT_ECLASS="git"
fi

KDE_REQUIRED="never"
inherit flag-o-matic kde4-base ${GIT_ECLASS}

DESCRIPTION="Advanced audio player based on KDE framework."
HOMEPAGE="http://amarok.kde.org/"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
SLOT="4"
IUSE="cdda daap debug +embedded ipod lastfm mp3tunes mtp opengl +player semantic-desktop +utils"

# Tests require gmock - http://code.google.com/p/gmock/
# It's not in the tree yet
RESTRICT="test"

# The QT regression patch was submitted by Jeff Mitchell at
# http://gitweb.kde.org/amarok/amarok.git/commitdiff_plain/79d86829294ac54132c01153660e70e30c15c378?hp=fd2a40d970c57fa2102e95de1a60c59e37892638
PATCHES=(
	"${FILESDIR}/${P}-flac-fix.patch"
	"${FILESDIR}/${P}-fix-qt-regression.patch"
)

# ipod requires gdk enabled and also gtk compiled in libgpod
COMMONDEPEND="
	>=media-libs/taglib-1.6.1[asf,mp4]
	>=media-libs/taglib-extras-1.0.1
	player? (
		app-crypt/qca:2
		>=app-misc/strigi-0.5.7[dbus,qt4]
		>=kde-base/kdelibs-${KDE_MINIMAL}[opengl?,semantic-desktop?]
		sys-libs/zlib
		>=virtual/mysql-5.1
		x11-libs/qt-script
		>=x11-libs/qtscriptgenerator-0.1.0
		cdda? (
			>=kde-base/libkcddb-${KDE_MINIMAL}
			>=kde-base/libkcompactdisc-${KDE_MINIMAL}
			>=kde-base/kdemultimedia-kioslaves-${KDE_MINIMAL}
		)
		embedded? (
			|| ( >=dev-db/mysql-5.1.50-r3 >=dev-db/mariadb-5.1.50 )
		)
		ipod? ( >=media-libs/libgpod-0.7.0[gtk] )
		lastfm? ( >=media-libs/liblastfm-0.3.0 )
		mp3tunes? (
			dev-libs/glib:2
			dev-libs/libxml2
			dev-libs/openssl
			net-libs/loudmouth
			net-misc/curl
			x11-libs/qt-core[glib]
		)
		mtp? ( >=media-libs/libmtp-1.0.0 )
		opengl? ( virtual/opengl )
	)
	utils? (
		x11-libs/qt-core
		x11-libs/qt-dbus
	)
	!player? ( !utils? ( media-sound/amarok[player] ) )
"
DEPEND="${COMMONDEPEND}
	dev-util/automoc
	dev-util/pkgconfig
"
RDEPEND="${COMMONDEPEND}
	!media-sound/amarok-utils
	player? ( >=kde-base/phonon-kde-${KDE_MINIMAL} )
"

src_prepare() {
	if ! use player; then
		# Disable po processing
		sed -e "s:include(MacroOptionalAddSubdirectory)::" \
			-i "${S}/CMakeLists.txt" \
			|| die "Removing include of MacroOptionalAddSubdirectory failed."
		sed -e "s:macro_optional_add_subdirectory( po )::" \
			-i "${S}/CMakeLists.txt" \
			|| die "Removing include of MacroOptionalAddSubdirectory failed."
	fi

	kde4-base_src_prepare
}

src_configure() {
	# Append minimal-toc cflag for ppc64, see bug 280552 and 292707
	use ppc64 && append-flags -mminimal-toc

	if use player; then
		mycmakeargs=(
			-DWITH_PLAYER=ON
			-DWITH_Libgcrypt=OFF
			$(cmake-utils_use embedded WITH_MYSQL_EMBEDDED)
			$(cmake-utils_use_with ipod)
			$(cmake-utils_use_with ipod Gdk)
			$(cmake-utils_use_with lastfm LibLastFm)
			$(cmake-utils_use_with mtp)
			$(cmake-utils_use_with mp3tunes MP3Tunes)
		)
	else
		mycmakeargs=(
			-DWITH_PLAYER=OFF
		)
	fi

	mycmakeargs+=(
		$(cmake-utils_use_with utils UTILITIES)
	)
		# $(cmake-utils_use_with semantic-desktop Nepomuk)
		# $(cmake-utils_use_with semantic-desktop Soprano)

	kde4-base_src_configure
}

pkg_postinst() {
	kde4-base_pkg_postinst

	if use player; then

		if use daap; then
			echo
			elog "You have installed amarok with daap support."
			elog "You may be interested in installing www-servers/mongrel as well."
			echo
		fi

		if ! use embedded; then
			echo
			elog "You've disabled the amarok support for embedded mysql DBs."
			elog "You'll have to configure amarok to use an external db server."
			echo
			elog "Please read http://amaroklive.com/wiki/MySQL_Server for details on how"
			elog "to configure the external db and migrate your data from the embedded database."
			echo

			if has_version "dev-db/mysql[minimal]"; then
				elog "You built mysql with the minimal use flag, so it doesn't include the server."
				elog "You won't be able to use the local mysql installation to store your amarok collection."
				echo
			fi
		fi
	fi
}