[gentoo-commits] gentoo-x86 commit in games-puzzle/sgt-puzzles: ChangeLog sgt-puzzles-9306.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    11/12/22 01:29:22

  Modified:             ChangeLog
  Added:                sgt-puzzles-9306.ebuild
  Log:
  version bump with patch reroll from Michael (kensington) (bug #395577)
  
  (Portage version: 2.1.10.41/cvs/Linux i686)

Revision  Changes    Path
1.11                 games-puzzle/sgt-puzzles/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	4 Jan 2011 22:53:18 -0000	1.10
+++ ChangeLog	22 Dec 2011 01:29:21 -0000	1.11
@@ -1,6 +1,13 @@
 # ChangeLog for games-puzzle/sgt-puzzles
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog,v 1.10 2011/01/04 22:53:18 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog,v 1.11 2011/12/22 01:29:21 mr_bones_ Exp $
+
+*sgt-puzzles-9306 (22 Dec 2011)
+
+  22 Dec 2011; Michael Sterrett <mr_bones_@g.o>
+  files/sgt-puzzles-9023-gentoo.patch, +sgt-puzzles-9306.ebuild,
+  +files/sgt-puzzles-9306-gentoo.patch:
+  version bump with patch reroll from Michael (kensington) (bug #395577)
 
   04 Jan 2011; Markos Chandras <hwoarang@g.o> sgt-puzzles-9023.ebuild:
   Stable on amd64 wrt bug #350438



1.1                  games-puzzle/sgt-puzzles/sgt-puzzles-9306.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-puzzle/sgt-puzzles/sgt-puzzles-9306.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-puzzle/sgt-puzzles/sgt-puzzles-9306.ebuild?rev=1.1&content-type=text/plain

Index: sgt-puzzles-9306.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/sgt-puzzles-9306.ebuild,v 1.1 2011/12/22 01:29:22 mr_bones_ Exp $

EAPI=2
inherit eutils toolchain-funcs games
if [[ ${PV} == "99999999" ]] ; then
	ESVN_REPO_URI="svn://svn.tartarus.org/sgt/puzzles"
	inherit subversion
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-r${PV}.tar.gz"
	S=${WORKDIR}/puzzles-r${PV}
	KEYWORDS="~amd64 ~x86"
fi

DESCRIPTION="Simon Tatham's Portable Puzzle Collection"
HOMEPAGE="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/"

LICENSE="MIT"
SLOT="0"
IUSE="doc"

RDEPEND="x11-libs/gtk+:2"
DEPEND="${RDEPEND}
	dev-lang/perl
	dev-util/pkgconfig
	doc? ( >=app-doc/halibut-1.0 )"

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	./mkfiles.pl
	sed -i \
		-e 's:= -O2 -Wall -Werror -ansi -pedantic -g:= $(CPPFLAGS):' \
		-e '/LDFLAGS/s:=:=$(LDFLAGS) :' \
		Makefile || die
}

src_compile() {
	emake CC="$(tc-getCC)" || die
	if use doc ; then
		halibut --text --html --info --pdf --ps puzzles.but
	fi
}

src_install() {
	dodir "${GAMES_BINDIR}"
	emake DESTDIR="${D}" gamesdir="${GAMES_BINDIR}" install || die
	dodoc README HACKING

	local file name
	for file in *.R ; do
		[[ ${file} == "nullgame.R" ]] && continue
		name=$(sed -n 's/^[a-z]*\.exe://p' "${file}")
		file=${file%.R}
		if [[ ${PV} -lt 99999999 ]] ; then
			newicon icons/${file}-48d24.png ${PN}-${file}.png || die
			make_desktop_entry "${GAMES_BINDIR}/${file}" "${name}" "${PN}-${file}"
		else
			# No icons with the live version
			make_desktop_entry "${GAMES_BINDIR}/${file}" "${name}"
		fi
	done

	dodoc puzzles.txt puzzles.chm
	if use doc ; then
		dohtml *.html
		doinfo puzzles.info
		dodoc puzzles.pdf puzzles.ps
	fi

	prepgamesdirs
}