[gentoo-commits] repo/gentoo:master commit in: dev-util/diffoscope/

[Sam James]

commit:     2cc7a74dda30e1aabcd453c242fc1217e9a13a2f
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 26 20:56:33 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Mar 26 21:21:38 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2cc7a74d

dev-util/diffoscope: add 208

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/diffoscope/Manifest              |   1 +
 dev-util/diffoscope/diffoscope-208.ebuild | 108 ++++++++++++++++++++++++++++++
 2 files changed, 109 insertions(+)

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index af25eae9821d..7d76047338e0 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,2 +1,3 @@
 DIST diffoscope-205.tar.gz 2706492 BLAKE2B efeeef0ee12f5813dfd7de6b2128b1e6e7ad3cb9fae758c5337ddb04e86ec24d26581ba051fa31a8e825c423076f609fa0acbb07c26f6f89ec763e9939fca0cd SHA512 6a8a665c477dafa98a876d08ed6e7bb1e0528ec32f1d14430d14ea5fd54c15ffab66feaca48ec4bc82cd1e4d60ba8b629f3e9f4ed70cfaaf7d8cf0386c791991
 DIST diffoscope-207.tar.gz 2707223 BLAKE2B e20f21c9e0acc78cadfce082f874b3e3cbbbd26cfa5041012eb07a347f177724506d1263b6636c71c5304993e52b81e8ac1fa82ee7231d892346ede2d00de37f SHA512 ebbcf3e7e41f042626f2d175cea027392fc52f65dd11ded8e2a65ed3d58129fe4948e6129c2aec74d58d8f6b58855ada23be8231b426a9473b165eba0f182955
+DIST diffoscope-208.tar.gz 2709374 BLAKE2B cd5bf11f8686fe9afc97285bad335ac3a20a214b83a9a6746326e8b455fd1b32ee2e17ae8a2a5ce36fffcb67dc694c2f17b93f372eec5c4237e62120902c9ebd SHA512 c2583693b0b38f663c5674b60f988657c12a6de3919c407031d1e090eb1c8d25a34f441f328488be03137fbe6573e0cfa9cc32a43863ea476877f0aa03aa20db

diff --git a/dev-util/diffoscope/diffoscope-208.ebuild b/dev-util/diffoscope/diffoscope-208.ebuild
new file mode 100644
index 000000000000..46f6608598b5
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-208.ebuild
@@ -0,0 +1,108 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+
+RESTRICT="!test? ( test )"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="test? (
+		app-text/docx2txt
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)"
+RDEPEND="dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/PyPDF2[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence if filemagic's magic.py breaks imports
+# of dev-python/python-magic: https://bugs.gentoo.org/716482
+RDEPEND+=" !dev-python/filemagic"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+)
+
+distutils_enable_tests pytest