[gentoo-commits] gentoo-x86 commit in x11-libs/cairo: ChangeLog cairo-1.10.0-r1.ebuild cairo-9999.ebuild cairo-1.10.0.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    10/09/09 08:03:08

  Modified:             ChangeLog cairo-9999.ebuild
  Added:                cairo-1.10.0-r1.ebuild
  Removed:              cairo-1.10.0.ebuild
  Log:
  Disable xlib over xcb by default. To make the choice of backend up to application. Thanks to remi for pointing out.
  
  (Portage version: 2.2_rc75/cvs/Linux x86_64)

Revision  Changes    Path
1.256                x11-libs/cairo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.256&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.256&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?r1=1.255&r2=1.256

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v
retrieving revision 1.255
retrieving revision 1.256
diff -u -r1.255 -r1.256
--- ChangeLog	8 Sep 2010 20:01:52 -0000	1.255
+++ ChangeLog	9 Sep 2010 08:03:08 -0000	1.256
@@ -1,6 +1,13 @@
 # ChangeLog for x11-libs/cairo
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.255 2010/09/08 20:01:52 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.256 2010/09/09 08:03:08 scarabeus Exp $
+
+*cairo-1.10.0-r1 (09 Sep 2010)
+
+  09 Sep 2010; Tomáš Chvátal <scarabeus@g.o> -cairo-1.10.0.ebuild,
+  +cairo-1.10.0-r1.ebuild, cairo-9999.ebuild:
+  Disable xlib over xcb by default. To make the choice of backend up to
+  application. Thanks to remi for pointing out.
 
   08 Sep 2010; Tomáš Chvátal <scarabeus@g.o> cairo-1.10.0.ebuild,
   cairo-9999.ebuild:



1.3                  x11-libs/cairo/cairo-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild?r1=1.2&r2=1.3

Index: cairo-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- cairo-9999.ebuild	8 Sep 2010 20:01:52 -0000	1.2
+++ cairo-9999.ebuild	9 Sep 2010 08:03:08 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild,v 1.2 2010/09/08 20:01:52 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild,v 1.3 2010/09/09 08:03:08 scarabeus Exp $
 
 EAPI=3
 
@@ -39,12 +39,6 @@
 			>=sys-fs/udev-136
 			gallium? ( media-libs/mesa[gallium] )
 		)
-		xcb? (
-			|| (
-				<=x11-libs/libX11-1.3.5[xcb]
-				>x11-libs/libX11-1.3.5
-			)
-		)
 	)
 	xcb? (
 		x11-libs/libxcb
@@ -93,7 +87,6 @@
 	if use X; then
 		myopts+="
 			$(use_enable drm)
-			$(use_enable xcb xlib-xcb)
 		"
 
 		if use drm; then
@@ -112,10 +105,14 @@
 		use drm && ewarn "drm use requires X use enabled. So disabling for now."
 		myopts+="
 			--disable-drm
-			--disable-xcb-lib
+			--disable-gallium
+			--disable-xcb-drm
 		"
 	fi
 
+
+	# --disable-xcb-lib:
+	#	do not override good xlib backed by hardforcing rendering over xcb
 	econf \
 		--disable-dependency-tracking \
 		$(use_with X x) \
@@ -137,6 +134,7 @@
 		--enable-pdf \
 		--enable-png \
 		--enable-ps \
+		--disable-xcb-lib \
 		${myopts}
 }
 



1.1                  x11-libs/cairo/cairo-1.10.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.10.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.10.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: cairo-1.10.0-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.10.0-r1.ebuild,v 1.1 2010/09/09 08:03:08 scarabeus Exp $

EAPI=3

EGIT_REPO_URI="git://anongit.freedesktop.org/git/cairo"
[[ ${PV} == *9999 ]] && GIT_ECLASS="git"

inherit eutils flag-o-matic autotools ${GIT_ECLASS}

DESCRIPTION="A vector graphics library with cross-device output support"
HOMEPAGE="http://cairographics.org/"
[[ ${PV} == *9999 ]] || SRC_URI="http://cairographics.org/releases/${P}.tar.gz"

LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="X aqua debug directfb doc drm gallium opengl openvg qt static-libs +svg xcb"

# Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
RESTRICT="test"

RDEPEND="media-libs/fontconfig
	media-libs/freetype:2
	media-libs/libpng:0
	sys-libs/zlib
	>=x11-libs/pixman-0.18.4
	directfb? ( dev-libs/DirectFB )
	opengl? ( virtual/opengl )
	qt? ( x11-libs/qt-gui )
	svg? ( dev-libs/libxml2 )
	X? (
		>=x11-libs/libXrender-0.6
		x11-libs/libXext
		x11-libs/libX11
		x11-libs/libXft
		drm? (
			>=sys-fs/udev-136
			gallium? ( media-libs/mesa[gallium] )
		)
	)
	xcb? (
		x11-libs/libxcb
		x11-libs/xcb-util
	)"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=sys-devel/libtool-2
	doc? (
		>=dev-util/gtk-doc-1.6
		~app-text/docbook-xml-dtd-4.2
	)
	X? (
		x11-proto/renderproto
		drm? (
			x11-proto/xproto
			>=x11-proto/xextproto-7.1
		)
	)"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.8.8-interix.patch

	# Slightly messed build system YAY
	if [[ ${PV} == *9999* ]]; then
		touch boilerplate/Makefile.am.features
		touch src/Makefile.am.features
		touch ChangeLog
	fi

	# We need to run elibtoolize to ensure correct so versioning on FreeBSD
	# upgraded to an eautoreconf for the above interix patch.
	eautoreconf
}

src_configure() {
	local myopts

	[[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
	# http://bugs.freedesktop.org/show_bug.cgi?id=15463
	[[ ${CHOST} == *-solaris* ]] && append-flags -D_POSIX_PTHREAD_SEMANTICS

	#gets rid of fbmmx.c inlining warnings
	append-flags -finline-limit=1200

	if use X; then
		myopts+="
			$(use_enable drm)
		"

		if use drm; then
			myopts+="
				$(use_enable gallium)
				$(use_enable xcb xcb-drm)
			"
		else
			use gallium && ewarn "Gallium use requires drm use enabled. So disabling for now."
			myopts+="
				--disable-gallium
				--disable-xcb-drm
			"
		fi
	else
		use drm && ewarn "drm use requires X use enabled. So disabling for now."
		myopts+="
			--disable-drm
			--disable-gallium
			--disable-xcb-drm
		"
	fi


	# --disable-xcb-lib:
	#	do not override good xlib backed by hardforcing rendering over xcb
	econf \
		--disable-dependency-tracking \
		$(use_with X x) \
		$(use_enable X xlib) \
		$(use_enable X xlib-xrender) \
		$(use_enable aqua quartz) \
		$(use_enable aqua quartz-image) \
		$(use_enable debug test-surfaces) \
		$(use_enable directfb) \
		$(use_enable doc gtk-doc) \
		$(use_enable openvg vg) \
		$(use_enable opengl gl) \
		$(use_enable qt) \
		$(use_enable static-libs static) \
		$(use_enable svg) \
		$(use_enable xcb) \
		$(use_enable xcb xcb-shm) \
		--enable-ft \
		--enable-pdf \
		--enable-png \
		--enable-ps \
		--disable-xcb-lib \
		${myopts}
}

src_install() {
	# parallel make install fails
	emake -j1 DESTDIR="${D}" install || die "Installation failed"
	dodoc AUTHORS ChangeLog NEWS README || die

	use static-libs || find "${D}" -type f -name '*.la' -exec rm -f '{}' \;
}