[gentoo-commits] gentoo-x86 commit in dev-lang/R: ChangeLog R-2.7.2.ebuild R-2.7.1.ebuild R-2.8.0.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    08/10/27 10:32:15

  Modified:             ChangeLog R-2.7.2.ebuild R-2.7.1.ebuild
  Added:                R-2.8.0.ebuild
  Log:
  Version bump and get rid of virtual/tetex
  (Portage version: 2.2_rc11/cvs/Linux 2.6.25-gentoo-r7 x86_64)

Revision  Changes    Path
1.136                dev-lang/R/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/R/ChangeLog?rev=1.136&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/R/ChangeLog?rev=1.136&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/R/ChangeLog?r1=1.135&r2=1.136

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/R/ChangeLog,v
retrieving revision 1.135
retrieving revision 1.136
diff -u -r1.135 -r1.136
--- ChangeLog	7 Oct 2008 09:42:00 -0000	1.135
+++ ChangeLog	27 Oct 2008 10:32:14 -0000	1.136
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/R
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/ChangeLog,v 1.135 2008/10/07 09:42:00 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/ChangeLog,v 1.136 2008/10/27 10:32:14 bicatali Exp $
+
+*R-2.8.0 (27 Oct 2008)
+
+  27 Oct 2008; Sébastien Fabbro <bicatali@g.o> R-2.7.1.ebuild,
+  R-2.7.2.ebuild, +R-2.8.0.ebuild:
+  Version bump and get rid of virtual/tetex
 
   07 Oct 2008; Sébastien Fabbro <bicatali@g.o> metadata.xml,
   -R-2.2.1-r1.ebuild, -R-2.6.1-r1.ebuild, R-2.7.2.ebuild:



1.3                  dev-lang/R/R-2.7.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/R/R-2.7.2.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/R/R-2.7.2.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/R/R-2.7.2.ebuild?r1=1.2&r2=1.3

Index: R-2.7.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.7.2.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- R-2.7.2.ebuild	7 Oct 2008 09:42:00 -0000	1.2
+++ R-2.7.2.ebuild	27 Oct 2008 10:32:14 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.7.2.ebuild,v 1.2 2008/10/07 09:42:00 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.7.2.ebuild,v 1.3 2008/10/27 10:32:14 bicatali Exp $
 
 inherit fortran flag-o-matic bash-completion versionator
 
@@ -32,7 +32,9 @@
 DEPEND="${CDEPEND}
 	dev-util/pkgconfig
 	doc? ( virtual/latex-base
-	  || ( dev-texlive/texlive-fontsrecommended virtual/tetex ) )"
+	  || ( dev-texlive/texlive-fontsrecommended
+		   app-text/tetex
+		   app-text/ptex ) )"
 
 RDEPEND="${CDEPEND}
 	app-arch/unzip



1.11                 dev-lang/R/R-2.7.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/R/R-2.7.1.ebuild?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/R/R-2.7.1.ebuild?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/R/R-2.7.1.ebuild?r1=1.10&r2=1.11

Index: R-2.7.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.7.1.ebuild,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- R-2.7.1.ebuild	6 Sep 2008 21:39:55 -0000	1.10
+++ R-2.7.1.ebuild	27 Oct 2008 10:32:14 -0000	1.11
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.7.1.ebuild,v 1.10 2008/09/06 21:39:55 dertobi123 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.7.1.ebuild,v 1.11 2008/10/27 10:32:14 bicatali Exp $
 
 inherit fortran flag-o-matic bash-completion
 
@@ -32,7 +32,9 @@
 DEPEND="${CDEPEND}
 	dev-util/pkgconfig
 	doc? ( virtual/latex-base
-	  || ( dev-texlive/texlive-fontsrecommended virtual/tetex ) )"
+	  || ( dev-texlive/texlive-fontsrecommended
+		   app-text/tetex
+		   app-text/ptex ) )"
 
 RDEPEND="${CDEPEND}
 	app-arch/unzip



1.1                  dev-lang/R/R-2.8.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/R/R-2.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/R/R-2.8.0.ebuild?rev=1.1&content-type=text/plain

Index: R-2.8.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/R/R-2.8.0.ebuild,v 1.1 2008/10/27 10:32:14 bicatali Exp $

EAPI=2
inherit eutils fortran flag-o-matic bash-completion versionator

