[gentoo-commits] repo/gentoo:master commit in: net-misc/radvd/

[Matthew Thode]

commit:     eb1c8c5848f08e9da1aba7473819f636ef79a687
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Wed May  6 19:57:58 2020 +0000
Commit:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Wed May  6 19:58:16 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eb1c8c58

net-misc/radvd: fix direct call to ar

Closes: https://bugs.gentoo.org/721272
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Matthew Thode <prometheanfire <AT> gentoo.org>

 net-misc/radvd/radvd-2.18-r1.ebuild | 73 +++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)

diff --git a/net-misc/radvd/radvd-2.18-r1.ebuild b/net-misc/radvd/radvd-2.18-r1.ebuild
new file mode 100644
index 00000000000..44a31097acb
--- /dev/null
+++ b/net-misc/radvd/radvd-2.18-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit systemd user eutils readme.gentoo-r1 toolchain-funcs
+
+DESCRIPTION="Linux IPv6 Router Advertisement Daemon"
+HOMEPAGE="http://v6web.litech.org/radvd/"
+SRC_URI="http://v6web.litech.org/radvd/dist/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="kernel_FreeBSD selinux test"
+RESTRICT="!test? ( test )"
+
+CDEPEND="dev-libs/libdaemon"
+DEPEND="${CDEPEND}
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+	test? ( dev-libs/check )"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-radvd )
+"
+DOCS=( CHANGES README TODO radvd.conf.example )
+
+PATCHES=(
+)
+
+pkg_setup() {
+	enewgroup radvd
+	enewuser radvd -1 -1 /dev/null radvd
+}
+
+src_configure() {
+	econf --with-pidfile=/run/radvd/radvd.pid \
+		--with-systemdsystemunitdir=no \
+		$(use_with test check)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+
+	insinto /usr/share/doc/${PF}/html
+	doins INTRO.html
+
+	newinitd "${FILESDIR}"/${PN}-2.15.init ${PN}
+	newconfd "${FILESDIR}"/${PN}.conf ${PN}
+
+	systemd_dounit "${FILESDIR}"/${PN}.service
+
+	if use kernel_FreeBSD ; then
+		sed -i -e \
+			's/^SYSCTL_FORWARD=.*$/SYSCTL_FORWARD=net.inet6.ip6.forwarding/g' \
+			"${D}"/etc/init.d/${PN} || die
+	fi
+
+	readme.gentoo_create_doc
+}
+
+DISABLE_AUTOFORMATTING=1
+DOC_CONTENTS="Please create a configuration file ${ROOT}etc/radvd.conf.
+See ${ROOT}usr/share/doc/${PF} for an example.
+
+grsecurity users should allow a specific group to read /proc
+and add the radvd user to that group, otherwise radvd may
+segfault on startup."