[gentoo-commits] gentoo-x86 commit in net-proxy/tinyproxy: ChangeLog tinyproxy-1.8.1-r1.ebuild

[Jeroen Roovers (jer)]

jer         10/06/03 22:30:52

  Modified:             ChangeLog
  Added:                tinyproxy-1.8.1-r1.ebuild
  Log:
  Fix various directory paths. Add tinyproxy user and make it own its directories. Fix configuration file location as used in initd script.
  (Portage version: 2.2_rc67/cvs/Linux i686)

Revision  Changes    Path
1.17                 net-proxy/tinyproxy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/tinyproxy/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/tinyproxy/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/tinyproxy/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/tinyproxy/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	3 Jun 2010 21:46:23 -0000	1.16
+++ ChangeLog	3 Jun 2010 22:30:52 -0000	1.17
@@ -1,6 +1,12 @@
 # ChangeLog for net-proxy/tinyproxy
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/tinyproxy/ChangeLog,v 1.16 2010/06/03 21:46:23 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/tinyproxy/ChangeLog,v 1.17 2010/06/03 22:30:52 jer Exp $
+
+*tinyproxy-1.8.1-r1 (03 Jun 2010)
+
+  03 Jun 2010; Jeroen Roovers <jer@g.o> +tinyproxy-1.8.1-r1.ebuild:
+  Fix various directory paths. Add tinyproxy user and make it own its
+  directories. Fix configuration file location as used in initd script.
 
   03 Jun 2010; Jeroen Roovers <jer@g.o> tinyproxy-1.8.1.ebuild:
   Remove USE=doc, only use USE=minimal.



1.1                  net-proxy/tinyproxy/tinyproxy-1.8.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/tinyproxy/tinyproxy-1.8.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/tinyproxy/tinyproxy-1.8.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: tinyproxy-1.8.1-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/tinyproxy/tinyproxy-1.8.1-r1.ebuild,v 1.1 2010/06/03 22:30:52 jer Exp $

EAPI="2"

inherit autotools eutils

DESCRIPTION="A lightweight HTTP/SSL proxy"
HOMEPAGE="http://www.banu.com/tinyproxy/"
SRC_URI="http://www.banu.com/pub/${PN}/1.8/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
IUSE="debug +filter-proxy minimal reverse-proxy transparent-proxy
	+upstream-proxy +xtinyproxy-header"

DEPEND="minimal? ( app-text/asciidoc )"
RDEPEND=""

pkg_setup() {
	enewgroup ${PN}
	enewuser ${PN} "" "" "" ${PN}
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-ldflags.patch
	use minimal && epatch "${FILESDIR}/${P}-minimal.patch"
	sed -i etc/${PN}.conf.in -e "s|nobody|${PN}|g" || die "sed failed"
	sed \
		"${FILESDIR}/${PN}.initd" \
		-e "/CONFFILE/s:${PN}/::g" \
		> "${WORKDIR}"/${PN}.initd \
		|| die "sed failed"
	eautoreconf
}

src_configure() {
	if use minimal; then
		ln -s /bin/true ${T}/a2x
		export PATH="${T}:${PATH}"
	fi
	econf \
		--localstatedir=/var \
		$(use_enable filter-proxy filter) \
		$(use_enable reverse-proxy reverse) \
		$(use_enable transparent-proxy transparent) \
		$(use_enable upstream-proxy upstream) \
		$(use_enable xtinyproxy-header xtinyproxy) \
		$(use_enable debug) \
		|| die "econf failed"
}

src_install() {
	sed -i \
		-e 's:mkdir $(datadir)/tinyproxy:mkdir -p $(DESTDIR)$(datadir)/tinyproxy:' \
		Makefile
	emake DESTDIR="${D}" install || die "install failed"

	if ! use minimal; then
		dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
	fi

	diropts -m0775 -o ${PN} -g ${PN}
	keepdir /var/log/${PN}
	keepdir /var/run/${PN}

	newinitd "${WORKDIR}"/tinyproxy.initd tinyproxy
}

pkg_postinst() {
	einfo "For filtering domains and URLs, enable filter option in the configuration file"
	einfo "and add them to the filter file (one domain or URL per line)."
}