[gentoo-commits] gentoo-x86 commit in dev-libs/STLport: ChangeLog STLport-5.1.5.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    08/04/30 18:54:27

  Modified:             ChangeLog
  Added:                STLport-5.1.5.ebuild
  Log:
  Version bump (including a lot fixes, thanks to Peter Alfredsen and Debian, bug #219457).
  (Portage version: 2.1.5_rc6)

Revision  Changes    Path
1.65                 dev-libs/STLport/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/STLport/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/STLport/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/STLport/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/STLport/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	25 Sep 2007 20:22:27 -0000	1.64
+++ ChangeLog	30 Apr 2008 18:54:27 -0000	1.65
@@ -1,6 +1,17 @@
 # ChangeLog for dev-libs/STLport
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/STLport/ChangeLog,v 1.64 2007/09/25 20:22:27 dev-zero Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/STLport/ChangeLog,v 1.65 2008/04/30 18:54:27 dev-zero Exp $
+
+*STLport-5.1.5 (30 Apr 2008)
+
+  30 Apr 2008; Tiziano Müller <dev-zero@g.o>
+  +files/STLport-5.1.5-alpha.patch, +files/STLport-5.1.5-bashism.patch,
+  +files/STLport-5.1.5-cxx_use_c99.patch,
+  +files/STLport-5.1.5-fix-warnings.patch,
+  +files/STLport-5.1.5-gcc-4.3.patch, +files/STLport-5.1.5-hppa.patch,
+  +files/STLport-5.1.5-portability-hack.patch, +STLport-5.1.5.ebuild:
+  Version bump (including a lot fixes, thanks to Peter Alfredsen and Debian,
+  bug #219457).
 
 *STLport-5.1.3 (25 Sep 2007)
 



1.1                  dev-libs/STLport/STLport-5.1.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/STLport/STLport-5.1.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/STLport/STLport-5.1.5.ebuild?rev=1.1&content-type=text/plain

Index: STLport-5.1.5.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/STLport/STLport-5.1.5.ebuild,v 1.1 2008/04/30 18:54:27 dev-zero Exp $

inherit eutils versionator eutils toolchain-funcs multilib flag-o-matic

KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"

DESCRIPTION="C++ STL library"
HOMEPAGE="http://stlport.sourceforge.net/"
SRC_URI="mirror://sourceforge/stlport/${P}.tar.bz2"
LICENSE="as-is"
SLOT="0"
IUSE="boost"

DEPEND="boost? ( dev-libs/boost )"
RDEPEND="${RDEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	#Debian bug 356570 http://bugs.debian.org/356570
	#Gentoo bug 183060 http://bugs.gentoo.org/183060
	#Debian bug 443234 http://bugs.debian.org/443234
	#Debian bug 389316 http://bugs.debian.org/389316
	#Debian bug 384247 http://bugs.debian.org/384247
	#Debian bug 465395 http://bugs.debian.org/465395
	#Debian bug 468063 http://bugs.debian.org/468063
	epatch "${FILESDIR}/${P}-portability-hack.patch" \
		"${FILESDIR}/${P}-bashism.patch" \
		"${FILESDIR}/${P}-cxx_use_c99.patch" \
		"${FILESDIR}/${P}-hppa.patch" \
		"${FILESDIR}/${P}-alpha.patch" \
		"${FILESDIR}/${P}-fix-warnings.patch" \
		"${FILESDIR}/${P}-gcc-4.3.patch"

	sed -i \
		-e 's/\(OPT += \)-O2/\1/' \
		build/Makefiles/gmake/*cc.mak \
		|| die "sed opts failed"

	# CXX_VERSION on gentoo has ( )s in them, they need to be quoted.

	sed -i \
		-e 's/echo ${CXX_VERSION}/echo "${CXX_VERSION}"/' \
		build/Makefiles/gmake/*.mak \
		|| die "sed CXX_VERSION failed"

	# We have to add this to host.h to make sure
	# that dependencies of STLport use the same settings
	cat <<- EOF >> stlport/stl/config/host.h
	#define _STLP_NATIVE_INCLUDE_PATH ../g++-v$(gcc-major-version)
	/* use pthreads for threading */
	#define _PTHREADS
	/* enable largefile support */
	#define _FILE_OFFSET_BITS 64
	#define _LARGEFILE_SOURCE
	#define _LARGEFILE64_SOURCE
	EOF
}

src_compile() {

	sed -i \
		-e "s|\(CC :=\) gcc|\1 $(tc-getCC)|" \
		-e "s|\(CXX :=\) c++|\1 $(tc-getCXX)|" \
		-e "s|^\(CFLAGS = \)|\1 ${CFLAGS} |" \
		-e "s|^\(CCFLAGS = \)|\1 ${CFLAGS} |" \
		-e "s|^\(CPPFLAGS = \)|\1 ${CPPFLAGS} |" \
		build/Makefiles/gmake/gcc.mak || die "sed failed"

	local myconf
	if use boost ; then
		myconf="${myconf} --with-boost=/usr/include"
		sed -i \
			-e 'N;N;N;s:/\**\n\(#define _STLP_USE_BOOST_SUPPORT 1\)*\n\*/:\1:' \
			stlport/stl/config/user_config.h
	fi

	cd "${S}/build/lib"

	# It's not an autoconf script
	./configure \
		${myconf} \
		--with-extra-cxxflags="${CXXFLAGS}" || die "configure failed"

	cd "${S}"

	cat <<- EOF >> build/Makefiles/config.mak
	CFLAGS := ${CFLAGS}
	EOF

	local targets
	targets="all-shared all-static"

	# The build-system is broken in respect to parallel builds, bug #161881
	emake \
		-j1 \
		-C build/lib \
		-f gcc.mak \
		depend ${targets} || die "Compile failed"

}

src_install() {
	emake -C build/lib -f gcc.mak install
	dolib.so lib/*

	emake -C build/lib -f gcc.mak install-static
	dolib.a lib/*.a

	insinto /usr/include
	doins -r stlport

	dodoc README etc/ChangeLog* etc/*.txt doc/*
}

src_test() {
	cd "${S}/build"

	sed -i \
		-e "1aLDFLAGS := -L${S}/build/lib/obj/gcc/so -L${S}/build/lib/obj/gcc/so_g -L${S}/build/lib/obj/gcc/so_stlg" \
		test/unit/gcc.mak || die "sed failed"

	emake -j1 -C test/unit -f gcc.mak || die "emake tests failed"

	export LD_LIBRARY_PATH="./lib/obj/gcc/so_stlg"
	./test/unit/obj/gcc/so_stlg/stl_unit_test || die "unit tests failed"
}



-- 
gentoo-commits@l.g.o mailing list