[gentoo-commits] gentoo-x86 commit in media-sound/amarok: amarok-2.2.1-r2.ebuild ChangeLog

[Jorge Manuel B. S. Vicetto (jmbsvicetto)]

jmbsvicetto    09/12/01 01:58:35

  Modified:             ChangeLog
  Added:                amarok-2.2.1-r2.ebuild
  Log:
  Updated taglib dependency - fixes bug 293950.
  Patched mysqlecollection to fix the build with >=binutils-2.20 - fixes bug 290662.
  Should fix bug 277785.
  (Portage version: 2.2_rc52/cvs/Linux x86_64)

Revision  Changes    Path
1.350                media-sound/amarok/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.350&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.350&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/ChangeLog?r1=1.349&r2=1.350

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v
retrieving revision 1.349
retrieving revision 1.350
diff -u -r1.349 -r1.350
--- ChangeLog	20 Nov 2009 10:27:27 -0000	1.349
+++ ChangeLog	1 Dec 2009 01:58:35 -0000	1.350
@@ -1,6 +1,15 @@
 # ChangeLog for media-sound/amarok
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.349 2009/11/20 10:27:27 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.350 2009/12/01 01:58:35 jmbsvicetto Exp $
+
+*amarok-2.2.1-r2 (01 Dec 2009)
+
+  01 Dec 2009; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
+  +amarok-2.2.1-r2.ebuild, +files/amarok-2.2-mysql-libs.patch:
+  Updated taglib dependency - fixes bug 293950.
+  Patched mysqlecollection to fix the build with >=binutils-2.20 - fixes bug
+  290662.
+  Should fix bug 277785.
 
   20 Nov 2009; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
   amarok-2.2.1-r1.ebuild:



1.1                  media-sound/amarok/amarok-2.2.1-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/amarok-2.2.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/amarok-2.2.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: amarok-2.2.1-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.2.1-r2.ebuild,v 1.1 2009/12/01 01:58:35 jmbsvicetto Exp $

EAPI="2"

# Translations are only in the tarballs, not the git repo
if [[ ${PV} != *9999* ]]; then
	KDE_LINGUAS="bg ca cs da de en_GB es et eu fi fr it ja km nb nds nl
	pa pl pt pt_BR ru sl sr sr@latin sv th tr uk wa zh_TW"
else
	EGIT_REPO_URI="git://gitorious.org/${PN}/${PN}.git"
	GIT_ECLASS="git"
fi
OPENGL_REQUIRED="optional"
inherit kde4-base ${GIT_ECLASS}

DESCRIPTION="Advanced audio player based on KDE framework."
HOMEPAGE="http://amarok.kde.org/"
if [[ ${PV} = *9999* ]]; then
	SRC_URI=""
else
	SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.bz2"
fi

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="4"
IUSE="bindist cdda daap debug ipod lastfm mp3tunes mtp +semantic-desktop"

# ipod requires gdk enabled and also gtk compiled in libgpod
DEPEND="
	app-crypt/qca:2
	>=app-misc/strigi-0.5.7
	|| (
		>=dev-db/mysql-5.0.76-r1[embedded,-minimal]
		>=dev-db/mysql-community-5.0.77-r1[embedded,-minimal]
	)
	>=media-libs/taglib-extras-1.0.1
	>=kde-base/kdelibs-${KDE_MINIMAL}[opengl?,semantic-desktop?]
	sys-libs/zlib
	>=x11-libs/qtscriptgenerator-0.1.0
	bindist? ( >=media-libs/taglib-1.6.1[-asf,-mp4] )
	!bindist? ( >=media-libs/taglib-1.6.1[asf,mp4] )
	cdda? (
		>=kde-base/libkcddb-${KDE_MINIMAL}
		>=kde-base/libkcompactdisc-${KDE_MINIMAL}
		>=kde-base/kdemultimedia-kioslaves-${KDE_MINIMAL}
	)
	ipod? ( >=media-libs/libgpod-0.7.0[gtk] )
	lastfm? ( >=media-libs/liblastfm-0.3.0 )
	mp3tunes? (
		dev-libs/glib:2
		dev-libs/libxml2
		dev-libs/openssl
		net-libs/loudmouth
		net-misc/curl
		x11-libs/qt-core[glib]
	)
	mtp? ( >=media-libs/libmtp-0.3.0 )
"
RDEPEND="${DEPEND}
	>=kde-base/phonon-kde-${KDE_MINIMAL}
	>=media-sound/amarok-utils-${PV}
	semantic-desktop? ( >=kde-base/nepomuk-${KDE_MINIMAL} )
"

PATCHES=(
	"${FILESDIR}/amarok-qtscriptcheck.patch"
	"${FILESDIR}/amarok-2.2-mysql-libs.patch"
)

# Only really required for live ebuild, to skip git_src_prepare
src_prepare() {
	kde4-base_src_prepare
}

src_configure() {
	mycmakeargs="${mycmakeargs}
		-DWITH_PLAYER=ON
		-DWITH_UTILITIES=OFF
		-DWITH_Libgcrypt=OFF
		$(cmake-utils_use_with ipod)
		$(cmake-utils_use_with ipod Gdk)
		$(cmake-utils_use_with lastfm LibLastFm)
		$(cmake-utils_use_with mtp)
		$(cmake-utils_use_with mp3tunes MP3Tunes)"
#		$(cmake-utils_use_with semantic-desktop Nepomuk)
#		$(cmake-utils_use_with semantic-desktop Soprano)"

	kde4-base_src_configure
}

pkg_postinst() {
	kde4-base_pkg_postinst

	if use daap; then
		echo
		elog "You have installed amarok with daap support."
		elog "You may be interested in installing www-servers/mongrel as well."
		echo
	fi
}