[gentoo-commits] repo/gentoo:master commit in: dev-python/jaraco-functools/

[Michał Górny]

commit:     51c75a29aafe5f60c49ce322cfe98cf7033b35d0
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Feb  3 10:14:36 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Feb  3 10:58:14 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=51c75a29

dev-python/jaraco-functools: Use flit to build (for bootstrap)

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../jaraco-functools-3.5.0-r1.ebuild               | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-python/jaraco-functools/jaraco-functools-3.5.0-r1.ebuild b/dev-python/jaraco-functools/jaraco-functools-3.5.0-r1.ebuild
new file mode 100644
index 000000000000..afb16b117a96
--- /dev/null
+++ b/dev-python/jaraco-functools/jaraco-functools-3.5.0-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Additional functions used by other projects by developer jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.functools"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN/-/.}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+distutils_enable_tests pytest
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "jaraco.functools"
+		version = "${PV}"
+		description = "Functools like those found in stdlib"
+	EOF
+}