[gentoo-commits] repo/gentoo:master commit in: dev-libs/librelp/

[Thomas Deutschmann]

commit:     0e658bd3b2450cd2e058c6da80de34c3321f2532
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 13 22:53:13 2019 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Wed Mar 13 22:58:16 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0e658bd3

dev-libs/librelp: bump to v1.4.0

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Thomas Deutschmann <whissi <AT> gentoo.org>

 dev-libs/librelp/Manifest             |  1 +
 dev-libs/librelp/librelp-1.4.0.ebuild | 83 +++++++++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)

diff --git a/dev-libs/librelp/Manifest b/dev-libs/librelp/Manifest
index 529bb05a24c..a713989ed53 100644
--- a/dev-libs/librelp/Manifest
+++ b/dev-libs/librelp/Manifest
@@ -1,2 +1,3 @@
 DIST librelp-1.2.18.tar.gz 506766 BLAKE2B 939bd2279e03a6431fbdfb787aa3d62b3f622ec3248dfc7c0a0a141294c27319081092a624c328374cdba0cbd51659301a77ad41bed27ba13f47601f7a607944 SHA512 7193438238b7019e7a4944d6d900a1fa5a369ff8a6b97a6dca7e82b6637c0f391ec3554eeeaa285881457cb2abe72fa1a893244ec9a36cc9d2e2592d58c5462a
 DIST librelp-1.3.0.tar.gz 514470 BLAKE2B 3e8d844d3cccd4c148036191f376ba49b3851a2c7e95361bb31a1a172ca0813caa96eb3753b2285a2547c85e073de3237a749bc64fc0fead69ab170656dcb200 SHA512 6e60398c68a78f4b4202a697e144f1516ff3bbb32192f745b52c77d107954febf8cb31d2e166efa96c00122f6807860ecd01084f1d3d4005336f2cb75e6461c9
+DIST librelp-1.4.0.tar.gz 519235 BLAKE2B 9c1e52cc9f666e75f261db65f45e3d954afa033cac59f93394c30ba99ed772d71b2882bdbb9bed696e57ed99805d47e57fd5e331cc3bc3850c5f15041a0d70d0 SHA512 92d01a51b4ee3c66d1f65d2e26f214646d72b41a8411ab700fe5f9f30f805ef98dec962526ef95c8d8428bf7398d38f656c919f95a3e49382adc745ef9eb4239

diff --git a/dev-libs/librelp/librelp-1.4.0.ebuild b/dev-libs/librelp/librelp-1.4.0.ebuild
new file mode 100644
index 00000000000..26d84e37b33
--- /dev/null
+++ b/dev-libs/librelp/librelp-1.4.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+
+inherit autotools python-any-r1
+
+DESCRIPTION="An easy to use library for the RELP protocol"
+HOMEPAGE="http://www.librelp.com/"
+SRC_URI="http://download.rsyslog.com/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+ doc? ( FDL-1.3 )"
+
+# subslot = soname version
+SLOT="0/0.5.0"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~sparc ~x86"
+IUSE="debug doc +ssl +gnutls libressl openssl static-libs test"
+REQUIRED_USE="ssl? ( ^^ ( gnutls openssl ) )
+	gnutls? ( ssl )
+	openssl? ( ssl )
+	libressl? ( openssl )"
+
+RDEPEND="ssl? (
+		gnutls? ( >=net-libs/gnutls-3.3.17.1:0= )
+		openssl? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl:0= )
+		)
+	)"
+
+DEPEND="ssl? (
+		gnutls? ( >=net-libs/gnutls-3.3.17.1:0= )
+		openssl? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl:0= )
+		)
+	)
+	test? ( ${PYTHON_DEPS} )
+	virtual/pkgconfig"
+
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	sed -i \
+		-e 's/ -g"/"/g' \
+		configure.ac || die "sed failed"
+
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-valgrind
+		$(use_enable debug)
+		$(use_enable gnutls tls)
+		$(use_enable openssl tls-openssl)
+		$(use_enable static-libs static)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	emake -j1 check
+}
+
+src_install() {
+	local DOCS=( ChangeLog )
+	use doc && local HTML_DOCS=( doc/relp.html )
+	default
+
+	if ! use static-libs; then
+		find "${ED%/}"/usr/lib* -name '*.la' -delete || die
+	fi
+}