[gentoo-commits] gentoo-x86 commit in mail-filter/mimedefang: ChangeLog mimedefang-2.75.ebuild

[Tim Harder (radhermit)]

radhermit    14/06/20 07:41:13

  Modified:             ChangeLog
  Added:                mimedefang-2.75.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.20                 mail-filter/mimedefang/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/mimedefang/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/mimedefang/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/mimedefang/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/mimedefang/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	7 Jun 2014 19:15:53 -0000	1.19
+++ ChangeLog	20 Jun 2014 07:41:13 -0000	1.20
@@ -1,6 +1,11 @@
 # ChangeLog for mail-filter/mimedefang
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/mimedefang/ChangeLog,v 1.19 2014/06/07 19:15:53 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/mimedefang/ChangeLog,v 1.20 2014/06/20 07:41:13 radhermit Exp $
+
+*mimedefang-2.75 (20 Jun 2014)
+
+  20 Jun 2014; Tim Harder <radhermit@g.o> +mimedefang-2.75.ebuild:
+  Version bump.
 
   07 Jun 2014; Agostino Sarubbo <ago@g.o> mimedefang-2.74.ebuild:
   Stable for x86, wrt bug #502830



1.1                  mail-filter/mimedefang/mimedefang-2.75.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/mimedefang/mimedefang-2.75.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/mimedefang/mimedefang-2.75.ebuild?rev=1.1&content-type=text/plain

Index: mimedefang-2.75.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/mimedefang/mimedefang-2.75.ebuild,v 1.1 2014/06/20 07:41:13 radhermit Exp $

EAPI=5

inherit eutils user

DESCRIPTION="Antispam, antivirus and other customizable filtering for MTAs with Milter support"
HOMEPAGE="http://www.mimedefang.org/"
SRC_URI="http://www.mimedefang.org/static/${P}.tar.gz"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="clamav +poll"

DEPEND=">=dev-perl/MIME-tools-5.412
	dev-perl/IO-stringy
	virtual/perl-MIME-Base64
	dev-perl/Digest-SHA1
	clamav? ( app-antivirus/clamav )
	|| ( mail-filter/libmilter mail-mta/sendmail )"
RDEPEND="${DEPEND}"
RESTRICT="test"

pkg_setup() {
	enewgroup defang
	enewuser defang -1 -1 -1 defang
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.72-ldflags.patch
}

src_configure() {
	econf \
		--with-user=defang \
		$(use_enable poll) \
		$(use_enable clamav) \
		$(use_enable clamav clamd)
}

src_install() {
	emake DESTDIR="${D}" INSTALL_STRIP_FLAG="" install

	fowners defang:defang /etc/mail/mimedefang-filter
	fperms 644 /etc/mail/mimedefang-filter
	insinto /etc/mail/
	insopts -m 644
	newins "${S}"/SpamAssassin/spamassassin.cf sa-mimedefang.cf

	keepdir /var/spool/{MD-Quarantine,MIMEDefang}
	fowners defang:defang /var/spool/{MD-Quarantine,MIMEDefang}
	fperms 700 /var/spool/{MD-Quarantine,MIMEDefang}

	keepdir /var/log/mimedefang

	newinitd "${FILESDIR}"/${PN}.init ${PN}
	newconfd "${FILESDIR}"/${PN}.conf ${PN}

	dodoc -r examples
}