[gentoo-commits] repo/gentoo:master commit in: dev-util/sysdig/

[Michał Górny]

commit:     5a3e046618188a2fb5bf5de1fb2544f420c0a8ac
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Oct  5 06:04:58 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Oct  5 06:41:48 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5a3e0466

dev-util/sysdig: Bump to 0.24.0, with new license

Most important changes in 0.24.0:
- userspace switched to Apache-2.0 license,
- kernel module switched to || ( MIT GPL-2 ) license,
- complete IPv6 support,
- loginuid support.

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-util/sysdig/Manifest             |  1 +
 dev-util/sysdig/sysdig-0.24.0.ebuild | 94 ++++++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/dev-util/sysdig/Manifest b/dev-util/sysdig/Manifest
index 2c047df45fb..9db66838d25 100644
--- a/dev-util/sysdig/Manifest
+++ b/dev-util/sysdig/Manifest
@@ -1 +1,2 @@
 DIST sysdig-0.23.1.tar.gz 830420 BLAKE2B 31a8c4cd8b570a308c81b4df53494cff2619d05724e509634671968025ebee0e46c5e59a7c877e6d9f1f1eba86a8a27a0cd9c5b66e75723ec8eec66c6782d4c0 SHA512 059a564a5d31381efae4bc50d2b83f83a1d051f1cfb9fa6bfb75a341305149073a6eb3b9a3ce4da12fa293e75b71f8b30c9021ac8d4c4a2f59a40e35a5ffd482
+DIST sysdig-0.24.0.tar.gz 846171 BLAKE2B fc65c6df7351e1e1f4afd168cf9eaaed8d714539822ede1ce1941ead191b0d6e9898bd1da36a78737d4662b8e47090d63978441ce01fe30f13c504a3fa09eb5c SHA512 ff8162fbd5941a7a5532e8c1d0300acdd2d7ae85044600021f12e76f3752b50c46c894ea2007d0467761927403a784b85cfc000e735004e5fdbd48c31c20071e

diff --git a/dev-util/sysdig/sysdig-0.24.0.ebuild b/dev-util/sysdig/sysdig-0.24.0.ebuild
new file mode 100644
index 00000000000..3ba452c42e3
--- /dev/null
+++ b/dev-util/sysdig/sysdig-0.24.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+MODULES_OPTIONAL_USE=modules
+inherit linux-mod bash-completion-r1 cmake-utils
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="https://www.sysdig.org/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0
+	modules? ( || ( MIT GPL-2 ) )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl +modules"
+
+RDEPEND="
+	app-misc/jq:0=
+	dev-cpp/tbb:0=
+	dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	dev-libs/libb64:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0=
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	net-misc/curl:0="
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/os-headers"
+
+# needed for the kernel module
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
+
+pkg_pretend() {
+	linux-mod_pkg_setup
+}
+
+pkg_setup() {
+	linux-mod_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod for that
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_DEPS=OFF
+	)
+
+	cmake-utils_src_configure
+
+	# setup linux-mod ugliness
+	MODULE_NAMES="sysdig-probe(extra:${S}/driver:)"
+	BUILD_PARAMS='KERNELDIR="${KERNEL_DIR}"'
+	BUILD_TARGETS="all"
+
+	if use modules; then
+		cmake-utils_src_make configure_driver
+
+		cp "${BUILD_DIR}"/driver/Makefile.dkms driver/Makefile || die
+	fi
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	linux-mod_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	linux-mod_src_install
+
+	# remove sources
+	rm -r "${ED%/}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED%/}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED%/}"/usr/etc || die
+}