[gentoo-commits] repo/gentoo:master commit in: sci-libs/gmsh/

[Matthias Maier]

commit:     73ddc4916985225d253684569fa364ed160be400
Author:     Fabio Rossi <rossi.f <AT> inwind <DOT> it>
AuthorDate: Sun May 29 10:26:14 2022 +0000
Commit:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
CommitDate: Mon Jun  6 05:49:27 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=73ddc491

sci-libs/gmsh: added latest version

Signed-off-by: Fabio Rossi <rossi.f <AT> inwind.it>
Signed-off-by: Matthias Maier <tamiko <AT> gentoo.org>

 sci-libs/gmsh/Manifest           |  1 +
 sci-libs/gmsh/gmsh-4.10.3.ebuild | 80 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/sci-libs/gmsh/Manifest b/sci-libs/gmsh/Manifest
index 1acc490e0367..6438ce1deb83 100644
--- a/sci-libs/gmsh/Manifest
+++ b/sci-libs/gmsh/Manifest
@@ -1 +1,2 @@
+DIST gmsh-4.10.3-source.tgz 14994941 BLAKE2B b9229f81fc8daabdb3b3db3acd50a0a0e602fec1423bc67a0033a02217c908910eeb1f9bd1cbc57fe2d24b566f256b969fe92e9e9ceefe4cd5af34dd07cf1a9e SHA512 863c5a7fe13095afad37b4450855b2079d034222b5a595fc25b2b0d840d8ef63ceafbbf56ea642b3c3e9277faabe08a2cc19a7a3126a8e12e9d4117243244653
 DIST gmsh-4.9.5-source.tgz 14921704 BLAKE2B e805bd786154bf6ce8bebb2d2c38204a88d06a251c45fbe6dd37641a15e02291993c244f26a01faad2a6445a4852274e5481d4236b7a3d9b7ee65fc863f1b880 SHA512 4da61bdf03fb9466af80ac790e83c8888bab755c78d860d601474d7ebca220ac51cba620db310165021412dbecc1cf187ccdff47b8a78e0579339bb72cfa6484

diff --git a/sci-libs/gmsh/gmsh-4.10.3.ebuild b/sci-libs/gmsh/gmsh-4.10.3.ebuild
new file mode 100644
index 000000000000..139dbbd52704
--- /dev/null
+++ b/sci-libs/gmsh/gmsh-4.10.3.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake fortran-2 python-any-r1 toolchain-funcs
+
+DESCRIPTION="A three-dimensional finite element mesh generator"
+HOMEPAGE="http://www.geuz.org/gmsh/"
+SRC_URI="http://www.geuz.org/gmsh/src/${P}-source.tgz"
+
+LICENSE="GPL-3 free-noncomm"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+## cgns is not compiling ATM, maybe fix cgns lib first
+IUSE="blas cgns examples jpeg med metis mpi netgen opencascade petsc png python shared X zlib"
+
+REQUIRED_USE="med? ( mpi )"
+
+RDEPEND="
+	virtual/fortran
+	X? ( x11-libs/fltk:1[xft] )
+	blas? ( virtual/blas virtual/lapack sci-libs/fftw:3.0 )
+	cgns? ( sci-libs/cgnslib )
+	jpeg? ( media-libs/libjpeg-turbo )
+	med? ( sci-libs/med[mpi] )
+	opencascade? ( sci-libs/opencascade:* )
+	png? ( media-libs/libpng:0 )
+	petsc? ( sci-mathematics/petsc[mpi=] )
+	zlib? ( sys-libs/zlib )
+	mpi? ( virtual/mpi[cxx] )"
+
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	python? ( dev-lang/swig:0 )
+	"
+
+S="${WORKDIR}"/${P}-source
+
+PATCHES=( "${FILESDIR}"/$PN-4.9.5-opencascade.patch )
+
+pkg_setup() {
+	fortran-2_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=( )
+
+	use blas && \
+		mycmakeargs+=(-DCMAKE_Fortran_COMPILER=$(tc-getF77))
+
+	mycmakeargs+=(
+		-DENABLE_BLAS_LAPACK="$(usex blas)"
+		-DENABLE_BUILD_DYNAMIC="$(usex shared)"
+		-DENABLE_CGNS="$(usex cgns)"
+		-DENABLE_FLTK="$(usex X)"
+		-DENABLE_GRAPHICS="$(usex X)"
+		-DENABLE_MED="$(usex med)"
+		-DENABLE_MPI="$(usex mpi)"
+		-DENABLE_METIS="$(usex metis)"
+		-DENABLE_NETGEN="$(usex netgen)"
+		-DENABLE_OCC="$(usex opencascade)"
+		-DENABLE_PETSC="$(usex petsc)"
+		-DENABLE_PRIVATE_API="$(usex shared)"
+		-DENABLE_WRAP_PYTHON="$(usex python)")
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use examples ; then
+		dodoc -r examples tutorials
+		docompress -x /usr/share/doc/${PF}/{examples,tutorials}
+	fi
+}