[gentoo-commits] gentoo-x86 commit in dev-util/bzr: ChangeLog bzr-1.6.ebuild bzr-1.1.ebuild bzr-1.6_rc5.ebuild bzr-1.3.ebuild bzr-1.4.ebuild bzr-0.17.ebuild

[Peter Volkov (pva)]

pva         08/08/25 23:10:30

  Modified:             ChangeLog
  Added:                bzr-1.6.ebuild
  Removed:              bzr-1.1.ebuild bzr-1.6_rc5.ebuild bzr-1.3.ebuild
                        bzr-1.4.ebuild bzr-0.17.ebuild
  Log:
  Version bump, removed old.
  (Portage version: 2.2_rc8/cvs/Linux 2.6.25-gentoo-r7 i686)

Revision  Changes    Path
1.57                 dev-util/bzr/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/bzr/ChangeLog?rev=1.57&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/bzr/ChangeLog?rev=1.57&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/bzr/ChangeLog?r1=1.56&r2=1.57

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/bzr/ChangeLog,v
retrieving revision 1.56
retrieving revision 1.57
diff -u -r1.56 -r1.57
--- ChangeLog	23 Aug 2008 17:13:05 -0000	1.56
+++ ChangeLog	25 Aug 2008 23:10:29 -0000	1.57
@@ -1,6 +1,14 @@
 # ChangeLog for dev-util/bzr
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/bzr/ChangeLog,v 1.56 2008/08/23 17:13:05 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/bzr/ChangeLog,v 1.57 2008/08/25 23:10:29 pva Exp $
+
+*bzr-1.6 (25 Aug 2008)
+
+  25 Aug 2008; Peter Volkov <pva@g.o> -files/70bzr-gentoo.el,
+  -files/bzr-0.16-fix-manpage-location.patch, -bzr-0.17.ebuild,
+  -bzr-1.1.ebuild, -bzr-1.3.ebuild, -bzr-1.4.ebuild, -bzr-1.6_rc5.ebuild,
+  +bzr-1.6.ebuild:
+  Version bump, removed old.
 
   23 Aug 2008; Markus Meier <maekke@g.o> bzr-1.5.ebuild:
   amd64/x86 stable, bug #235504



1.1                  dev-util/bzr/bzr-1.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/bzr/bzr-1.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/bzr/bzr-1.6.ebuild?rev=1.1&content-type=text/plain

Index: bzr-1.6.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/bzr/bzr-1.6.ebuild,v 1.1 2008/08/25 23:10:29 pva Exp $

NEED_PYTHON=2.4

inherit distutils bash-completion elisp-common eutils versionator

MY_PV=${PV/_rc/rc}
MY_P=${PN}-${MY_PV}
SERIES=$(get_version_component_range 1-2)

DESCRIPTION="Bazaar is a next generation distributed version control system."
HOMEPAGE="http://bazaar-vcs.org/"
#SRC_URI="http://bazaar-vcs.org/releases/src/${MY_P}.tar.gz"
SRC_URI="http://launchpad.net/bzr/${SERIES}/${MY_PV}/+download/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-fbsd"
IUSE="curl emacs sftp test"

RDEPEND="|| ( dev-python/celementtree >=dev-lang/python-2.5 )
	curl? ( dev-python/pycurl )
	sftp? ( dev-python/paramiko )"

DEPEND="emacs? ( virtual/emacs )
	test? (
		$RDEPEND
		dev-python/medusa
	)"

S="${WORKDIR}/${MY_P}"
PYTHON_MODNAME="bzrlib"
SITEFILE=71bzr-gentoo.el
DOCS="doc/*.txt"

src_unpack() {
	distutils_src_unpack

	# Don't regenerate .c files from .pyx when pyrex is found.
	epatch "${FILESDIR}/${PN}-0.92-no-pyrex.patch"
	# Don't run lock permission tests when running as root
	epatch "${FILESDIR}/${PN}-0.90-tests-fix_root.patch"
	# Fix permission errors when run under directories with setgid set.
	epatch "${FILESDIR}/${PN}-0.90-tests-sgid.patch"
}

src_compile() {
	distutils_src_compile

	if use emacs; then
		elisp-compile contrib/emacs/bzr-mode.el || die "Emacs modules failed!"
	fi
}

src_install() {
	distutils_src_install --install-data /usr/share

	docinto developers
	dodoc doc/developers/*
	for doc in mini-tutorial tutorials user-{guide,reference}; do
		docinto $doc
		dodoc doc/en/$doc/*
	done

	if use emacs; then
		elisp-install ${PN} contrib/emacs/*.el* || die "elisp-install failed"
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die "elisp-site-file-install failed"

		# don't add automatically to the load-path, so the sitefile
		# can do a conditional loading
		touch "${D}${SITELISP}/${PN}/.nosearch"
	fi

	insinto /usr/share/zsh/site-functions
	doins contrib/zsh/_bzr
	dobashcompletion contrib/bash/bzr
}

pkg_postinst() {
	distutils_pkg_postinst
	bash-completion_pkg_postinst

	if use emacs; then
		elisp-site-regen
		elog "If you are using a GNU Emacs version greater than 22.1, bzr support"
		elog "is already included.  This ebuild does not automatically activate bzr support"
		elog "in versions below, but prepares it in a way you can load it from your ~/.emacs"
		elog "file by adding"
		elog "       (load \"bzr-mode\")"
	fi
}

pkg_postrm() {
	distutils_pkg_postrm
	use emacs && elisp-site-regen
}

src_test() {
	# Some tests expect the usual pyc compiling behaviour.
	unset PYTHON_DONTCOMPILE
	"${python}" bzr --no-plugins selftest || die "bzr selftest failed"
	# Just to make sure we don't hit any errors on later stages.
	export PYTHON_DONTCOMPILE=1
}