[gentoo-commits] repo/gentoo:master commit in: sys-apps/bolt/files/, sys-apps/bolt/

[Matthew Thode]

commit:     046e89752c49f8542e53ef2b0f695b8e19dcf418
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 24 18:13:19 2020 +0000
Commit:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Mon Aug 24 18:14:15 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=046e8975

sys-apps/bolt: add openrc support

thanks to redflyhacker+gentoo <AT> gmail.com for providing the init script
and the kernel config checks.

Closes: https://bugs.gentoo.org/692510
Package-Manager: Portage-3.0.4, Repoman-2.3.23
Signed-off-by: Matthew Thode <prometheanfire <AT> gentoo.org>

 sys-apps/bolt/bolt-0.9-r1.ebuild | 52 ++++++++++++++++++++++++++++++++++++++++
 sys-apps/bolt/files/bolt.openrc  | 14 +++++++++++
 2 files changed, 66 insertions(+)

diff --git a/sys-apps/bolt/bolt-0.9-r1.ebuild b/sys-apps/bolt/bolt-0.9-r1.ebuild
new file mode 100644
index 00000000000..8145c75880e
--- /dev/null
+++ b/sys-apps/bolt/bolt-0.9-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit linux-info meson systemd
+
+DESCRIPTION="Userspace system daemon to enable security levels for Thunderbolt 3"
+HOMEPAGE="https://gitlab.freedesktop.org/bolt/bolt"
+SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc systemd"
+
+DEPEND="
+	>=dev-libs/glib-2.56.0:2
+	dev-util/glib-utils
+	virtual/libudev
+	virtual/udev
+	dev-util/umockdev
+	sys-auth/polkit[introspection]
+	systemd? ( sys-apps/systemd )
+	doc? ( app-text/asciidoc )"
+RDEPEND="${DEPEND}"
+
+pkg_pretend() {
+	CONFIG_CHECK="~THUNDERBOLT"
+	ERROR_THUNDERBOLT="This package requires the thunderbolt kernel driver."
+	check_extra_config
+
+	CONFIG_CHECK="~HOTPLUG_PCI"
+	ERROR_HOTPLUG_PCI="Thunderbolt requires PCI hotplug support."
+	check_extra_config
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dman=$(usex doc true false)
+		--sysconfdir=/etc
+		--localstatedir=/var
+		--sharedstatedir=/var/lib
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	newinitd "${FILESDIR}"/${PN}.openrc boltd
+	keepdir /var/lib/boltd
+}

diff --git a/sys-apps/bolt/files/bolt.openrc b/sys-apps/bolt/files/bolt.openrc
new file mode 100644
index 00000000000..b80a7b31b26
--- /dev/null
+++ b/sys-apps/bolt/files/bolt.openrc
@@ -0,0 +1,14 @@
+#!/sbin/openrc-run
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+name="Thunderbolt Security Daemon"
+description="Userspace system daemon to enable security levels for Thunderbolt 3"
+command="/usr/libexec/boltd"
+command_background="true"
+pidfile="/var/run/boltd.pid"
+
+depend() {
+	need dbus
+	before xdm
+}