DESCRIPTION="Language and environment for statistical computing and graphics"
HOMEPAGE="http://www.r-project.org/"
SRC_URI="mirror://cran/src/base/R-2/${P}.tar.gz
	bash-completion? ( mirror://gentoo/R.bash_completion.bz2 )"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

IUSE="doc java jpeg lapack minimal nls png readline tk X cairo"

# common depends
CDEPEND="dev-lang/perl
	dev-libs/libpcre
	app-arch/bzip2
	virtual/blas
	virtual/ghostscript
	cairo? ( x11-libs/cairo[X] x11-libs/pango[X] )
	readline? ( sys-libs/readline )
	jpeg? ( media-libs/jpeg )
	png? ( media-libs/libpng )
	lapack? ( virtual/lapack )
	tk? ( dev-lang/tk )
	X? ( x11-libs/libXmu x11-misc/xdg-utils )"

DEPEND="${CDEPEND}
	dev-util/pkgconfig
	doc? ( virtual/latex-base
	  || ( dev-texlive/texlive-fontsrecommended
		   app-text/tetex
		   app-text/ptex ) )"

RDEPEND="${CDEPEND}
	app-arch/unzip
	app-arch/zip
	java? ( >=virtual/jre-1.5 )"

R_HOME=/usr/$(get_libdir)/${PN}

pkg_setup() {
	FORTRAN="gfortran ifc g77"
	fortran_pkg_setup
	export FFLAGS="${FFLAGS:--O2}"
	[[ ${FORTRANC} = gfortran || ${FORTRANC} = if* ]] && \
		export FCFLAGS="${FCFLAGS:-${FFLAGS}}"
	filter-ldflags -Wl,-Bdirect -Bdirect
}

src_prepare() {

	# fix packages.html for doc (bug #205103)
	# check in later versions if fixed
	sed -i \
		-e "s:../../library:../../../../$(get_libdir)/R/library:g" \
		src/library/tools/R/packageshtml.R \
		|| die "sed failed"

	# fix Rscript
	sed -i \
		-e "s:-DR_HOME='\"\$(rhome)\"':-DR_HOME='\"${R_HOME}\"':" \
		src/unix/Makefile.in || die "sed unix Makefile failed"

	use lapack && \
		export LAPACK_LIBS="$(pkg-config --libs lapack)"

	if use X; then
		export R_BROWSER="$(type -p xdg-open)"
		export R_PDFVIEWER="$(type -p xdg-open)"
	fi
}

src_configure() {
	econf \
		--disable-rpath \
		--enable-R-profiling \
		--enable-memory-profiling \
		--enable-R-shlib \
		--enable-linux-lfs \
		--with-system-zlib \
		--with-system-bzlib \
		--with-system-pcre \
		--with-blas="$(pkg-config --libs blas)" \
		--docdir=/usr/share/doc/${PF} \
		rdocdir=/usr/share/doc/${PF} \
		$(use_enable nls) \
		$(use_with lapack) \
		$(use_with tk tcltk) \
		$(use_with jpeg jpeglib) \
		$(use_with !minimal recommended-packages) \
		$(use_with png libpng) \
		$(use_with readline) \
		$(use_with cairo) \
		$(use_with X x)
}

src_compile(){
	emake || die "emake failed"
	RMATH_V=0.0.0
	emake -j1 -C src/nmath/standalone \
		libRmath_la_LDFLAGS=-Wl,-soname,libRmath.so.${RMATH_V} \
		|| die "emake math library failed"
	if use doc; then
		export VARTEXFONTS="${T}/fonts"
		emake info pdf || die "emake docs failed"
	fi
}

src_test() {
	# we need to unset R_HOME otherwise some of the diff based
	# tests fail due to warnings in the output
	R_HOME="" emake -j1 check || die "Some of the tests failed"
}

src_install() {
	# -j1 because creates various dirs sequentially (hit should be small)
	emake -j1 DESTDIR="${D}" install || die "emake install failed"

	if use doc; then
		emake DESTDIR="${D}" \
			install-info install-pdf || die "emake install docs failed"
	fi

	emake -j1 \
		-C src/nmath/standalone \
		DESTDIR="${D}" install \
		|| die "emake install math library failed"

	local mv=$(get_major_version ${RMATH_V})
	mv  "${D}"/usr/$(get_libdir)/libRmath.so \
		"${D}"/usr/$(get_libdir)/libRmath.so.${RMATH_V}
	dosym libRmath.so.${RMATH_V} /usr/$(get_libdir)/libRmath.so.${mv}
	dosym libRmath.so.${mv} /usr/$(get_libdir)/libRmath.so

	# env file
	cat > 99R <<-EOF
		LDPATH=${R_HOME}/lib
		R_HOME=${R_HOME}
	EOF
	doenvd 99R || die "doenvd failed"

	dobashcompletion "${WORKDIR}"/R.bash_completion
}

pkg_config() {
	if use java; then
		einfo "Re-initializing java paths for ${P}"
		R CMD javareconf
	fi
}