[gentoo-commits] gentoo-x86 commit in mail-filter/dovecot-antispam: ChangeLog dovecot-antispam-1.3.ebuild

[Benedikt Boehm (hollow)]

hollow      10/05/29 06:45:28

  Modified:             ChangeLog
  Added:                dovecot-antispam-1.3.ebuild
  Log:
  version bump wrt #320651
  (Portage version: 2.2_rc67/cvs/Linux i686)

Revision  Changes    Path
1.18                 mail-filter/dovecot-antispam/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/dovecot-antispam/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/dovecot-antispam/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/dovecot-antispam/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/dovecot-antispam/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	11 Mar 2010 21:16:41 -0000	1.17
+++ ChangeLog	29 May 2010 06:45:28 -0000	1.18
@@ -1,6 +1,12 @@
 # ChangeLog for mail-filter/dovecot-antispam
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/dovecot-antispam/ChangeLog,v 1.17 2010/03/11 21:16:41 nyhm Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/dovecot-antispam/ChangeLog,v 1.18 2010/05/29 06:45:28 hollow Exp $
+
+*dovecot-antispam-1.3 (29 May 2010)
+
+  29 May 2010; Benedikt Böhm <hollow@g.o>
+  +dovecot-antispam-1.3.ebuild:
+  version bump wrt #320651
 
   11 Mar 2010; Tristan Heaven <nyhm@g.o> dovecot-antispam-1.2.ebuild:
   inherit eutils for epatch



1.1                  mail-filter/dovecot-antispam/dovecot-antispam-1.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/dovecot-antispam/dovecot-antispam-1.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/dovecot-antispam/dovecot-antispam-1.3.ebuild?rev=1.1&content-type=text/plain

Index: dovecot-antispam-1.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/dovecot-antispam/dovecot-antispam-1.3.ebuild,v 1.1 2010/05/29 06:45:28 hollow Exp $

EAPI="1"

inherit confutils eutils

DESCRIPTION="A dovecot antispam plugin supporting multiple backends"
HOMEPAGE="http://johannes.sipsolutions.net/Projects/dovecot-antispam"
SRC_URI="http://johannes.sipsolutions.net/download/dovecot-antispam/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug +dspam crm114 mailtrain signature-log spool2dir syslog"

DEPEND="net-mail/dovecot
	dspam? ( mail-filter/dspam )
	crm114? ( app-text/crm114 )"
RDEPEND="${DEPEND}"

# we need this to prevent errors from dovecot-config
top_builddir() {
	return
}

pkg_setup() {
	confutils_require_one dspam signature-log mailtrain crm114 spool2dir
	confutils_use_depend_all syslog debug
}

src_compile() {
	source "${ROOT}"/usr/lib/dovecot/dovecot-config || \
		die "cannot find dovecot-config"

	echo DOVECOT=${dovecot_incdir} > .config
	echo INSTALLDIR=${moduledir}/imap/ >> .config
	echo PLUGINNAME=antispam >> .config
	echo USER=root >> .config
	echo GROUP=root >> .config

	use dspam && echo BACKEND=dspam-exec >> .config
	use signature-log && echo BACKEND=signature-log >> .config
	use mailtrain && echo BACKEND=mailtrain >> .config
	use crm114 && echo BACKEND=crm114-exec >> .config
	use spool2dir && echo BACKEND=spool2dir >> .config

	if use debug; then
		if use syslog; then
			echo DEBUG=syslog >> .config
		else
			echo DEBUG=stderr >> .config
		fi
	fi

	emake || die "make failed"
}

src_install() {
	source "${ROOT}"/usr/lib/dovecot/dovecot-config || \
		die "cannot find dovecot-config"

	dodir "${moduledir}"/imap/
	make DESTDIR="${D}" install || die "make install failed"

	newman antispam.7 dovecot-antispam.7
	dodoc NOTES README
}