[gentoo-commits] gentoo-x86 commit in dev-java/xom: ChangeLog xom-1.2.6-r1.ebuild

[Ralph Sennhauser (sera)]

sera        12/01/29 09:57:39

  Modified:             ChangeLog
  Added:                xom-1.2.6-r1.ebuild
  Log:
  Revbump, strip out fallback parser to allow building wiht other JVMs than
  SUN/Oracles. #399119
  Use java-virtuals/servlet-api instead of dev-java/servletapi. #398689
  
  (Portage version: 2.1.10.44/cvs/Linux x86_64)

Revision  Changes    Path
1.60                 dev-java/xom/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/xom/ChangeLog?rev=1.60&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/xom/ChangeLog?rev=1.60&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/xom/ChangeLog?r1=1.59&r2=1.60

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/xom/ChangeLog,v
retrieving revision 1.59
retrieving revision 1.60
diff -u -r1.59 -r1.60
--- ChangeLog	1 Jan 2012 14:51:59 -0000	1.59
+++ ChangeLog	29 Jan 2012 09:57:39 -0000	1.60
@@ -1,6 +1,14 @@
 # ChangeLog for dev-java/xom
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/xom/ChangeLog,v 1.59 2012/01/01 14:51:59 sera Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/xom/ChangeLog,v 1.60 2012/01/29 09:57:39 sera Exp $
+
+*xom-1.2.6-r1 (29 Jan 2012)
+
+  29 Jan 2012; Ralph Sennhauser <sera@g.o> +xom-1.2.6-r1.ebuild,
+  +files/xom-strip-fallback-parser.patch:
+  Revbump, strip out fallback parser to allow building wiht other JVMs than
+  SUN/Oracles. #399119
+  Use java-virtuals/servlet-api instead of dev-java/servletapi. #398689
 
   01 Jan 2012; Ralph Sennhauser <sera@g.o> xom-1.0-r6.ebuild,
   xom-1.0-r7.ebuild, xom-1.2.6.ebuild:



1.1                  dev-java/xom/xom-1.2.6-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/xom/xom-1.2.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/xom/xom-1.2.6-r1.ebuild?rev=1.1&content-type=text/plain

Index: xom-1.2.6-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/xom/xom-1.2.6-r1.ebuild,v 1.1 2012/01/29 09:57:39 sera Exp $

EAPI="4"

JAVA_PKG_IUSE="doc examples source"

inherit java-pkg-2 java-ant-2

JAXEN_V="1.1.3"
JAXEN_P="jaxen-${JAXEN_V}"

DESCRIPTION="A new XML object model."
HOMEPAGE="http://cafeconleche.org/XOM/index.html"
SRC_URI="http://cafeconleche.org/XOM/${P}.tar.gz
	http://dist.codehaus.org/jaxen/distributions/${JAXEN_P}-src.tar.gz"
# Bundled jaxen as its moved under XOM's namespace

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE=""

COMMON_DEPEND="dev-java/xerces:2
		dev-java/xml-commons-external:1.3
		examples? ( java-virtuals/servlet-api:2.4 )"
RDEPEND=">=virtual/jre-1.4
		${COMMON_DEPEND}"
DEPEND=">=virtual/jdk-1.4
		dev-java/jarjar:1
		${COMMON_DEPEND}"

S="${WORKDIR}/XOM"

# Test require network access to pass
# They need a redirected http document on public web
RESTRICT="test"

java_prepare() {
	epatch "${FILESDIR}/${P}.patch"
	epatch "${FILESDIR}/${PN}-strip-fallback-parser.patch" #399119

	# Delete test files as they aren't installed
	rm -vr src/nu/xom/tests || die

	# Delete bundled jars
	rm -v *.jar lib/*.jar || die

	# Delete bundled classes
	find . -name "*.class" -delete -print || die

	# Move bundled jaxen to where the build.xml expects it
	mv "${WORKDIR}"/${JAXEN_P}/ lib/ || die

	java-pkg_jar-from --into lib/ xml-commons-external-1.3
	java-pkg_jar-from --into lib/ xerces-2
	java-pkg_jar-from --build-only --into lib/ jarjar-1
	# tagsoup is only needed to run betterdoc but we use the pregenerated ones
}

src_compile() {
	local ant_flags="-Ddebug=off"
	use examples && ant_flags="${ant_flags} -Dservlet.jar=$(java-pkg_getjar	servlet-api-2.4 servlet-api.jar)"

	ANT_TASKS="jarjar-1" eant jar ${ant_flags}\
		$(use examples && echo samples)
}

src_install() {
	java-pkg_newjar build/${P}.jar ${PN}.jar
	use examples && java-pkg_dojar build/xom-samples.jar
	dodoc Todo.txt

	use doc && java-pkg_dojavadoc apidocs/
	use source && java-pkg_dosrc src/*
	use examples && java-pkg_doexamples --subdir nu/xom/samples src/nu/xom/samples
}